;/*************************************** Copyright (c) *************************************************
;*
;*										POLAR STAR
;*								北天星國際貿(mào)易（深圳）有限公司
;*								http://www.po-star.com
;*
;*	文 件 名: Startup.s
;*	文件描述：lpc210x的啟動代碼，包含異常向量入口、初始化堆棧的代碼等
;*
;*  說    明: 每個工程應(yīng)當(dāng)有獨立的這個文件的拷貝，并進行相應(yīng)的修改
;*
;********************************************************************************************************/

;//定義堆棧的大小
SVC_STACK_LEGTH         EQU         0
FIQ_STACK_LEGTH         EQU         0
IRQ_STACK_LEGTH         EQU         256
ABT_STACK_LEGTH         EQU         0
UND_STACK_LEGTH         EQU         0


USR32Mode   EQU 0x10
SVC32Mode   EQU 0x13
SYS32Mode   EQU 0x1f
IRQ32Mode   EQU 0x12
FIQ32Mode   EQU 0x11



;//引入的外部標(biāo)號在這聲明
    IMPORT  FIQ_Exception                   ;//快速中斷異常處理程序
    IMPORT  __main                          ;//C語言主程序入口 
    IMPORT  TargetResetInit                 ;//目標(biāo)板基本初始化
    IMPORT  StackUsr
    IMPORT  bottom_of_heap

;//給外部使用的標(biāo)號在這聲明
    EXPORT  Reset
    EXPORT __rt_div0
    EXPORT __user_initial_stackheap

    CODE32

    AREA    vectors,CODE,READONLY
        ENTRY
;//中斷向量表
Reset
        LDR     PC, ResetAddr
        LDR     PC, UndefinedAddr
        LDR     PC, SWI_Addr
        LDR     PC, PrefetchAddr
        LDR     PC, DataAbortAddr
        DCD     0xb9205f80
        LDR     PC, [PC, #-0xff0]
        LDR     PC, FIQ_Addr

ResetAddr           DCD     ResetInit
UndefinedAddr       DCD     Undefined
SWI_Addr            DCD     SoftwareInterrupt
PrefetchAddr        DCD     PrefetchAbort
DataAbortAddr       DCD     DataAbort
Nouse               DCD     0
IRQ_Addr            DCD     0
FIQ_Addr            DCD     FIQ_Handler

;//未定義指令
Undefined
        B       Undefined

;//軟中斷
SoftwareInterrupt
        B       SoftwareInterrupt

;//取指令中止
PrefetchAbort
        B       PrefetchAbort

;//取數(shù)據(jù)中止
DataAbort
        B       DataAbort

;//快速中斷
FIQ_Handler
        STMFD   SP!, {R0-R3, LR}
        BL      FIQ_Exception
        LDMFD   SP!, {R0-R3, LR}
        SUBS    PC,  LR,  #4

;/*********************************************************************************************************
;*
;* 函數(shù)名稱: InitStack
;*
;* 功能描述: 初始化堆棧
;*
;* 輸　  入: 無
;*
;* 輸　  出: 無
;*
;* 全局變量: 無
;* 調(diào)用模塊: 無
;* 
;********************************************************************************************************/
InitStack    
        MOV     R0, LR

;//設(shè)置管理模式堆棧
        MSR     CPSR_c, #0xd3
        LDR     SP, StackSvc
;//設(shè)置中斷模式堆棧
        MSR     CPSR_c, #0xd2
        LDR     SP, StackIrq
;//設(shè)置快速中斷模式堆棧
        MSR     CPSR_c, #0xd1
        LDR     SP, StackFiq
;//設(shè)置中止模式堆棧
        MSR     CPSR_c, #0xd7
        LDR     SP, StackAbt
;//設(shè)置未定義模式堆棧
        MSR     CPSR_c, #0xdb
        LDR     SP, StackUnd
;//設(shè)置系統(tǒng)模式堆棧
        MSR     CPSR_c, #0xdf
        LDR     SP, =StackUsr

        MOV     PC, R0

;/*********************************************************************************************************
;*
;* 函數(shù)名稱: ResetInit
;* 功能描述: 復(fù)位入口
;* 
;* 輸　  入: 無
;*
;* 輸　  出: 無
;*         
;* 全局變量: 無
;* 調(diào)用模塊: 無
;*
;********************************************************************************************************/
ResetInit     
        BL      InitStack               	;//初始化堆棧
        BL      TargetResetInit         	;//目標(biāo)板基本初始化
                                        
        B       __main						;//跳轉(zhuǎn)到c語言入口


;/*********************************************************************************************************
;*
;* 函數(shù)名稱: __user_initial_stackheap 
;* 功能描述: 庫函數(shù)初始化堆和棧，不能刪除
;* 
;* 輸　  入: 參考庫函數(shù)手冊
;*
;* 輸　  出: 參考庫函數(shù)手冊
;*         
;* 全局變量: 無
;* 調(diào)用模塊: 無
;*
;********************************************************************************************************/
__user_initial_stackheap    
    LDR   r0,=bottom_of_heap
	MOV   pc,lr


;/*********************************************************************************************************
;*
;* 函數(shù)名稱: __rt_div0
;* 功能描述: 整數(shù)除法除數(shù)為0錯誤處理函數(shù)，替代原始的__rt_div0減少目標(biāo)代碼大小
;* 
;* 輸　  入: 參考庫函數(shù)手冊
;*
;* 輸　  出: 無
;*         
;* 全局變量: 無
;* 調(diào)用模塊: 無
;*
;********************************************************************************************************/
__rt_div0

        B       __rt_div0

StackSvc           DCD     SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4
StackIrq           DCD     IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4
StackFiq           DCD     FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4
StackAbt           DCD     AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4
StackUnd           DCD     UndtStackSpace + (UND_STACK_LEGTH - 1)* 4

;/*********************************************************************************************************
;* 函數(shù)名稱: CrpData
;* 功能描述: 支持芯片加密功能
;* 
;* 輸　  入: 無
;*
;* 輸　  出: 無
;*         
;* 全局變量: 無
;* 調(diào)用模塊: 無
;*
;********************************************************************************************************/
    IF :DEF: EN_CRP
        IF  . >= 0x1fc
        INFO    1,"\nThe data at 0x000001fc must be 0x87654321.\nPlease delete some source before this line."
        ENDIF
CrpData
    WHILE . < 0x1fc
    NOP
    WEND
CrpData1
    DCD     0x87654321          				;// 當(dāng)此數(shù)為0x87654321時，用戶程序被保護
    ENDIF


;/* 分配堆棧空間 */
        AREA    MyStacks, DATA, NOINIT, ALIGN=2
SvcStackSpace      SPACE   SVC_STACK_LEGTH * 4  ;//管理模式堆棧空間
IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;//中斷模式堆棧空間
FiqStackSpace      SPACE   FIQ_STACK_LEGTH * 4  ;//快速中斷模式堆棧空間
AbtStackSpace      SPACE   ABT_STACK_LEGTH * 4  ;//中止義模式堆棧空間
UndtStackSpace     SPACE   UND_STACK_LEGTH * 4  ;//未定義模式堆棧
    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/