;********************MCOBCDROR********************
;本程序實現多字節壓縮BCD碼循環右移1位。
;入口參數: 原數據地址在SADR中,字節數在CNT中。
;出口參數: 結果首地址在SADR中,字節數在CNT中,移出位在SOU中。
;占用資源: W,STATUS,FSR,020H,023H,024H,028H,一重堆棧。
;說    明: 1.原數據將被沖掉.

           IFNDEF       MCOBCDROR1
            #DEFINE     MCOBCDROR1
MCOBCDROR   DECF        CNT,W
            ADDWF       SADR,W
            MOVWF       FSR         ;末地址
            MOVWF       TEMP1
            CLRF        SOU
NEXT14      MOVLW       0FH
            ANDWF       INDF,W
            SWAPF       SOU,F
            IORWF       SOU,F
            MOVLW       0F0H
            ANDWF       INDF,F
            ANDWF       SOU,W
            SWAPF       INDF,F
            IORWF       INDF,F
            MOVLW       0FH
            ANDWF       SOU,F       ;SOU低4位:INDF右移1位
            DECF        FSR,F
            DECFSZ      CNT,F
            GOTO        NEXT14
            MOVF        TEMP1,W     ;移出位送往最高位
            MOVWF       FSR
            SWAPF       SOU,W
            IORWF       INDF,F
            DECF        SADR,W
            SUBWF       TEMP1,W
            MOVWF       CNT         ;恢復字節數
            RETURN
           ENDIF