Attribute VB_Name = "modPublic"
Option Explicit
'***********************************************
'聲明
'***********************************************
'指定下述一個或多個標志 (用OR運算符合并到一起)
'強迫中止沒有響應的進程
Public Const EWX_FORCE = 4
'中止進程，然后注銷
Public Const EWX_LOGOFF = 0
'關掉系統電源（如果可能的話，ATX電源就可以）
Public Const EWX_SHUTDOWN = 1
'重新引導系統
Public Const EWX_REBOOT = 2
'如果可能，關掉電源
Public Const EWX_POWEROFF = 8

'***********************************************
'聲明重啟動Windows的函數
'***********************************************
Private Declare Function SHRestartSystemMB Lib "shell32" Alias "#59" (ByVal hOwner As Long, ByVal sExtraPrompt As String, ByVal uFlags As Long) As Long
Private Declare Function GetActiveWindow Lib "user32" () As Long            'Use Me.hwnd in VB
'***********************************************
'聲明引用winio.dll中的函數
'***********************************************
Declare Function InstallWinIoDriver Lib "winio.dll" _
    (ByRef pszWinIoDriverPath As String, _
    ByVal IsDemandLoaded As Boolean) As Boolean

Declare Function InitializeWinIo Lib "winio.dll" () As Boolean

Declare Function SetPortVal Lib "winio.dll" _
    (ByVal wPortAddr As Integer, ByVal dwPortVal As Integer, _
    ByVal bSize As Byte) As Boolean

Declare Sub ShutdownWinIo Lib "winio.dll" ()
Declare Sub RemoveWinIoDriver Lib "winio.dll" ()
'***********************************************
'聲明結束
'***********************************************

'********************************************************
'功能：提示用戶系統設置更新后是否重新啟動系統
'      用戶點擊“是”則重新啟動，“否”不重新啟動，
'      無選則等待15秒后自動重啟
'參數：[sExtraMessage]  顯示組戶的額外信息
'      [lMode]          以EWX_開頭的常量
'*********************************************************
Function SystemUpdatedRestart(Optional ByVal sExtraMessage As String = vbNullString, Optional lMode As Long = EWX_LOGOFF) As Long
    On Error Resume Next
    If Len(sExtraMessage) Then
        'Format and convert extra message
        If Right$(sExtraMessage, 2) <> vbNewLine Then
            sExtraMessage = sExtraMessage & vbNewLine & vbNewLine
        End If
        sExtraMessage = StrConv(sExtraMessage, vbUnicode)
    End If
    SystemUpdatedRestart = SHRestartSystemMB(GetActiveWindow, sExtraMessage, EWX_FORCE + lMode)
    On Error GoTo 0
End Function

'***********************************************
'功能：將一個字節形的數轉換為二進制數，以字符串形式返回
'***********************************************
Public Function CBin(ByVal Number As Byte) As String
    Dim temp As Byte
    '將1置于一個字節的首位
    temp = &H80
    
    Do Until temp < 1
        If Number >= temp Then  'Number在此位為1
           CBin = CBin + "1"
           Number = Number - temp
        Else                    'Number在此位為0
            CBin = CBin + "0"
        End If
        temp = temp / 2 'temp 所表示的1右移
    Loop '循環直到1從一個字節右端移出去
End Function

'***********************************************
'功能：將一個以字符串形式表示的二進制數轉換為十進制數
'***********************************************
Public Function CDecFromBin(ByVal xBin As String) As Integer
    Dim i As Integer
    Dim res As Integer
    res = 0
    '逐位計算得到
    For i = 1 To Len(xBin)
        res = res * 2 + CByte(Mid(xBin, i, 1))
    Next i
    CDecFromBin = res
End Function