/*========== 生成月結數據庫 ==========*/
/*--要求描述

	數據庫名格式為: xxYYYYMM,即指定的前緣xx+年月
	要求在每個月末自動復制本月數據庫,生成下個月的空數據庫
--*/

--方法1. 備份+恢復
use master
go

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[sp_ProcCopyDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[sp_ProcCopyDb]
GO

/*--數據庫自動復制
	
	將指定前緣的數據庫,復制為一個以當前月份+1為庫名的數據庫中,并且清除所有的數據
	例如,數據庫前緣為 Pos ,當前日期為 2005-3-27
	則要求復制數據 Pos200503 為 Pos200504,并且清空里面的數據

	用備份+恢復的方法實現
	好處是在清理數據時,可以設置條件,保留指定的數據
	不好的地方是數據多時,速度慢,消耗的資源多

--鄒建 2005.03(引用請保留此信息)--*/

/*--調用示例

	-- 復制 Pos
	exec sp_ProcCopyDb 'Pos'
--*/
create proc sp_ProcCopyDb
@DB_Head sysname=N''  --數據庫前綴
as
declare @sdbname sysname,@ddbname sysname
declare @s Nvarchar(4000),@bkfile Nvarchar(1000),@move Nvarchar(4000)

--復制的源庫名及目標庫名
if @DB_Head is null set @DB_Head=N''

select @sdbname=@DB_Head+convert(char(6),getdate(),112),
	@ddbname=@DB_Head+convert(char(6),dateadd(month,1,getdate()),112)

if db_id(@sdbname) is null
begin
	raiserror(N'源數據庫"%s"不存在',1,16,@sdbname)
	return
end

if db_id(@ddbname) is not null
begin
	raiserror(N'目標數據庫"%s"已經存在',1,16,@ddbname)
	return
end

--臨時備份文件名
select top 1 @bkfile=rtrim(reverse(filename)) 
from master.dbo.sysfiles 
where name=N'master'
select @bkfile=stuff(@bkfile,1,charindex('\',@bkfile),N'')
	,@bkfile=reverse(stuff(@bkfile,1,charindex('\',@bkfile),N''))
	+N'\BACKUP\'+cast(newid() as nvarchar(36))+N'.bak'

--數據文件移動語句
set @s=N'set @move=N''''
select @move=@move
	+N'',move ''+quotename(rtrim(name),N'''''''')
	+N'' to ''+quotename(rtrim(case 
		when charindex(N'
	+quotename(@sdbname,N'''')
	+N',filename)>0
		then stuff(filename,charindex(N'
	+quotename(@sdbname,N'''')
	+N',filename),'
	+cast(len(@sdbname) as nvarchar)
	+N',N'+quotename(@ddbname,N'''')+N')
		else reverse(stuff(
			reverse(filename),
			charindex(''\'',reverse(filename)),
			0,
			+N''_''+reverse(N'+quotename(@ddbname,N'''')+N')))
		end),N'''''''')
from '+quotename(@sdbname)+N'.dbo.sysfiles'
exec sp_executesql @s,N'@move Nvarchar(4000) out',@move out

--備份源數據庫
set @s=N'backup database '+quotename(@sdbname)+N' to disk=@bkfile with format'
exec sp_executesql @s,N'@bkfile Nvarchar(1000)',@bkfile

--還原為目標數據庫
set @s=N'restore database '
	+quotename(@ddbname)
	+N' from disk=@bkfile with replace'
	+@move
exec sp_executesql @s,N'@bkfile Nvarchar(1000)',@bkfile

--刪除臨時備份文件
set @s='del "'+@bkfile+'"'
exec master..xp_cmdshell @s,no_output

--清理目標數據庫中的所有數據
set @s=N'
use '+quotename(@ddbname)+N'
exec sp_msforeachtable 
	@command1=N''truncate table ?'',
	@whereand=N'' and objectproperty(o.id,N''''TableHasForeignRef'''')=0''
exec sp_msforeachtable 
	@command1=N''delete from ?'',
	@whereand=N'' and objectproperty(o.id,N''''TableHasForeignRef'''')=1''
'
exec sp_executesql @s
go


/*=================================================================*/

--方法2. 腳本復制
use master
go

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[sp_ProcCopyDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[sp_ProcCopyDb]
GO

/*--數據庫自動復制
	
	將指定前緣的數據庫,復制為一個以當前月份+1為庫名的數據庫中,并且清除所有的數據
	例如,數據庫前緣為 Pos ,當前日期為 2005-3-27
	則要求復制數據 Pos200503 為 Pos200504,并且清空里面的數據

	用生成源庫腳本的方法實現
	好處是速度快,不需要考慮源數據庫的數據
	但如果要保留源數據庫的部分數據,則要專門做數據復制處理

--運行需求
	需要如下兩個文件,可以在sql安裝盤 X86\UPGRADE 目錄下找到
	scptxfr.exe
	scptxfr.rll

	將其復制到下述目錄
	%systemroot%\system32\
--鄒建 2005.03(引用請保留此信息)--*/

/*--調用示例

	-- 復制 Pos
	exec sp_ProcCopyDb 'Pos'
--*/
create proc sp_ProcCopyDb
@DB_Head sysname=N''  --數據庫前綴
as
declare @sdbname sysname,@ddbname sysname
declare @s Nvarchar(4000),@bkfile Nvarchar(1000)

--復制的源庫名及目標庫名
select @sdbname=@DB_Head+convert(char(6),getdate(),112),
	@ddbname=@DB_Head+convert(char(6),dateadd(month,1,getdate()),112)

if db_id(@sdbname) is null
begin
	raiserror(N'源數據庫"%s"不存在',1,16,@sdbname)
	return
end

if db_id(@ddbname) is not null
begin
	raiserror(N'目標數據庫"%s"已經存在',1,16,@ddbname)
	return
end

--臨時備份文件名
select top 1 @bkfile=rtrim(reverse(filename)) 
from master.dbo.sysfiles 
where name=N'master'
select @bkfile=stuff(@bkfile,1,charindex('\',@bkfile),N'')
	,@bkfile=reverse(stuff(@bkfile,1,charindex('\',@bkfile),N''))
	+N'\BACKUP\'+cast(newid() as nvarchar(36))+N'.sql'

--腳本生成處理
set @s=N'scptxfr /s '+quotename(cast(serverproperty(N'servername') as nvarchar),N'"')
	+N' /d '+quotename(@sdbname,N'"')
	+N' /I'  --使用windows身份驗證,如果使用sql身份驗證,則愀為 +N' /P "sa密碼"',固定使用sa用戶
	+N' /f '+quotename(@bkfile,N'"')
	+N' /Y /q /T /C /Y'
exec master..xp_cmdshell @s,no_output

--創建目標數據庫
set @s=N'create database '+quotename(@ddbname)
exec sp_executesql @s

--使用源庫腳本,為目標數據庫創建對象
set @s=N'osql /S'+quotename(cast(serverproperty(N'servername') as nvarchar),N'"')
	+N' /d '+quotename(@ddbname,N'"')
	+N' /E'  --使用windows身份驗證,如果使用sql身份驗證,則愀為 +N' /U"sa" /P"sa密碼"'
	+N' /i'+quotename(@bkfile,N'"')
exec master..xp_cmdshell @s,no_output

--刪除臨時備份文件
set @s='del "'+@bkfile+'"'
exec master..xp_cmdshell @s,no_output
go



/*=================================================================*/

--創建一個每月最后一個工作日執行的作業,調用上述存儲過程實現自動創建數據庫

use master
go

--設置 SQL Agent 服務為自動啟動
exec msdb..sp_set_sqlagent_properties @auto_start=1
go

--創建作業
exec msdb..sp_add_job @job_name=N'自動建庫處理'

--創建作業步驟
declare @sql varchar(800),@dbname varchar(250)
select @sql=N'exec sp_ProcCopyDb'  --調用自動建庫的存儲過程
	,@dbname=db_name()         --執行自動建庫處理的數據庫名

exec msdb..sp_add_jobstep @job_name=N'自動建庫處理',
	@step_name = '建庫處理',
	@subsystem = 'TSQL',
	@database_name=@dbname,
	@command = @sql,
	@retry_attempts = 5, --重試次數
	@retry_interval = 5  --重試間隔

--添加作業調度(每月最后一個工作日)
EXEC msdb.dbo.sp_add_jobschedule @job_name = N'自動建庫處理', 
	@name = N'時間安排',
	@freq_type = 32, 
	@active_start_time = 0,  --0點開始執行
	@freq_interval = 9,      --每月最后一個工作日
	@freq_subday_type = 1, 
	@freq_subday_interval = 0, 
	@freq_relative_interval = 16, 
	@freq_recurrence_factor = 1
	
-- 添加目標服務器
EXEC msdb.dbo.sp_add_jobserver 
	@job_name = N'自動建庫處理' ,
	@server_name = N'(local)'