;A15=E的選通信號,A9=R/W,A8=RS
COM      EQU      20H     ;指令寄存器                         
DAT      EQU      21H     ;數(shù)據(jù)寄存器             
CW_Add   EQU      8000H   ;指令口寫地址           
CR_Add   EQU      8200H   ;指令口讀地址           
DW_Add   EQU      8100H   ;數(shù)據(jù)口寫地址            
DR_Add   EQU      8300H   ;數(shù)據(jù)口讀地址
    
;初始化演示程序
 MAIN:  MOV        SP,#60H
        ANL        P3,#0C7H
        LCALL      INT
        LCALL      WRIT
;讀BF和AC值
PRO:     PUSH        DPH 
         PUSH        DPL
         PUSH        ACC
         MOV         DPTR,#CR_Add    ;設(shè)置指令口讀地址
         MOVX	     A,@DPTR         ;讀BF和AC值     
         MOV         COM,A           ;存入COM單元
         POP         ACC
         POP         DPL
         POP         DPH
         RET
;寫指令代碼子程序
PR1:      PUSH     DPH
          PUSH     DPL
          PUSH     ACC
          MOV      DPTR,#CR_Add   ;設(shè)置指令口讀地址
PR11:     MOVX     A,@DPTR
          JB       ACC.7,PR11     ;判BF=0？是繼續(xù)
          MOV      A,COM
          MOV      DPTR,#CW_Add   ;設(shè)置指令口寫地址
          MOVX     @DPTR,A        ;寫指令代碼
          POP      ACC
          POP      DPL
          POP      DPH
          RET
;寫顯示數(shù)據(jù)子程序
PR2:     PUSH     DPH
         PUSH     DPL
         PUSH     ACC
         MOV      DPTR,#CR_Add   ;設(shè)置指令口讀地址
PR21:    MOVX     A,@DPTR
          JB       ACC.7,PR21     ;判BF=0？是繼續(xù)
          MOV      A,DAT
          MOV      DPTR,#DW_Add   ;設(shè)置數(shù)據(jù)口寫地址
          MOVX     @DPTR,A        ;寫數(shù)據(jù)
          POP      ACC
          POP      DPL
          POP      DPH
          RET
;讀顯示數(shù)據(jù)子程序
 PR3:    PUSH     DPH
         PUSH     DPL
         PUSH     ACC
         MOV      DPTR,#CR_Add   ;設(shè)置指令口讀地址
 PR31:    MOVX     A,@DPTR
          JB       ACC.7,PR31     ;判BF=0？是繼續(xù)
          MOV      DPTR,#DR_Add   ;設(shè)置數(shù)據(jù)口讀地址
          MOVX     A,@DPTR        ;讀數(shù)據(jù)
          MOV      DAT,A          ;存入DAT單元
          POP      ACC
          POP      DPL
          POP      DPH
          RET
;直接訪問方式下的初始化子程序
  INT:    MOV     A,#38H          ;此循環(huán)必要,不可刪除
          MOV     DPTR,#CW_Add    ;指令口地址設(shè)置
          MOV     R2,#03H        ;循環(huán)量=3 
 INTU1:   MOVX    @DPTR,A         ;寫指令代碼
          LCALL   DELAY5MS            ;調(diào)延時子程序 
          DJNZ    R2,INTU1
          MOV     COM,#38H        ;設(shè)置工作方式*
          LCALL   PR1              ;
          MOV     COM,#01H        ;清屏
          LCALL   PR1
          MOV     COM,#06H        ;設(shè)置輸入方式
          LCALL   PR1
          MOV     COM,#0FH        ;設(shè)置顯示方式
          LCALL   PR1
          RET
;光標(biāo)左移輸入方式演示程序段
WRIT:      MOV      COM,#04H            ;輸入方式設(shè)置
           LCALL    PR1
           MOV      COM,#90H           ;設(shè)置DDRAM 地址
           LCALL    PR1        
           MOV      DPTR,#TABCL        ;設(shè)置字表首地址
           MOV      R2,#12H            ;循環(huán)量設(shè)置
CL_1:      MOV      A,R2
           DEC      A
           MOVC     A,@A+DPTR          ;取字符代碼
           MOV      DAT,A            
           LCALL    PR2                 ;寫數(shù)據(jù)
           LCALL    DELAY20MS               ;演示用延時
           DJNZ     R2,CL_1
           SJMP     $
;注:*工作方式參數(shù)根據(jù)所使用的字符型液晶顯示模塊的特性而定。
DELAY5MS:   MOV      R6,#04H         ;延時子程序  
            MOV      R7,#10H
DELAY1:     NOP
            DJNZ       R7,DELAY1 
            DJNZ       R6,DELAY1
            RET
DELAY20MS:  MOV      R6,#0FFH         ;延時子程序  
            MOV      R7,#0FFH
DELAY2:     NOP
            DJNZ       R7,DELAY2
            DJNZ       R6,DELAY2
            RET
TABCL:     DB  43H, 75H, 72H, 73H, 6FH, 72H, 20H      ;Cursor 
           DB  4CH, 65H, 66H, 74H, 20H                ;Left
           DB  53H, 63H, 72H, 6FH, 6CH,6CH            ;Scroll 
END