VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CBill_BOSShow"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Attribute VB_Description = "This is BillEvent Interface Class, made by K3BOSPLUGINSWIZAED"
 
'定義 BillEvent 接口. 必須具有的聲明, 以此來獲得事件
Private WithEvents m_BillInterface  As BillEvent
Attribute m_BillInterface.VB_VarHelpID = -1
 
Public Sub Show(ByVal oBillInterface As Object)
 
    'BillEvent 接口實現
    '注意: 此方法必須存在, 請勿修改
    Set m_BillInterface = oBillInterface
 
End Sub

Private Sub Class_Terminate()
 
    '釋放接口對象
    '注意: 此方法必須存在, 請勿修改
    Set m_BillInterface = Nothing

End Sub

Private Sub m_BillInterface_AfterLoadBill()
    If bBilledit Then
        '如果是點了序事簿變更按鈕的話，則在打開單據時使保存按鈕可見和可用屬性變為真
        m_BillInterface.SetBarStatus "mnuFileSave", "Visible", True
        m_BillInterface.SetBarStatus "mnuFileSave", "Enabled", True
        '刷新菜單對象
        m_BillInterface.MenuBar.Refresh
        '重新賦單據的標題
        m_BillInterface.SetBillFormCaption m_BillInterface.BillName & "-變更"
        'm_billinterface.billentrys(1)(1)
    End If
End Sub

'Private Sub m_BillInterface_BeforeSelBills(ByVal lSelBillType As Long, ByVal oDataSrv As Object, ByVal dctLink As Object, sFilter As String, dctParam As Object)
'  If lSelBillType = -72 Then
'     sFilter = "v1.FCheckerID>0 and v1.FHeadSelfP0334>0"
'  Else
'     sFilter = "v1.FCheckerID>0 and v1.FHeadSelft0232>0"
'  End If
'End Sub


Private Sub m_BillInterface_AfterNewBill()
   '改變默認分錄行數為2000行
  m_BillInterface.BillEntrys(1).MaxRows = 2000
  '新增時插入一行
  '注意：對于基礎類型的字段只要提供代碼即可，而不是內碼
  m_BillInterface.InsertNewRowAndFill 2, 1, "FItemid", "01.001", "FMustQty", 100, "FCommitQty", 100, "FPrice", 1500

End Sub
'描述: 單據打開事件前處理函數
'版本: V10 0.3
'作者: Christin
'參數:
'返回值:
'創建時間: 2006-06-12
Private Sub m_BillInterface_BeforLoadBillFillData()

    If bBilledit Then
        '如果是點了序事簿變更按鈕則將單據狀態改為可修改
        '注意：改變狀態的語句只有放在此事件中只能起作用，放在afterload事件無效
        m_BillInterface.BillCtl.BillStatus = Enu_BillStatusExt_Modify
    End If
End Sub

Private Sub m_BillInterface_Change(ByVal dct As KFO.IDictionary, ByVal dctFld As KFO.IDictionary, ByVal Col As Long, ByVal Row As Long, Cancel As Boolean)
  '如果單據頭金額字段大于10000，則將單據頭備注字段鎖定
  If UCase(dct("FKey")) = "FTOTALAMOUNT" Then
     If dctFld("FFLD") > 10000 Then
        m_BillInterface.BillHeads(1).BOSFields("FNote").FieldLock = True
     Else
        m_BillInterface.BillHeads(1).BOSFields("FNote").FieldLock = False
     End If
  End If
End Sub

Private Sub m_BillInterface_MenuBarInitialize(ByVal oMenuBar As K3ClassEvents.MenuBar)
  Dim oBand As K3ClassEvents.BOSBand
  Dim oTool As K3ClassEvents.BOSTool
    
  
  '增加復制菜單在工具欄上的顯示
  Set oTool = oMenuBar.BOSTools("mnuEditCopy")
  With oTool
    .Caption = "復制"
    .ToolTipText = "復制"
    .Description = "復制"
    .BeginGroup = False
    '清空剪貼板里的內容
    Clipboard.Clear
    '從資源文件從讀取預先保存的圖片　須注意此處客戶內存不足時有可能執行失敗
    Clipboard.SetData LoadResPicture(101, vbResBitmap), vbCFBitmap
    .PasteToolFace
  End With
  Set oBand = oMenuBar.BOSBands("BandToolBar")
  oBand.BOSTools.InsertBefore "mnuCaculate", oTool '將菜單對象插入指定工具欄
  
  '隱藏頁面設置菜單
  Set oBand = oMenuBar.BOSBands("mnuFile")
  Set oTool = oBand.BOSTools("mnuFilePageSetup")
  With oTool
     .Visible = False
     .Enabled = True
  End With

  

End Sub