?? bo hao.asm
字號:
;8位數據傳送方式，雙行顯示，字形5*7點陣。
;開顯示，不顯示光標。
;--------------------------------------------------------
INIT_LCD:
CALL DELAY5MS ;延時15MS
CALL DELAY5MS
CALL DELAY5MS
MOV A,#38H ;雙行顯示，字形5*7點陣，8位數據。
CALL WCOM_NC ;不檢測忙信號
CALL DELAY5MS
MOV A,#38H ;雙行顯示，字形5*7點陣
CALL WCOM_NC ;不檢測忙信號
CALL DELAY5MS
MOV A,#38H ;雙行顯示，字形5*7點陣
CALL WCOM_NC ;不檢測忙信號
CALL DELAY5MS
MOV A,#38H ;雙行顯示，字形5*7點陣
CALL WCOM ;檢測忙信號
CALL DELAY5MS
MOV A,#0CH ;開顯示，不顯示光標，光標不閃爍。
CALL WCOM
CALL DELAY5MS
MOV A,#01H ;清除 LCD 顯示屏
CALL WCOM
CALL DELAY5MS
RET
; ------------------------------------------------
CONV1:
MOV A,@R0
ANL A,#0FH ;取出低四位二進制數
CJNE A,#0AH,CONV2
MOV A,#00H
CONV2:
PUSH ACC ;壓入堆棧
CLR C ;C=0
SUBB A,#0AH ;減10
POP ACC ;彈出堆棧
JC ASCII0 ;該數小于10，轉ASCII0
ADD A,#07H ;大于10的數加上37H
ASCII0: ADD A,#30H ;小于10的數加上30H
MOV B,LCD_X
CALL LCDP2
RET
;--------------------------------------------------------
;在LCD1602的第二行顯示數字
;--------------------------------------------------------
SHOW_DIG2:
MOV B,#10 ;設置被除數
DIV AB ;結果A存商數，B存余數
ADD A,#30H ;A為十位數，轉換為字符
PUSH B ;B放入堆棧暫存
MOV B,LCD_X ;設置 LCD 顯示的位置
CALL LCDP2 ;由 LCD 顯示出來
POP B ;
MOV A,B ;B為個位數
ADD A,#30H ;轉換為字符
INC LCD_X ;LCD 顯示位置加1
MOV B,LCD_X ;設置 LCD 顯示的位置
CALL LCDP2 ;由 LCD 顯示出來
RET
;--------------------------------------------------------
;在LCD的第二行顯示字符
;--------------------------------------------------------
LCDP2:
PUSH ACC ;入棧保護
MOV A,B ;設置顯示地址
ADD A,#0C0H ;設置LCD的第二行地址
CALL WCOM ;寫入命令
POP ACC ;由堆棧取出A
CALL WDATA ;寫入數據
RET
;--------------------------------------------------------
;在LCD的第一行或第二行顯示字符
;--------------------------------------------------------
LCD_PRINT:
CJNE A,#1,LINE2 ;判斷是否為第一行
LINE1: MOV A,#80H ;設置 LCD 的第一行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數據
MOV A,#80H ;設置 LCD 的第一行地址
CALL WCOM ;寫入命令
JMP FILL
LINE2: MOV A,#0C0H ;設置 LCD 的第二行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數據
MOV A,#0C0H ;設置 LCD 的第二行地址
CALL WCOM
FILL: CLR A ;填入字符
MOVC A,@A+DPTR ;由信息區取出字符
CJNE A,#0,LC1 ;判斷是否為結束碼
RET
LC1: CALL WDATA ;寫入數據
INC DPTR ;指針加1
JMP FILL ;繼續填入字符
RET
;--------------------------------------------------------
;清除 LCD 指定行的字符
;“空白”的ASCII代碼為20H。
;--------------------------------------------------------
CLR_LINE:
MOV R0,#24
CL1:
MOV A,#20H ;' '
CALL WDATA
DJNZ R0,CL1
RET
;--------------------------------------------------------
;寫控制指令子程序
;寫控制指令到LCD
;傳入參數: ACC(要寫入的指令)
;RS=L,RW=L,E=高脈沖，D0-D7=指令碼 。
;--------------------------------------------------------
WCOM:
ACALL CHECKBUSY
WCOM_NC:
MOV P0,A ;寫入指令
CLR LCD_EN
NOP
NOP
CLR LCD_RS
CLR LCD_RW
SETB LCD_EN
ACALL DEL_250
CLR LCD_EN
RET
;--------------------------------------------------------
;寫數據子程序
;寫顯示數據到LCD
;傳入參數: ACC(要寫入的數據)
;RS=H,RW=L,E=高脈沖，D0-D7=數據碼 。
;--------------------------------------------------------
WDATA:
ACALL CHECKBUSY
MOV P0,A ;寫入數據
CLR LCD_EN
NOP
NOP
SETB LCD_RS
CLR LCD_RW
SETB LCD_EN
CALL DEL_250
CLR LCD_EN
RET
DEL_250:
MOV R7,#125 ;延時250微秒
DJNZ R7,$
RET
;--------------------------------------------------------
;檢測LCD控制器忙碌狀態
;正常讀寫操作之前必須檢測LCD控制器狀態
;BUSY FLAG(P0.7)=1時，忙,不能接收MCU送來的指令和數據。
;BUSY FLAG(P0.7)=0時，閑,能夠接收MCU送來的指令和數據。
;讀數據時
;RS=L,RW=H,E=H,輸出：D0-D7=數據
;--------------------------------------------------------
CHECKBUSY:
PUSH ACC
MOV P0,#0FFH ;置P0口為輸入狀態
CLR LCD_EN
NOP
NOP
SETB LCD_RW
CLR LCD_RS
SETB LCD_EN
BUSYLOOP:
NOP
JB P0.7,BUSYLOOP
CLR LCD_EN
POP ACC
RET
;---------------------------------------------------------
;延時50MS子程序
;---------------------------------------------------------
DELAY50MS:
MOV R6,#100
DEL2: MOV R7,#250
DJNZ R7,$
DJNZ R6,DEL2
RET
;--------------------------------------------------------
;延時5MS子程序
;--------------------------------------------------------
DELAY5MS:
MOV R6,#25
DEL3: MOV R7,#100
DJNZ R7,$
DJNZ R6,DEL3
RET
;===================================================
;
;蜂鳴器響一聲子程序
;
;===================================================
BEEP_BL:
MOV R6,#100
BL1: CALL DEX1
CPL BEEP ;P3.7取反
DJNZ R6,BL1
MOV R5,#50
CALL DELAY
RET
DEX1: MOV R7,#180
DEX2: NOP
DJNZ R7,DEX2
RET
DELAY: ;延時R5×10MS
MOV R6,#40
D1: MOV R7,#100
DJNZ R7,$
DJNZ R6,D1
DJNZ R5,DELAY
RET
;-----------------------------------------------------
;矩陣鍵盤鍵值讀取子程序
;使用R3
;-----------------------------------------------------
KEY_IN:
MOV P1,#0F0H ;置列線為0，行線為1
MOV A,P1
ANL A,#0F0H
MOV B,A
MOV P1,#0FH ;置列線為1，行線為0
MOV A,P1
ANL A,#0FH
ORL A,B ;高四位與低四位重新組合
CJNE A,#0FFH,KEY_IN1 ;0FFH為末按鍵
RET
KEY_IN1:
MOV B,A
MOV DPTR,#KEYTABLE
MOV R3,#0FFH
KEY_IN2:
INC R3
MOV A,R3
MOVC A,@A+DPTR
CJNE A,B,KEY_IN3
MOV A,R3 ;找到，取順序碼
RET
KEY_IN3:
CJNE A,#00H,KEY_IN2 ;末完，繼續查
RET ;00H為結束碼
;*********************************************************
KEYTABLE:
DB 0EEH,0EDH,0EBH,0E7H,0DEH ;0,1,2,3,4, 順序碼
DB 0DDH,0DBH,0D7H,0BEH,0BDH ;5,6,7,8,9,
DB 0BBH,0B7H,07EH,07DH,07BH ;A,B,C,D,E,
DB 077H,00H ;F 00為結束碼
;*********************************************************
END
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -