;**********************  程序說明  **************************
;按鍵K1，K2為獨立式鍵盤,K1對應P3.2,K2對應P3.3
;K1模式選擇鍵，其對應的模式有：
;LED_DISPLAY1:	LED逐個左移點亮
;LED_DISPLAY2:	LED逐個右移點亮
;LED_DISPLAY3:	LED流水燈左移
;LED_DISPLAY4:	LED流水燈右移
;K2顯示時間選擇鍵，其對應的時間間隔有：
;0.5S
;1.0S
;1.5S
;2.0S
;***********************************************************
	ORG	8000H
	LJMP	START
	ORG	800BH
	LJMP	TIMER0

	ORG	8100H
	
TIME_05	EQU	30H	;0.5S的定時記數器
TIME_10	EQU	31H	;1S  的定時記數器
TIME_15	EQU	32H	;1.5S的定時記數器
TIME_20	EQU	33H	;2.0S的定時記數器
LED_STATE	EQU	34H	;LED顯示狀態變量

LED_TIME_SEL	EQU	35H	;LED顯示狀態變化時間選擇變量
;LED_TIME_SEL=1		LED的刷新時間為0.5S
;LED_TIME_SEL=2		LED的刷新時間為1S
;LED_TIME_SEL=3		LED的刷新時間為1.5S

LED_MODE_SEL	EQU	36H	;LED顯示模式選擇變量
;LED_MODE_SEL=1		LED的顯示方式為拉屏顯示，即LED_DISPLAY1
;LED_MODE_SEL=2		LED的顯示方式為正向流水燈，即LED_DISPLAY2,且FOLLOW_BACK=0
;LED_MODE_SEL=3		LED的顯示方式為反向流水燈，即LED_DISPLAY2,且FOLLOW_BACK=1

KEY_VALUE	EQU	37H	;鍵盤鍵值寄存器
KEY_PUSH_TIME	EQU	38H	;鍵盤被按下的次數，即按鍵碼時間=10ms*次數
KEY_STATE	EQU	39H	;鍵盤狀態寄存器
KEY_NAME	EQU	40H	;鍵盤鍵名寄存器
KEY_NAME_OUT	EQU	41H	;鍵盤鍵名輸出寄存器
DISP_REG	EQU	42H	;LED顯示寄存器
FOLLOW_KEY	EQU	43H	;上一次按鍵寄存器
KEY_GET_REG	EQU	44H	;取鍵值狀態寄存器
OLD_KEY		EQU	45H	;舊鍵寄存器

T05flag	BIT	00H	;0.5S的定時時標位
T10flag	BIT	01H	;1S  的定時時標位
T15flag	BIT	02H	;1.5S的定時時標位
T20flag	BIT	03H	;2.0S的定時時標位	
T10MSflag	BIT	04H	;10mS的定時時標位
MODEflag	BIT	05H	;MODE選擇標志位
TIMEflag	BIT	06H	;TIME選擇標志位	
KEY_LED_flag	bit	07h	;按鍵與顯示狀態標志位 KEY為0，LED為1
KEYSUCCflag	BIT	08H	;按鍵成功標志位		
K1_flag		BIT	09H	;K1一次按鍵有效標志位
K2_flag		BIT	0AH	;K2一次按鍵有效標志位

