/********************************************************************************/
/* TMS320F2810 Linker Command File                                              */
/* The Linker Command File For Boot To H0 RAM Bootmode      Version number: 1.0 */
/*                                                                              */
/* File name : DSP2810_LINK_RAM.cmd                                             */
/* Date/Time created: Oct 25 2005                                               */
/* Author: Anakin.Lee                                                           */
/********************************************************************************/

MEMORY
{
PAGE 0 :            /* Program Memory */
        RAML0          : origin = 0x008000, length = 0x001000     /* on-chip RAM block L0 */
        OTP            : origin = 0x3D7800, length = 0x000800     /* on-chip OTP */
        FLASH_E        : origin = 0x3E8000, length = 0x004000     /* on-chip FLASHE */
        FLASH_D        : origin = 0x3EC000, length = 0x004000     /* on-chip FLASHD */
        FLASH_C        : origin = 0x3F0000, length = 0x004000     /* on-chip FLASHC */
        FLASH_AB       : origin = 0x3F4000, length = 0x003F80     /* on-chip FLASHAB */
        CSM_RSVD       : origin = 0x3F7F80, length = 0x000076     /* Part of FLASHA. Reserved when CSM is in use. */
        BEGIN_FLASH    : origin = 0x3F7FF6, length = 0x000002     /* Part of FLASHA. Used for "boot to flash" bootloader mode. */
        PASSWORDS      : origin = 0x3F7FF8, length = 0x000008     /* Part of FLASHA.  CSM password locations. */
        BEGIN_H0       : origin = 0x3F8000, length = 0x000002     /* Part of H0 SARAM.  Used for "boot to H0" bootloader mode. */
        RAMH0          : origin = 0x3F8002, length = 0x001FFE     /* on-chip H0 SARAM */
        ROM            : origin = 0x3FF000, length = 0x000FC0     /* boot ROM available if MP/MCn=0 */
        RESET          : origin = 0x3FFFC0, length = 0x000002     /* part of boot ROM (MP/MCn=0) */
        VECTORS        : origin = 0x3FFFC2, length = 0x00003E     /* part of boot ROM (MP/MCn=0) */

PAGE 1 :            /* Data Memory */
        RAMM0          : origin = 0x000000, length = 0x000400     /* on-chip RAM block M0 */
        RAMM1          : origin = 0x000400, length = 0x000400     /* on-chip RAM block M1 */
        RAML1          : origin = 0x009000, length = 0x001000     /* on-chip RAM block L1 */

                       /* Peripheral Frame 0 */
        DEV_EMU        : origin = 0x000880, length = 0x000180     /* EMU Register block. Secured by EALLOW */
        FLASH_REGS     : origin = 0x000A80, length = 0x000060     /* FLASH Register block. Secured by EALLOW */
        CSM            : origin = 0x000AE0, length = 0x000010     /* Code Secure Module block. Secured by CSM */
        XINTF          : origin = 0x000B20, length = 0x000020     /* XINTF Register block */
        CPU_TIMER0     : origin = 0x000C00, length = 0x000008     /* TIME0 Register block */
        CPU_TIMER1     : origin = 0x000C08, length = 0x000008     /* TIME1 Register block */
        CPU_TIMER2     : origin = 0x000C10, length = 0x000008     /* TIME2 Register block */
        PIE_CTRL       : origin = 0x000CE0, length = 0x000020     /* PIE Register block */
        PIE_VECT       : origin = 0x000D00, length = 0x000100     /* PIE Vectors Table block */

                       /* Peripheral Frame 1 */
        ECAN_A         : origin = 0x006000, length = 0x000100
        ECAN_AMBOX     : origin = 0x006100, length = 0x000100

                       /* Peripheral Frame 2 */
        SYSTEM         : origin = 0x007010, length = 0x000020     /* System Control Register block. Secured by EALLOW */
        SPI_A          : origin = 0x007040, length = 0x000010     /* SPI A Register block */
        SCI_A          : origin = 0x007050, length = 0x000010     /* SCI A Register block */
        XINTRUPT       : origin = 0x007070, length = 0x000010     /* XINT Register block */
        GPIOMUX        : origin = 0x0070C0, length = 0x000020     /* GPIO Multiplexer Register block. Secured by EALLOW */
        GPIODAT        : origin = 0x0070E0, length = 0x000020     /* GPIO Data Register block */
        ADC            : origin = 0x007100, length = 0x000020     /* ADC Register block */
        EV_A           : origin = 0x007400, length = 0x000040     /* EV_A Register block */
        EV_B           : origin = 0x007500, length = 0x000040     /* EV_B Register block */
        SPI_B          : origin = 0x007740, length = 0x000010     /* SPI B Register block */
        SCI_B          : origin = 0x007750, length = 0x000010     /* SCI B Register block */
        MCBSP          : origin = 0x007800, length = 0x000040     /* McBSP Register block */
}


SECTIONS
{                      /***  Compiler Required Sections  ***/
                       /* Program memory (PAGE 0) sections */
       .text           : > RAMH0,       PAGE = 0
       .data           : > RAMH0,       PAGE = 0                  /* ASM language initialization section */
       .cinit          : > RAMH0,       PAGE = 0                  /* C language initialization section */
       .pinit          : > RAMH0,       PAGE = 0
       .reset          : > RESET,       PAGE = 0, TYPE = DSECT    /* We are not using the .reset section */

                       /* Data Memory (PAGE 1) sections */
       .cio            : > RAMM0,       PAGE = 1
       .bss            : > RAMM0,       PAGE = 1                  /* Should be empty with large memory model */
       .ebss           : > RAMM0,       PAGE = 1
       .const          : > RAMM0,       PAGE = 1                  /* Should be empty with large memory model */
       .econst         : > RAMM0,       PAGE = 1
       .stack          : > RAMM1,       PAGE = 1
       .sysmem         : > RAMM1,       PAGE = 1                  /* Should be empty with large memory model */
       .esysmem        : > RAMM1,       PAGE = 1
       .switch         : > RAMM1,       PAGE = 1

                       /***  User Defined Sections  ***/
        codeStart      : > BEGIN_H0,    PAGE = 0                  /* Used by file CodeStartBranch.asm */
        csm_rsvd       : > CSM_RSVD,    PAGE = 0                  /* Not used in RAM example */
        passwords      : > PASSWORDS,   PAGE = 0                  /* Not used in RAM example */
        vectorTable    : > PIE_VECT,    PAGE = 1                  /* PIE Vectors Table */
        secureRamFuncs :   LOAD = RAMH0,PAGE = 0                  /* Used by InitFlash() in SysCtrl.c */ 
                           RUN = RAML0, PAGE = 0
                           LOAD_START(_secureRamFuncs_loadstart),
                           LOAD_END(_secureRamFuncs_loadend),
                           RUN_START(_secureRamFuncs_runstart)
}