DATA   SEGMENT
LINE   DW   0                     ;矩形塊左上角的行
ROW    DW   0                     ;矩形塊左上角的列
PIX    DB   0                    ;矩形塊的顏色
DATA   ENDS

CODE         SEGMENT
             ASSUME  CS:CODE,DS:DATA
START:                               ;主程序
             MOV AX , DATA
             MOV DS , AX
             MOV AH , 0
             MOV AL , 4
             INT 10H                 ;設(shè)置320×200彩色圖形方式
             
             mov ah,0bh
             mov bh,01
             mov bl,0
             int 10h
             MOV CX, 4
L1:
             CALL DISP_RECT
             call delay
             inc PIX                 ;每循環(huán)一次，點(diǎn)的顏色加1
             ADD ROW , 30            ;改變下一個(gè)方塊的顯示位置
             LOOP L1
             MOV AH , 4CH
             INT 21H                 ;返回DOS
;顯示矩形塊的子程序，矩形塊的顯示位置由DATA段中的LINE、ROW變量指定，
;顏色由PIX變量指定，矩形塊的大小是固定的，為10個(gè)點(diǎn)寬，100個(gè)點(diǎn)高。
DISP_RECT    PROC  near
             PUSH AX
             PUSH CX
             PUSH DX
             PUSH SI
             PUSH DI
             MOV AH , 0CH       ;指明寫點(diǎn)調(diào)用
             MOV AL , PIX       ;取點(diǎn)的顏色
             MOV DI , 100       ;用于控制行顯示循環(huán)
             MOV DX , LINE      ;取點(diǎn)的行坐標(biāo)
DISP_2: 
             MOV SI , 10        ;控制列顯示循環(huán)
             MOV CX , ROW       ;取顯示點(diǎn)的列坐標(biāo)
DISP_1: 
             INT 10H            ;完成點(diǎn)的顯示
             INC CX             ;列坐標(biāo)加1（行不變）
             DEC SI
             JNZ DISP_1         ;循環(huán)顯示完一行的10個(gè)點(diǎn)
             INC DX             ;行坐標(biāo)加1
             DEC DI
             JNZ DISP_2         ;循環(huán)顯示完100行
             POP DI
             POP SI
             POP DX
             POP CX
             POP AX
             RET
DISP_RECT    ENDP
delay        proc near       
             push cx
             push dx
             mov dx,5000
d11:         mov cx,25000  
d12:         loop d12
             dec   dx
             jnz   d11
             pop   dx
             pop   cx
             ret
delay        endp
CODE         ENDS
             END  START