/*--示例說明
	下面的示例演示了如何把默認值綁定到列和用戶定義的數據類型
	并且演示了修改綁定于列和用戶定義的數據類型的默認值時，這兩者之間的差異。
--*/

--定義數據類型
EXEC sp_addtype 'ut_age','int','null'
GO

--為ut_age定義默認值
CREATE DEFAULT df_ut_age
AS 20
GO

--將默認值綁定到用戶定義的數據類型
EXEC sp_bindefault 'df_ut_age','ut_age'
GO

--使用定義的數據類型
CREATE TABLE tb(
Name nvarchar(20),
AGE_u ut_age,
AGE int)
GO

--直接將默認值綁定到列
EXEC sp_bindefault 'df_ut_age','tb.AGE'
GO

--插入數據
INSERT tb VALUES('AA',DEFAULT,DEFAULT)
INSERT tb(Name) VALUES('BB')
SELECT * FROM tb
/*--結果
Name                  AGE_u     AGE 
-------------------------------- ----------------- ----------- 
AA                   20          20
BB                   20          20
--*/
GO

--創建一個新默認值
CREATE DEFAULT df_ut_age1
AS 50
GO

--將新默認值綁定到列和用戶定義的數據類型
EXEC sp_bindefault 'df_ut_age1','tb.AGE'
EXEC sp_bindefault 'df_ut_age1','ut_age',futureonly
INSERT tb(Name) VALUES('CC')
SELECT * FROM tb
/*--結果
綁定到列的默認值在新增數據時立即生效
使用futureonly綁定默認值到用戶定義數據類型時時,不影響表中已經定義的列
Name                 AGE_u       AGE         
-------------------- ----------- ----------- 
AA                   20          20
BB                   20          20
CC                   20          50
--*/
GO

--刪除測試
DROP TABLE tb
EXEC sp_droptype 'ut_age'
DROP DEFAULT df_ut_age,df_ut_age1