?? upload_class.asp
字號:
<!--#include FILE="Upload.inc"-->
<%
'-----------------------------------------------------------------------
'--- 上傳處理類模塊
'--- Copyright (c) 2004 Aspsky, Inc.
'--- Mail: Sunwin@artbbs.net http://www.aspsky.net
'--- 2004-12-18
'-----------------------------------------------------------------------
'-----------------------------------------------------------------------
'-- InceptFileType : 設置上傳類型屬性 (以逗號分隔多個文件類型) String
'-- MaxSize : 設置上傳文件大小上限 (單位：kb) Long
'-- InceptMaxFile : 設置一次上傳文件最大個數 Long
'-- UploadPath : 設置保存的目錄相對路徑 String
'-- UploadType : 設置上傳組件類型 （0=無組件上傳類，1=Aspupload3.0 ,2=SA-FileUp 4.0 ,3=DvFile.Upload V1.0）
'-- SaveUpFile : 執行上傳
'-- GetBinary : 設置上傳是否返回文件數據流 Bloon值 : True/False
'-- ChkSessionName : 設置SESSION名，防止重復提交，SESSION名與提交的表單名要一致。
'-- RName設置文件名 : 定義文件名前綴 (如默認生成的文件名為200412230402587123.jpg
' 設置：RName="PRE_",生成的文件名為：PRE_200412230402587123.jpg)
'-----------------------------------------------------------------------
'-- 設置圖片組件屬性
'-- PreviewType : 設置組件(0=CreatePreviewImage組件，1=AspJpegV1.2 ,2=SoftArtisans ImgWriter V1.21)
'-- PreviewImageWidth : 設置預覽圖片寬度
'-- PreviewImageHeight : 設置預覽圖片高度
'-- DrawImageWidth : 設置水印圖片或文字區域寬度
'-- DrawImageHeight : 設置水印圖片或文字區域高度
'-- DrawGraph : 設置水印圖片或文字區域透明度
'-- DrawFontColor : 設置水印文字顏色
'-- DrawFontFamily : 設置水印文字字體格式
'-- DrawFontSize : 設置水印文字字體大小
'-- DrawFontBold : 設置水印文字是否粗體
'-- DrawInfo : 設置水印文字信息或圖片信息
'-- DrawType : 設置加載水印模式：0=不加載水印 ，1=加載水印文字 ，2=加載水印圖片
'-- DrawXYType : 圖片添加水印LOGO位置坐標："0" =左上，"1"=左下,"2"=居中,"3"=右上,"4"=右下
'-- DrawSizeType : 生成預覽圖片大小規則："0"=固定縮小，"1"=等比例縮小
'-----------------------------------------------------------------------
'-- 獲取上傳信息
'-- ObjName : 采用的組件名稱
'-- Count : 上傳文件總數
'-- CountSize : 上傳總大小字節數
'-- ErrCodes : 錯誤NUMBER (默認為0)
'-- Description : 錯誤描述
'-----------------------------------------------------------------------
'-- CreateView Imagename,TempFilename,FileExt
' 創建預覽圖片過程: 原始文件的相對路徑,生成預覽文件相對路徑,原文件后綴
'-----------------------------------------------------------------------
'-----------------------------------------------------------------------
'-- 獲取文件對象屬性 : UploadFiles
'-- FormName : 表單名稱
'-- FileName : 生成的文件名稱
'-- FilePath : 保存文件的相對路徑
'-- FileSize : 文件大小
'-- FileContentType : ContentType文件類型
'-- FileType : 0=其它,1=圖片,2=FLASH,3=音樂,4=電影
'-- FileData : 文件數據流 (若組件不支持直接獲取，則返回Null)
'-- FileExt : 文件后綴
'-- FileWidth : 圖片/Flash文件寬度 （其他文件默認=-1）
'-- FileHeight : 圖片/Flash文件高度 （其他文件默認=-1）
'-----------------------------------------------------------------------
'-----------------------------------------------------------------------
'-- 獲取表單對象屬性 : UploadForms
'-- Count : 表單數
'-- key : 表單內容
'-----------------------------------------------------------------------
'-----------------------------------------------------------------------
Class UpFile_Cls
Private UploadObj,ImageObj
Private FilePath,InceptFile,FileMaxSize,MaxFile,Upload_Type,FileInfo,IsBinary,SessionName
Private Preview_Type,View_ImageWidth,View_ImageHeight,Draw_ImageWidth,Draw_ImageHeight,Draw_Graph
Private Draw_FontColor,Draw_FontFamily,Draw_FontSize,Draw_FontBold,Draw_Info,Draw_Type,Draw_XYType,Draw_SizeType
Private RName_Str,Transition_Color
Public ErrCodes,ObjName,UploadFiles,UploadForms,Count,CountSize
'-----------------------------------------------------------------------------------
'初始化類
'-----------------------------------------------------------------------------------
Private Sub Class_Initialize
SessionName = Empty
IsBinary = False
ErrCodes = 0
Count = 0
CountSize = 0
FilePath = "./"
InceptFile = ""
FileMaxSize = -1
MaxFile = 1
Upload_Type = -1
Preview_Type = 999
ObjName = "未知組件"
View_ImageWidth = 0
View_ImageHeight = 0
Draw_FontColor = &H000000
Draw_FontFamily = "Arial"
Draw_FontSize = 10
Draw_FontBold = False
Draw_Info = "BBS.DVBBS.NET"
Draw_Type = -1
Set UploadFiles = Server.CreateObject ("Scripting.Dictionary")
Set UploadForms = Server.CreateObject ("Scripting.Dictionary")
UploadFiles.CompareMode = 1
UploadForms.CompareMode = 1
End Sub
'-----------------------------------------------------------------------------------
'銷毀類
'-----------------------------------------------------------------------------------
Private Sub Class_Terminate
If IsObject(UploadObj) Then
Set UploadObj = Nothing
End If
If IsObject(ImageObj) Then
Set ImageObj = Nothing
End If
UploadFiles.RemoveAll
UploadForms.RemoveAll
Set UploadForms = Nothing
Set UploadFiles = Nothing
End Sub
'-----------------------------------------------------------------------------------
'設置上傳是否返回文件數據流
'-----------------------------------------------------------------------------------
Public Property Let GetBinary(Byval Values)
IsBinary = Values
End Property
'-----------------------------------------------------------------------------------
'設置上傳類型屬性 (以逗號分隔多個文件類型)
'-----------------------------------------------------------------------------------
Public Property Let InceptFileType(Byval Values)
InceptFile = Lcase(Values)
End Property
'-----------------------------------------------------------------------------------
'設置上傳類型屬性 (以逗號分隔多個文件類型)
'-----------------------------------------------------------------------------------
Public Property Let ChkSessionName(Byval Values)
SessionName = Values
End Property
'-----------------------------------------------------------------------------------
'設置上傳文件大小上限 (單位：kb)
'-----------------------------------------------------------------------------------
Public Property Let MaxSize(Byval Values)
FileMaxSize = ChkNumeric(Values) * 1024
End Property
Public Property Get MaxSize
MaxSize = FileMaxSize
End Property
'-----------------------------------------------------------------------------------
'設置每次上傳文件上限
'-----------------------------------------------------------------------------------
Public Property Let InceptMaxFile(Byval Values)
MaxFile = ChkNumeric(Values)
End Property
'-----------------------------------------------------------------------------------
'設置上傳目錄路徑
'-----------------------------------------------------------------------------------
Public Property Let UploadPath(Byval Path)
FilePath = Replace(Path,Chr(0),"")
If Right(FilePath,1)<>"/" Then FilePath = FilePath & "/"
End Property
Public Property Get UploadPath
UploadPath = FilePath
End Property
'-----------------------------------------------------------------------------------
'獲取錯誤信息
'-----------------------------------------------------------------------------------
Public Property Get Description
Select Case ErrCodes
Case 1 : Description = "不支持 " & ObjName & " 上傳，服務器可能未安裝該組件。"
Case 2 : Description = "暫未選擇上傳組件！"
Case 3 : Description = "請先選擇你要上傳的文件!"
Case 4 : Description = "文件大小超過了限制 " & (FileMaxSize\1024) & "KB!"
Case 5 : Description = "文件類型不正確!"
Case 6 : Description = "已達到上傳數的上限！"
Case 7 : Description = "請不要重復提交！"
Case Else
Description = Empty
End Select
End Property
'-----------------------------------------------------------------------------------
'設置文件名前綴
'-----------------------------------------------------------------------------------
Public Property Let RName(Byval Values)
RName_Str = Values
End Property
'-----------------------------------------------------------------------------------
'設置上傳組件屬性
'-----------------------------------------------------------------------------------
Public Property Let UploadType(Byval Types)
Upload_Type = Types
If Upload_Type = "" or Not IsNumeric(Upload_Type) Then
Upload_Type = -1
End If
End Property
'-----------------------------------------------------------------------------------
'設置上傳圖片組件屬性
'-----------------------------------------------------------------------------------
Public Property Let PreviewType(Byval Types)
Preview_Type = Types
On Error Resume Next
If Preview_Type = "" or Not IsNumeric(Preview_Type) Then
Preview_Type = 999
Else
If PreviewType <> 999 Then
Select Case Preview_Type
Case 0
'---------------------CreatePreviewImage---------------
ObjName = "CreatePreviewImage組件"
Set ImageObj = Server.CreateObject("CreatePreviewImage.cGvbox")
Case 1
'---------------------AspJpegV1.2---------------
ObjName = "AspJpegV1.2組件"
Set ImageObj = Server.CreateObject("Persits.Jpeg")
Case 2
'---------------------SoftArtisans ImgWriter V1.21---------------
ObjName = "SoftArtisans ImgWriter V1.21組件"
Set ImageObj = Server.CreateObject("SoftArtisans.ImageGen")
Case Else
Preview_Type = 999
End Select
If Err.Number<>0 Then
ErrCodes = 1
End If
End If
End If
End Property
Public Property Get PreviewType
PreviewType = Preview_Type
End Property
'-----------------------------------------------------------------------------------
'設置預覽圖片寬度屬性
'-----------------------------------------------------------------------------------
Public Property Let PreviewImageWidth(Byval Values)
View_ImageWidth = ChkNumeric(Values)
End Property
'-----------------------------------------------------------------------------------
'設置預覽圖片高度屬性
'-----------------------------------------------------------------------------------
Public Property Let PreviewImageHeight(Byval Values)
View_ImageHeight = ChkNumeric(Values)
End Property
'-----------------------------------------------------------------------------------
'設置水印圖片或文字區域寬度屬性
'-----------------------------------------------------------------------------------
Public Property Let DrawImageWidth(Byval Values)
Draw_ImageWidth = ChkNumeric(Values)
End Property
'-----------------------------------------------------------------------------------
'設置水印圖片或文字區域高度屬性
'-----------------------------------------------------------------------------------
Public Property Let DrawImageHeight(Byval Values)
Draw_ImageHeight = ChkNumeric(Values)
End Property
'-----------------------------------------------------------------------------------
'設置水印圖片或文字區域透明度屬性
'-----------------------------------------------------------------------------------
Public Property Let DrawGraph(Byval Values)
If IsNumeric(Values) Then
Draw_Graph = Formatnumber(Values,2)
Else
Draw_Graph = 1
End If
End Property
'-----------------------------------------------------------------------------------
'設置水印圖片透明度去除底色值
'-----------------------------------------------------------------------------------
Public Property Let TransitionColor(Byval Values)
If Values<>"" or Values<>"0" Then
Transition_Color = Replace(Values,"#","&h")
End If
End Property
'-----------------------------------------------------------------------------------
'設置水印文字顏色
'-----------------------------------------------------------------------------------
Public Property Let DrawFontColor(Byval Values)
If Values<>"" or Values<>"0" Then
Draw_FontColor = Replace(Values,"#","&h")
End If
End Property
'-----------------------------------------------------------------------------------
'設置水印文字字體格式
'-----------------------------------------------------------------------------------
Public Property Let DrawFontFamily(Byval Values)
Draw_FontFamily = Values
End Property
'-----------------------------------------------------------------------------------
'設置水印文字字體大小
'-----------------------------------------------------------------------------------
Public Property Let DrawFontSize(Byval Values)
Draw_FontSize = Values
End Property
'-----------------------------------------------------------------------------------
'設置水印文字是否粗體 Boolean
'-----------------------------------------------------------------------------------
Public Property Let DrawFontBold(Byval Values)
Draw_FontBold = ChkBoolean(Values)
End Property
'-----------------------------------------------------------------------------------
'設置水印文字信息或圖片信息
'-----------------------------------------------------------------------------------
Public Property Let DrawInfo(Byval Values)
Draw_Info = Values
End Property
'-----------------------------------------------------------------------------------
'加載模式：0=不加載水印 ，1=加載水印文字 ，2=加載水印圖片
'-----------------------------------------------------------------------------------
Public Property Let DrawType(Byval Values)
Draw_Type = ChkNumeric(Values)
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -