<%
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
'★                                                                  ★
'☆                eWebEditor - eWebSoft在線文本編輯器               ☆
'★                                                                  ★
'☆  版權所有: eWebSoft.com                                          ☆
'★                                                                  ★
'☆  程序制作: eWeb開發團隊                                          ☆
'★            email:webmaster@webasp.net                            ★
'☆            QQ:589808                                             ☆
'★                                                                  ★
'☆  相關網址: [產品介紹]http://www.eWebSoft.com/Product/eWebEditor/ ☆
'★            [支持論壇]http://bbs.eWebSoft.com/                    ★
'☆                                                                  ☆
'★  主頁地址: http://www.eWebSoft.com/   eWebSoft團隊及產品         ★
'☆            http://www.webasp.net/     WEB技術及應用資源網站      ☆
'★            http://bbs.webasp.net/     WEB技術交流論壇            ★
'★                                                                  ★
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
%>

<%

'================================================
'作  用：替換字符串中的遠程文件為本地文件并保存遠程文件
'參  數：
'	sHTML		: 要替換的字符串
'	sSavePath	: 保存文件的路徑
'	sExt		: 執行替換的擴展名
'================================================
Function eWebEditor_ReplaceRemoteUrl(sHTML, sSavePath, sExt)
	Dim s_Content
	s_Content = sHTML
	If eWebEditor_IsObjInstalled("Microsoft.XMLHTTP") = False then
		eWebEditor_ReplaceRemoteUrl = s_Content
		Exit Function
	End If
	
	If sSavePath = "" Then sSavePath = "/eWebEditor/UploadFile/"
	If sExt = "" Then sExt = "jpg|gif|bmp|png"
	Dim re, RemoteFile, RemoteFileurl, SaveFileName, SaveFileType, ranNum
	Set re = new RegExp
	re.IgnoreCase  = True
	re.Global = True
	re.Pattern = "((http|https|ftp|rtsp|mms):(\/\/|\\\\){1}((\w)+[.]){1,}(net|com|cn|org|cc|tv|[0-9]{1,3})(\S*\/)((\S)+[.]{1}(" & sExt & ")))"
	Set RemoteFile = re.Execute(s_Content)
	For Each RemoteFileurl in RemoteFile
		SaveFileType = Mid(RemoteFileurl, InstrRev(RemoteFileurl, ".") + 1)
		Randomize
		ranNum = Int(900 * Rnd) + 100
		SaveFileName = sSavePath & year(now) & month(now) & day(now) & hour(now) & minute(now) & second(now) & ranNum & "." & SaveFileType
		Call eWebEditor_SaveRemoteFile(SaveFileName, RemoteFileurl)
		s_Content = Replace(s_Content,RemoteFileurl,SaveFileName)
	Next
	eWebEditor_ReplaceRemoteUrl = s_Content
End Function

'================================================
'作  用：保存遠程的文件到本地
'參  數：LocalFileName ------ 本地文件名
'		 RemoteFileUrl ------ 遠程文件URL
'返回值：True  ----成功
'        False ----失敗
'================================================
Sub eWebEditor_SaveRemoteFile(s_LocalFileName,s_RemoteFileUrl)
	Dim Ads, Retrieval, GetRemoteData
	On Error Resume Next
	Set Retrieval = Server.CreateObject("Microsoft.XMLHTTP")
	With Retrieval
		.Open "Get", s_RemoteFileUrl, False, "", ""
		.Send
		GetRemoteData = .ResponseBody
	End With
	Set Retrieval = Nothing
	Set Ads = Server.CreateObject("Adodb.Stream")
	With Ads
		.Type = 1
		.Open
		.Write GetRemoteData
		.SaveToFile Server.MapPath(s_LocalFileName), 2
		.Cancel()
		.Close()
	End With
	Set Ads=nothing
End Sub

'================================================
'作  用：檢查組件是否已經安裝
'參  數：strClassString ----組件名
'返回值：True  ----已經安裝
'        False ----沒有安裝
'================================================
Function eWebEditor_IsObjInstalled(s_ClassString)
	On Error Resume Next
	eWebEditor_IsObjInstalled = False
	Err = 0
	Dim xTestObj
	Set xTestObj = Server.CreateObject(s_ClassString)
	If 0 = Err Then eWebEditor_IsObjInstalled = True
	Set xTestObj = Nothing
	Err = 0
End Function
%>