START:
	MOV	SP,#60H
	MOV	TIME_05,#10	;初始化  50mS*10=0.5S
	MOV	TIME_10,#20	;初始化  50mS*20=1.0S
	MOV	TIME_15,#30	;初始化  50mS*30=1.5S
	MOV	TIME_20,#40	;初始化  50mS*40=2.0S
	MOV	LED_STATE,#02	;初始化	LED顯示狀態變量	
	MOV	LED_TIME_SEL,#1	;初始化	LED顯示時間選擇變量	
	MOV	LED_MODE_SEL,#1	;初始化	LED顯示模式選擇變量
	MOV	KEY_VALUE,#11H	;初始化	鍵盤鍵值寄存器
	MOV	KEY_PUSH_TIME,#00H	;初始化	按鍵次數寄存器
	MOV	KEY_STATE,#00H	;初始化	按鍵狀態寄存器
	MOV	KEY_NAME,#00H	;初始化	鍵盤鍵名寄存器
	MOV	KEY_NAME_OUT,#00H	;初始化	鍵盤鍵名輸出寄存器
	MOV	DISP_REG,#0FEH	;初始化	LED顯示寄存器
	MOV	FOLLOW_KEY,#00H	;初始化 前一次按鍵寄存器
	MOV	KEY_GET_REG,#00H	;初始化 取鍵值狀態寄存器
	MOV	OLD_KEY,#00H	;初始化 舊鍵寄存器

	CLR	T05flag
	CLR	T10flag
	CLR	T15flag
	CLR	T20flag
	CLR	T10MSflag
	CLR	MODEflag
	CLR	TIMEflag
	CLR	KEYSUCCflag
	SETB	KEY_LED_flag	;初始化，設為LED顯示狀態
	CLR	K1_flag
	CLR	K2_flag		
	
	MOV	TH0,#0D8H	;設計數初值，定時時間為10mS
	MOV	TL0,#0F0H

	MOV	TMOD,#01H	;定時器0工作于方式2，為16位的定時器
	SETB	ET0
	SETB	TR0
	SETB	EA

MAIN_LOOP:			;主程序入口
	
TEST_POINT1:
	
MAIN_NEXT1:
	JNB	T10MSflag,MAIN_NEXT2	;10MS調一下鍵盤掃描
	CLR	T10MSflag		;清10MS時標標志位
	LCALL	KEY
MAIN_NEXT2:
	
	;JNB	KEY_LED_flag,MAIN_NEXT3
	LCALL	TIME_MODE_SEL
	LJMP	MAIN_LOOP
MAIN_NEXT3:
	MOV	A,KEY_VALUE
	CPL	A
	MOV	P1,A	
	LJMP	MAIN_LOOP		;主程式序循環掃描

;***************************************************************
;獨立鍵盤處理程序
;K1從P3.2輸入  K2從P3.3輸入
;K1為模式選擇鍵，K2為方式選擇鍵
;***************************************************************
KEY:
	PUSH 	ACC
	PUSH	PSW
	MOV	A,P3
	ORL	A,#0CH
	MOV	A,P3
	ANL	A,#0CH
	CJNE	A,#0CH,KEY_00;		;沒有鍵按下直接退出
	LJMP	KEY_FF;
KEY_00:
	CJNE	A,OLD_KEY,KEY_AA	;本次按鍵與上次按鍵相比較
	LJMP	KEY_BB
KEY_AA:
	MOV	OLD_KEY,A	;將新鍵存入寄存器
	MOV	KEY_STATE,#00H	;按鍵狀態寄存器清零
KEY_BB:
	LCALL	KEY_WENDING	;調按鍵去抖動，延時程序		
	JNB	KEYSUCCflag,KEY_EE;
	CLR	KEYSUCCflag
	CJNE	A,#08H,KEY_DD	;判斷P3。3是否按下
	SETB	K1_flag
	MOV	A,KEY_VALUE	;將原鍵盤值取出
	SWAP	A
	ANL	A,#0FH	;屏蔽高四位
	INC	A	;將模式選擇加1，即選擇下一個LED顯示模式
	CJNE	A,#05H,KEY_MODE1A	;模式選擇只有1-4 四種方式
	ANL	A,#01H	;將低四位置為1
KEY_MODE1A:
	SWAP	A
	ANL	KEY_VALUE,#0FH	;將高四位屏蔽
	ORL	KEY_VALUE,A
	MOV	DISP_REG,#0FEH
	LJMP	KEY_EE
	
KEY_DD:	CJNE	A,#04H,KEY_EE	;判斷P3。2是否按下
	SETB	K2_flag
	MOV	A,KEY_VALUE	;將原鍵盤值取出
	INC	A	;將模式選擇加1，即選擇下一個LED顯示模式
       	ANL	A,#07H	;將高四位屏蔽
	CJNE	A,#05H,KEY_TIME1A	;時間選擇只有1-4 四種方式
	ANL	A,#0F1H	;將低四位置為1
KEY_TIME1A:
	ANL	KEY_VALUE,#0F0H	;將低四位屏蔽
	ORL	KEY_VALUE,A	;將KEY_VALUE返回

