VERSION 5.00
Object = "{5E9E78A0-531B-11CF-91F6-C2863C385E30}#1.0#0"; "msflxgrd.ocx"
Begin VB.Form frmWZSetup 
   Caption         =   "產(chǎn)品設(shè)置信息列表"
   ClientHeight    =   4908
   ClientLeft      =   48
   ClientTop       =   348
   ClientWidth     =   7740
   LinkTopic       =   "Form1"
   MDIChild        =   -1  'True
   ScaleHeight     =   4908
   ScaleWidth      =   7740
   WindowState     =   2  'Maximized
   Begin VB.Frame Frame2 
      Caption         =   "記錄操作"
      Height          =   972
      Left            =   960
      TabIndex        =   2
      Top             =   3840
      Width           =   6000
      Begin VB.CommandButton cmdDelete 
         Caption         =   "刪除"
         Height          =   375
         Left            =   4080
         TabIndex        =   5
         Top             =   360
         Width           =   1700
      End
      Begin VB.CommandButton cmdModify 
         Caption         =   "修改"
         Height          =   375
         Left            =   2160
         TabIndex        =   4
         Top             =   360
         Width           =   1700
      End
      Begin VB.CommandButton cmdAdd 
         Caption         =   "添加"
         Height          =   375
         Left            =   240
         TabIndex        =   3
         Top             =   360
         Width           =   1700
      End
   End
   Begin MSFlexGridLib.MSFlexGrid msgList 
      Height          =   3132
      Left            =   120
      TabIndex        =   0
      Top             =   600
      Width           =   7452
      _ExtentX        =   13145
      _ExtentY        =   5525
      _Version        =   393216
      Cols            =   4
      FixedCols       =   3
      AllowUserResizing=   1
   End
   Begin VB.Label lblTitle 
      Caption         =   "產(chǎn)  品  設(shè)  置  信  息  列  表"
      BeginProperty Font 
         Name            =   "宋體"
         Size            =   12
         Charset         =   134
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      ForeColor       =   &H8000000D&
      Height          =   252
      Left            =   1680
      TabIndex        =   1
      Top             =   120
      Width           =   3012
   End
End
Attribute VB_Name = "frmWZSetup"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Public txtSQL As String
Dim mrc As ADODB.Recordset

Private Sub cmdAdd_Click()
    gintWZSmode = 1
    frmWZSetup1.Show 1
    
End Sub

Private Sub cmdDelete_Click()
    Dim txtSQL As String
    Dim intCount As Integer
    Dim mrc As ADODB.Recordset
    Dim MsgText As String
    
    
    If msgList.Rows > 1 Then
        If MsgBox("真的要刪除款號為" & Trim(msgList.TextMatrix(msgList.Row, 1)) & "的記錄嗎？", vbOKCancel + vbExclamation, "警告") = vbOK Then
            intCount = msgList.Row
                        
            txtSQL = "select sum(sl) from kucun where wzdm ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
            
            Set mrc = ExecuteSQL(txtSQL, MsgText)
            
            If Not mrc.EOF Then
                If mrc.Fields(0) > 0 Then
                    MsgBox "庫存中仍存在" & Trim(msgList.TextMatrix(intCount, 2)) & ",不能進(jìn)行刪除操作！", vbOKOnly, "警告"
                    Exit Sub
                Else
                    txtSQL = "delete from dm_wz where dm ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
                    Set mrc = ExecuteSQL(txtSQL, MsgText)
                    
                    txtSQL = "delete from kucun where dm='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
                    Set mrc = ExecuteSQL(txtSQL, MsgText)
                End If
            Else
                txtSQL = "delete from dm_wz where dm ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
                Set mrc = ExecuteSQL(txtSQL, MsgText)
                
                txtSQL = "delete from kucun where dm='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
                Set mrc = ExecuteSQL(txtSQL, MsgText)
                
            End If
                
            
            Unload frmWZSetup
            frmWZSetup.txtSQL = "select * from dm_wz"
            frmWZSetup.Show
        End If
    End If


End Sub

Private Sub cmdModify_Click()
    Dim intCount As Integer
    
    If frmWZSetup.msgList.Rows > 1 Then
        gintWZSmode = 2
        intCount = msgList.Row
        If intCount > 0 Then
           frmWZSetup1.txtSQL = "select * from dm_wz where dm ='" & Trim(msgList.TextMatrix(intCount, 1)) & "'"
           frmWZSetup1.Show 1
        Else
            MsgBox "警告", vbOKOnly + vbExclamation, "請首先選擇需要修改的紀(jì)錄！"
        End If
    End If

End Sub



Private Sub Form_Load()
    ShowTitle
    ShowData
    
End Sub

Private Sub Form_Resize()
    If Me.WindowState <> vbMinimized And fMainForm.WindowState <> vbMinimized Then
        '邊界處理
        If Me.ScaleHeight < 10 * lblTitle.Height Then
            
            Exit Sub
        End If
        If Me.ScaleWidth < lblTitle.Width + lblTitle.Width / 2 Then
            
            Exit Sub
        End If
        '控制控件的位置
                
        lblTitle.Top = lblTitle.Height
        lblTitle.Left = (Me.Width - lblTitle.Width) / 2
        
        msgList.Top = lblTitle.Top + lblTitle.Height + lblTitle.Height / 2
        msgList.Width = Me.ScaleWidth - 200
        msgList.Left = Me.ScaleLeft + 100
        msgList.Height = Me.ScaleHeight - msgList.Top - 1500
        
        Frame2.Top = msgList.Top + msgList.Height + 50
        Frame2.Left = Me.ScaleWidth / 2 - 3000
    End If
End Sub



Public Sub FormClose()
    Unload Me
End Sub
Private Sub ShowData()
    
    Dim j As Integer
    Dim i As Integer
    Dim MsgText As String

  
    Set mrc = ExecuteSQL(txtSQL, MsgText)
        With msgList
        .Rows = 1
        
        Do While Not mrc.EOF
            .Rows = .Rows + 1
            For i = 1 To mrc.Fields.Count
                If Not IsNull(Trim(mrc.Fields(i - 1))) Then
                Select Case mrc.Fields(i - 1).Type
                    Case adDBDate
                        .TextMatrix(.Rows - 1, i) = Format(mrc.Fields(i - 1) & "", "yyyy-mm-dd")
                    Case Else
                        .TextMatrix(.Rows - 1, i) = mrc.Fields(i - 1) & ""
                End Select
                End If
            Next i
            mrc.MoveNext
        Loop
        
          
    End With
    mrc.Close
    
    
End Sub


'顯示Grid表頭
Private Sub ShowTitle()
    Dim i As Integer
    
    With msgList
        .Cols = 11
        .TextMatrix(0, 1) = "款號"
        .TextMatrix(0, 2) = "名稱"
        .TextMatrix(0, 3) = "單位"
        .TextMatrix(0, 4) = "類別"
        .TextMatrix(0, 5) = "入庫價格"
        .TextMatrix(0, 6) = "分銷價格"
        .TextMatrix(0, 7) = "零售價格"
        .TextMatrix(0, 8) = "生產(chǎn)廠家"
        .TextMatrix(0, 9) = "設(shè)置日期"
        .TextMatrix(0, 10) = "備注信息"
        
       
        
        '固定表頭
        .FixedRows = 1
                
        '設(shè)置各列的對齊方式
        For i = 0 To 10
            .ColAlignment(i) = 0
        Next i
        
        
        '表頭項居中
        .FillStyle = flexFillRepeat
        .Col = 0
        .Row = 0
        .RowSel = 1
        .ColSel = .Cols - 1
        .CellAlignment = 4
        
        '設(shè)置單元大小
        .ColWidth(0) = 1000
        .ColWidth(1) = 1000
        .ColWidth(2) = 2000
        .ColWidth(3) = 1000
        .ColWidth(4) = 1000
        .ColWidth(5) = 1000
        .ColWidth(6) = 1000
        .ColWidth(7) = 1000
        .ColWidth(8) = 1000
        .ColWidth(9) = 1000
        .ColWidth(10) = 1000
        .Row = 1
        
    End With
End Sub




Private Sub msgList_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
    '右鍵彈出
    If Button = 2 And Shift = 0 Then
       
    End If
    
End Sub