?? wl011.asm
字號:
;********************************************************************************
;* 標題: 偉納電子ME300B單片機開發系統演示程序 - 數碼管顯示秒表 *
;* 文件: wl011.asm *
;* 日期: 2004-1-5 *
;* 版本: 1.0 *
;* 作者: 偉納電子 - Freeman *
;* 郵箱: freeman@willar.com *
;* 網站： http://www.willar.com *
;********************************************************************************
;* 描述: *
;* 數碼管顯示秒表 *
;* K1---控制按鈕 *
;* 第一次按下時, 啟動開始計時 *
;* 第二次按下時, 停止 *
;* 第三次按下時, 歸零 *
;* *
;* 秒單位,寄存器與數碼管對應關系: *
;* *
;* --- 秒單位 ---------- 數碼管端口 ---- 緩沖區 --------- 計時(BCD碼)值寄存器 *
;* 十萬位 P20 dis_buf[7] sec_bcd[7] *
;* 萬位 P21 dis_buf[6] sec_bcd[6] *
;* 千位 P22 dis_buf[5] sec_bcd[5] *
;* 百位 P23 dis_buf[4] sec_bcd[4] *
;* 十位 P24 dis_buf[3] sec_bcd[3] *
;* 個位(1.s) P25 dis_buf[2] sec_bcd[2] *
;* 十分位(0.1s) P26 dis_buf[1] sec_bcd[1] *
;* 百分位(0.01s) P27 dis_buf[0] sec_bcd[0] *
;* *
;********************************************************************************
;* 【版權】 Copyright(C)偉納電子 www.willar.com All Rights Reserved *
;* 【聲明】 此程序僅用于學習與參考，引用請注明版權和作者信息！ *
;********************************************************************************
NAME WL011
CODE_SEG SEGMENT CODE
DATA_SEG SEGMENT DATA
STACK_SEG SEGMENT IDATA
RSEG DATA_SEG
KEY_S: DS 1
KEY_V: DS 1
DIS_DIGIT: DS 1
DIS_INDEX: DS 1
SEC_BCD: DS 8 ; 秒計數值, BCD碼
KEY_TIMES: DS 1 ; K1 按下次數
DIS_BUF: DS 8 ; 顯示緩沖區
RSEG STACK_SEG
STACK: DS 20
K1 BIT P1.4
;===============================================================================
CSEG AT 0000H
LJMP MAIN
CSEG AT 0000BH
LJMP TIMER0
CSEG AT 0001BH
LJMP TIMER1
;===============================================================================
RSEG CODE_SEG
MAIN:
USING 0
MOV SP,#(STACK-1)
MOV P0,#0FFH ; 初始化端口
MOV P2,#0FFH
MOV TMOD,#011H ;
MOV TH1,#0DCH
CLR A
MOV TL1,A
MOV TH0,#0FCH
MOV TL0,#017H
LCALL CLR_TIME ; 清零計時值
MOV DIS_DIGIT,#07FH ; 上電時選通P27數碼管
CLR A
MOV DIS_INDEX,A
MOV KEY_TIMES,A
MOV KEY_V,#01H
MOV IE,#08AH ; 使能timer0, timer1中斷
SETB TR0
CLR TR1
MAIN_LP:
LCALL SCAN_KEY ; 鍵掃描
JZ MAIN_LP ; 無鍵返回
MOV R7,#10 ; 延時10ms
LCALL DELAYMS ; 延時去抖動
LCALL SCAN_KEY ; 再次掃描
JZ MAIN_LP ; 無鍵返回
MOV KEY_V,KEY_S ; 保存鍵值
LCALL PROC_KEY ; 鍵處理
SJMP MAIN_LP ; 調回主循環
; END OF main
;===============================================================================
CLR_TIME:
CLR A
MOV SEC_BCD,A ; 清零所有計時值
MOV SEC_BCD+01H,A
MOV SEC_BCD+02H,A
MOV SEC_BCD+03H,A
MOV SEC_BCD+04H,A
MOV SEC_BCD+05H,A
MOV SEC_BCD+06H,A
MOV SEC_BCD+07H,A
LJMP UPDATE_DISBUF ; 更新顯示緩沖區
; END OF CLR_TIME
;===============================================================================
SCAN_KEY:
CLR A
MOV KEY_S,A
MOV C,K1 ; 讀按鍵狀態
RLC A
ORL KEY_S,A
MOV A,KEY_S
XRL A,KEY_V ;
RET
; END OF scan_key
;===============================================================================
PROC_KEY:
MOV A,KEY_V
JB ACC.0,END_PROC_KEY
INC KEY_TIMES
MOV A,KEY_TIMES
CJNE A,#01H,PROC_KEY1
SETB TR1 ; KEY_TIMES = 1,第一次按下K1, 啟動開始計時
RET
PROC_KEY1:
MOV A,KEY_TIMES
CJNE A,#02H,PROC_KEY2
CLR TR1 ; KEY_TIMES = 2, 第二次按下K1, 停止計時
RET
PROC_KEY2:
LCALL CLR_TIME ; 第三次按下K1, 清零計時值
CLR A
MOV KEY_TIMES,A ; 清零KEY_TIMES
END_PROC_KEY:
RET
;===============================================================================
TIMER0:
; 定時器0中斷服程序, 用于數碼管的動態掃描
; DIS_INDEX --- 顯示索引, 用于標識當前顯示的數碼管和緩沖區的偏移量
; DIS_DIGIT --- 位選通值, 傳送到P2口用于選通當前數碼管的數值, 如等于0xfe時,
; 選通P2.0口數碼管
; DIS_BUF --- 顯于緩沖區基地址
PUSH ACC
PUSH PSW
PUSH AR0
MOV TH0,#0FCH
MOV TL0,#017H
MOV P2,#0FFH ; 先關閉所有數碼管
MOV A,#DIS_BUF ; 獲得顯示緩沖區基地址
ADD A,DIS_INDEX ; 獲得偏移量
MOV R0,A ; R0 = 基地址 + 偏移量
MOV A,@R0 ; 獲得顯示代碼
MOV P0,A ; 顯示代碼傳送到P0口
MOV P2,DIS_DIGIT ;
MOV A,DIS_DIGIT ; 位選通值右移(P20<-P27), 下次中斷時選通下一位數碼管
RR A
MOV DIS_DIGIT,A
INC DIS_INDEX ; DIS_INDEX加1, 下次中斷時顯示下一位
ANL DIS_INDEX,#0x07 ; 當DIS_INDEX等于8(0000 1000)時, 清0
POP AR0
POP PSW
POP ACC
RETI
; END OF timer0
;===============================================================================
TIMER1:
PUSH ACC
PUSH B
PUSH DPH
PUSH DPL
PUSH PSW
PUSH AR7
ORL TH1,#0DCH ; 恢復定時器初值
CLR A
MOV R7,A
MOV A,#LOW (SEC_BCD)
MOV R0,A ; 計時值寄存器地址到R0
TIMER_INC: ;
INC @R0 ; 計時值加1
MOV A,@R0
CLR C
SUBB A,#10 ;
JC END_INC ; 如果低位不滿10, 則結束
MOV @R0,#00H ; 低位滿10, 清零低位
INC R0 ; 指向高位
INC R7 ;
CJNE R7,#08H,TIMER_INC ; 如果達到最高位, 則結束
END_INC:
LCALL UPDATE_DISBUF
POP AR7
POP PSW
POP DPL
POP DPH
POP B
POP ACC
RETI
; END OF timer1
;===============================================================================
UPDATE_DISBUF:
; 根據計時寄存器的值更新顯示緩沖區
MOV DPTR,#DIS_CODE ; 保存表格地址
MOV A,sec_bcd
MOV DPTR,#dis_code
MOVC A,@A+DPTR ; 獲得顯示代碼
MOV dis_buf,A ; 更新顯示緩沖區
MOV A,sec_bcd+01H
MOVC A,@A+DPTR
MOV dis_buf+01H,A
MOV A,sec_bcd+02H
MOVC A,@A+DPTR
ANL A,#07FH ; 顯示小數點
MOV dis_buf+02H,A
MOV A,sec_bcd+03H
MOVC A,@A+DPTR
MOV dis_buf+03H,A
MOV A,sec_bcd+04H
MOVC A,@A+DPTR
MOV dis_buf+04H,A
MOV A,sec_bcd+05H
MOVC A,@A+DPTR
MOV dis_buf+05H,A
MOV A,sec_bcd+06H
MOVC A,@A+DPTR
MOV dis_buf+06H,A
MOV A,sec_bcd+07H
MOVC A,@A+DPTR
MOV dis_buf+07H,A
RET
; END OF UPDATE_DISBUF
;===============================================================================
DELAYMS:
; 延時子程序
; 傳入參數：R7 --- 延時值(MS)
; 返回值：無
MOV A,R7
JZ END_DLYMS
DLY_LP1:
MOV R6,#185
DLY_LP2:
NOP
NOP
NOP
DJNZ R6,DLY_LP2
DJNZ R7,DLY_LP1
END_DLYMS:
RET
; END OF DELAYMS
;===============================================================================
DIS_CODE:
DB 0C0H ; '0'
DB 0F9H ; '1'
DB 0A4H ; '2'
DB 0B0H ; '3'
DB 099H ; '4'
DB 092H ; '5'
DB 082H ; '6'
DB 0F8H ; '7'
DB 080H ; '8'
DB 090H ; '9'
DB 0FFH ; off
END
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -