VERSION 5.00
Begin VB.Form frmWZLB1 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "商品類別設置信息"
   ClientHeight    =   3144
   ClientLeft      =   48
   ClientTop       =   336
   ClientWidth     =   6012
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   3144
   ScaleWidth      =   6012
   ShowInTaskbar   =   0   'False
   StartUpPosition =   1  'CenterOwner
   Begin VB.Frame Frame1 
      Caption         =   "商類別品設置："
      Height          =   2412
      Left            =   120
      TabIndex        =   4
      Top             =   120
      Width           =   5772
      Begin VB.TextBox txtItem 
         Height          =   1560
         Index           =   2
         Left            =   960
         MaxLength       =   80
         MultiLine       =   -1  'True
         ScrollBars      =   2  'Vertical
         TabIndex        =   7
         Top             =   600
         Width           =   4572
      End
      Begin VB.TextBox txtItem 
         Height          =   270
         Index           =   0
         Left            =   960
         MaxLength       =   8
         TabIndex        =   0
         Top             =   240
         Width           =   1572
      End
      Begin VB.TextBox txtItem 
         Height          =   270
         Index           =   1
         Left            =   3480
         MaxLength       =   20
         TabIndex        =   1
         Top             =   240
         Width           =   2052
      End
      Begin VB.Label Label2 
         Caption         =   "備注信息："
         Height          =   252
         Index           =   10
         Left            =   120
         TabIndex        =   8
         Top             =   600
         Width           =   1092
      End
      Begin VB.Label Label2 
         Caption         =   "類別編號："
         Height          =   252
         Index           =   0
         Left            =   120
         TabIndex        =   6
         Top             =   240
         Width           =   1092
      End
      Begin VB.Label Label2 
         Caption         =   "類別名稱："
         Height          =   252
         Index           =   1
         Left            =   2640
         TabIndex        =   5
         Top             =   240
         Width           =   1092
      End
   End
   Begin VB.CommandButton cmdExit 
      Caption         =   "返回 (&X)"
      Height          =   375
      Left            =   3000
      TabIndex        =   3
      Top             =   2640
      Width           =   1215
   End
   Begin VB.CommandButton cmdSave 
      Caption         =   "保存 (&S)"
      Height          =   375
      Left            =   1560
      TabIndex        =   2
      Top             =   2640
      Width           =   1215
   End
End
Attribute VB_Name = "frmWZLB1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
'是否改動過記錄，ture為改過
Dim mblChange As Boolean
Dim mrc As ADODB.Recordset
Public txtSQL As String

Private Sub cmdExit_Click()
    If mblChange And cmdSave.Enabled Then
        If MsgBox("保存當前記錄的變化嗎？", vbOKCancel + vbExclamation, "警告") = vbOK Then
            '保存
            Call cmdSave_Click
        End If
    End If
    Unload Me
End Sub

Private Sub cmdSave_Click()
    Dim intCount As Integer
    Dim sMeg As String
    Dim MsgText As String
    
  
    For intCount = 0 To 1
        If Trim(txtItem(intCount) & " ") = "" Then
            Select Case intCount
                Case 0
                    sMeg = "類別編號"
                Case 1
                    sMeg = "類別名稱"
            End Select
            sMeg = sMeg & "不能為空！"
            MsgBox sMeg, vbOKOnly + vbExclamation, "警告"
            txtItem(intCount).SetFocus
            Exit Sub
        End If
    Next intCount
    
   
    '添加判斷是否有相同的ID記錄
    If gintWZLBSmode = 1 Then
        txtSQL = "select * from dm_wzlb where lbcode ='" & Trim(txtItem(0)) & "'"
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        If mrc.EOF = False Then
            MsgBox "已經存在此類別編號的記錄！", vbOKOnly + vbExclamation, "警告"
            txtItem(0).SetFocus
            Exit Sub
        End If
        mrc.Close
    End If
    
    
    '先刪除已有記錄
    txtSQL = "delete from dm_wzlb where lbcode ='" & Trim(txtItem(0)) & "'"
    Set mrc = ExecuteSQL(txtSQL, MsgText)
   
    
    '再加入新記錄
    txtSQL = "insert dm_wzlb values  ('"
    For intCount = 0 To 1
        txtSQL = txtSQL & Trim(txtItem(intCount)) & "','"
    Next intCount
    
    
    txtSQL = txtSQL & Trim(txtItem(2)) & "')"
    
    Set mrc = ExecuteSQL(txtSQL, MsgText)
        
    If gintWZLBSmode = 1 Then
        MsgBox "添加記錄成功！", vbOKOnly + vbExclamation, "添加記錄"
        For intCount = 0 To 2
            txtItem(intCount) = ""
        Next intCount
        
        
        mblChange = False
        
        Unload frmWZLB
        frmWZLB.txtSQL = "select * from dm_wzlb"
        frmWZLB.Show
        
    ElseIf gintWZLBSmode = 2 Then
        Unload Me
        Unload frmWZLB
        
        frmWZLB.txtSQL = "select * from dm_wzlb"
        frmWZLB.Show
    End If
    
End Sub


Private Sub Form_Load()
    Dim intCount As Integer
    Dim MsgText As String
    Dim i As Integer
    Dim mrcc As ADODB.Recordset
  
    If gintWZLBSmode = 1 Then
        Me.Caption = Me.Caption & "添加"
        For i = 0 To 2
            txtItem(i).Text = ""
        Next i
        
    ElseIf gintWZLBSmode = 2 Then
        Set mrc = ExecuteSQL(txtSQL, MsgText)
        
        If mrc.EOF = False Then
            With mrc
                For intCount = 0 To 2
                    txtItem(intCount) = .Fields(intCount)
                Next intCount
            End With
            txtItem(0).Enabled = False
        End If
        
        Me.Caption = Me.Caption & "修改"
    End If
    
    mblChange = False
End Sub

Private Sub Form_Unload(Cancel As Integer)
    gintWZLBSmode = 0
End Sub



Private Sub txtItem_Change(Index As Integer)
    '有變化設置gblchange
    mblChange = True
End Sub

Private Sub txtItem_GotFocus(Index As Integer)
    txtItem(Index).SelStart = 0
    txtItem(Index).SelLength = Len(txtItem(Index))
End Sub

Private Sub txtItem_KeyDown(Index As Integer, KeyCode As Integer, Shift As Integer)
    EnterToTab KeyCode
End Sub