if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_changeusertype]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_changeusertype]
GO

/*--存儲過程功能說明
	
	修改當前庫中定義的用戶定義數據類型的長度及精度
	并自動修改所有的表/視圖/存儲過程/觸發器/自定義函數中的對應定義
	由于數據庫的復雜性,建議修改前先備份

--作者:鄒建 2004.06--*/

/*--調用示例
	
	exec p_changeusertype 'test','nvarchar(20)'
--*/
create proc p_changeusertype
@typename sysname,	--要修改的用戶定義數據類型名
@newdef sysname,	--新的用戶定義數據類型的定義
@allownull bit=1,	--新的用戶定義數據類型是否允許NULL,為1表示允許,為0表示不允許
@deloldtype bit=1	--是否在處理完成后刪除舊的用戶定義數據類型,默認為刪除
as
declare @bktypename nvarchar(36)

if not exists(select 1 from systypes where name=@typename)
begin
	print '------------------------------------------------'
	print ' 要修改的用戶定義數據類型不存在'
	print '------------------------------------------------'
	return
end

set nocount on
set @bktypename=cast(newid() as varchar(36))
print '------------------------------------------------'
print ' 原來的用戶定義數據類型將被改名為: '+@bktypename
print '------------------------------------------------'

set xact_abort on
begin tran
	--1.修改舊用戶定義數據類型的名稱
	exec sp_rename @typename,@bktypename,'USERDATATYPE'

	--2.新增用戶定義數據類型(按新的定義)
	if @allownull=1
		exec sp_addtype @typename,@newdef,N'null'
	else
		exec sp_addtype @typename,@newdef,N'not null'

	declare hCForEach cursor global for 
	--修改表結構定義的處理語句
	select 'alter table ['+replace(user_name(uid), N']',N']]')+'].['
		+replace(object_name(id),N']',N']]')+'] alter column ['
		+replace(a.name,N']',N']]')+'] '+@typename
	from syscolumns a join systypes b on a.xusertype=b.xusertype
	where b.name=@bktypename and objectproperty(a.id,N'isusertable')=1
	union all	--刷新視圖的語句
	select 'exec sp_refreshview ''['+replace(user_name(uid), N']',N']]')+'].['
		+replace(object_name(id),N']',N']]')+']'''
	from dbo.sysobjects
	where xtype='v' and status>=0
	union all	--刷新存儲過程,自定義函數,觸發器的語句
	select 'exec sp_recompile ''[' + replace(user_name(uid), N']', N']]')+'].['
		+ replace(object_name(id), N']', N']]')+ ']'''
	from dbo.sysobjects
	where xtype in('tr','fn','if','tf','p') and status>=0
	
	exec sp_msforeach_worker '?'

	if @deloldtype=1
		exec sp_droptype @bktypename
commit tran
set nocount off
go