KEY_EE:	
;	LCALL	KEY_VALUE_GET	

KEY_FF:
	POP	PSW
	POP	ACC
	RET
;***************************************************************

;***************************************************************
;按鍵穩定程序：去抖動，并且確認有鍵按下
;***************************************************************
KEY_WENDING:
	PUSH	ACC
	PUSH	PSW
	MOV	A,KEY_STATE
KSR0:
	CJNE	A,#00H,KSR1
	MOV	KEY_STATE,#01H		;將按鍵狀態寄存器轉為1
	POP	PSW
	POP	ACC
	RET
KSR1:	
	CJNE	A,#01H,KSR2
	MOV	KEY_STATE,#02H		;將按鍵狀態寄存器轉為2
	CLR	KEY_LED_flag		;當有確認有鍵盤按下,顯示指示為KEY按鍵狀態指示
	POP	PSW
	POP	ACC
	RET
KSR2:	
	CJNE	A,#02H,KSR3
	INC	KEY_PUSH_TIME
	MOV	A,KEY_PUSH_TIME
	CJNE	A,#35,KSR_OUT		;鍵按下未到350MS，則跳出
	SETB	KEYSUCCflag		;按鍵有效標志位
	MOV	KEY_PUSH_TIME,#00H	;將按鍵次數記數器清
	MOV	KEY_STATE,#00H		;將按鍵狀態寄存器設為0
KSR3:	
	
KSR_OUT:
	POP	PSW
	POP	ACC
	RET
;***************************************************************





;***************************************************************
;LED顯示輸出程序
;***************************************************************
TIME_MODE_SEL:
	PUSH	ACC
	PUSH	PSW

	MOV	A,KEY_VALUE
	ANL	A,#0F0H		;屏蔽低四位
MODE1:	;顯示方式11-14  LED_DISPLAY1:	LED逐個左移點亮
	CJNE	A,#10H,	MODE2	;判斷是否為模式1
	MOV	A,KEY_VALUE	
	ANL	A,#0FH		;屏蔽高四位
TIME11:
	CJNE	A,#01H,TIME12	;判斷顯示時間是否為0。5S
	JNB	T05flag,TIME15	;出口返回
	CLR	T05flag		;清0。5S到時間標志位
	LCALL	LED_DISPLAY1	;調顯示方式1
	LJMP	TIME15	;出口返回
TIME12:
	CJNE	A,#02H,TIME13	;判斷顯示時間是否為1。0S
	JNB	T10flag,TIME15	;出口返回
	CLR	T10flag		;清1。0S到時間標志位
	LCALL	LED_DISPLAY1	;調顯示方式1
	LJMP	MT_OUT	;出口返回
TIME13:
	CJNE	A,#03H,TIME14	;判斷顯示時間是否為1。5S
	JNB	T15flag,TIME15;出口返回
	CLR	T15flag		;清0。5S到時間標志位
	LCALL	LED_DISPLAY1	;調顯示方式1
	LJMP	TIME15	;出口返回
TIME14:
	CJNE	A,#04H,TIME15	;判斷顯示時間是否為2。0S
	JNB	T20flag,TIME15	;出口返回
	CLR	T20flag		;清2。0S到時間標志位
	LCALL	LED_DISPLAY1	;調顯示方式1
	LJMP	TIME15	;出口返回
TIME15:
	LJMP	MT_OUT

MODE2:	;顯示方式21-24  LED_DISPLAY2:	LED逐個右移點亮
	CJNE	A,#20H,	MODE3	;判斷是否為模式2
	MOV	A,KEY_VALUE	
	ANL	A,#0FH		;屏蔽高四位
TIME21:
	CJNE	A,#01H,TIME22	;判斷顯示時間是否為0。5S
	JNB	T05flag,TIME25	;出口返回
	CLR	T05flag		;清0。5S到時間標志位
	LCALL	LED_DISPLAY2	;調顯示方式2
	LJMP	TIME25	;出口返回
TIME22:
	CJNE	A,#02H,TIME23	;判斷顯示時間是否為1。0S
	JNB	T10flag,TIME25	;出口返回
	CLR	T10flag		;清1。0S到時間標志位