#ifndef  _display_
#define  _display_           
;DISPLAY_S.ASM    串行口顯示子程序
;功能：            DP-51板顯示測試子程序
;說明：            顯示從DBUF0指定單元開始的5個數據
;定義變量
DBUF0      DATA    40H                ;顯示緩沖區首址
DBUF1      DATA    41H
DBUF2      DATA    42H
DBUF3      DATA    43H
DBUF4      DATA    44H
BUF        EQU     45H                ;存放中間變量
LENTH      EQU     05H                ;顯示緩沖區長度
FRIT       DATA    P1                 ;定義位口
SDA	   BIT	   P1^0
CLK	   BIT     P1^1	

DISPLAY:  
	   PUSH	   PSW
	   PUSH	   ACC	
	   MOV     R2,       #7FH     ;給位碼初值
           MOV     R0,       #DBUF0   ;給顯示緩沖區首值
ZCQ:       MOV     A,        @R0
           LCALL   TAB                ;查表取段碼
           ACALL   TXDBYTE		      ;送段碼輸出
           MOV     BUF,      FRIT
           ANL     BUF,      #07H
           MOV     A,        R2       ;保證不影響其它位送位碼
           ORL     A,        BUF       
           MOV     FRIT,     A
           LCALL   DELAY              ;調延時子程序
 	   MOV	   FRIT,#0FFH
           INC     R0
           MOV     A,        R2
           RR      A
           MOV     R2,       A
           CJNE    R0,       #45H,  ZCQ;5位顯示完嗎?
           MOV	   FRIT,     #0FFH
	   POP	   ACC
           POP	   PSW	
           RET

TXDBYTE:
	   PUSH	   PSW
	   PUSH	   ACC	
	   MOV	   R3,#08H
TXDUP:	   RLC	   A
	   MOV	   SDA,C
	   CLR	   CLK
	   SETB	   CLK
	   DJNZ	   R3,TXDUP
	   POP	   ACC
           POP	   PSW
	   RET

;延時子程序
DELAY:     MOV     R7,      #50H     ;12M時鐘下延時1MS	
DELAY0:    MOV     R6,      #10H
DELAY1:    DJNZ    R6,      DELAY1
           DJNZ    R7,      DELAY0
           RET

;查表子程序
TAB:       INC     A	             ;基地址加一
           MOVC    A,       @A+PC    ;查段碼表，取其相應的段碼
           RET
DB         0C0H,0F9H,0A4H,0B0H,099H,092H,082H,0F8H,80H,090H,088H,083H,0c6H,0a1H,86H,8eH,0bfH,89H,8CH
	   ;(0-9 A-F)共陽段碼表
#endif