{*******************************************************}
{                                                       }
{                   QReportMaker 2.0                    }
{               QMPrintEhGrid Component                 }
{                                                       }
{            Copyright (c) 2003,2004 by Zwm.            }
{                                                       }
{*******************************************************}
                   
unit QM_PEhGrid;

interface

{$I QRMaker.Inc}

uses
  Windows, Messages, SysUtils, Classes, Controls, Dialogs, DBGrids, Forms,
  Grids, QM_RGrid, QM_RConsole;

type
  { TQMPrintEhGrid }
  TQMPrintEhGrid = class(TQMDataReport)
  private
    FDBGridEh: TCustomGrid;
    procedure SetDBGridEh(const Value: TCustomGrid);
  protected
    procedure Notification(AComponent: TComponent; Operation: TOperation); override;
    procedure DrawReport; override;
    function GridType: TQMGridType; override;
    function GetRecordCount: Integer; override;
  public
    procedure LoadColumnSetting;
    function ColumnSetup: Boolean;
    procedure ExportData;
  published
    property DBGridEh: TCustomGrid read FDBGridEh write SetDBGridEh;
  end;

implementation

{$IFDEF EHLib}
uses DBGridEh, DBGridEhImpExp, QM_Prntr, QM_Utils, QM_SetCols, QM_Const;

var
  EhGrid: TDBGridEh;

{ TQMPrintEhGrid }

procedure TQMPrintEhGrid.DrawReport;
var
  i,j,RepWidth: Integer;
begin
  Grid.Columns.Clear;
  if EhGrid <> nil then
  begin
    for i := 0 to EhGrid.Columns.Count - 1 do
    begin
      if (EhGrid.Columns[i].Visible = True) and (EhGrid.Columns[i].Width > 0) then
      with Grid.Columns.Add do
      begin
        Title.Caption := EhGrid.Columns[i].Title.Caption;
        Width := EhGrid.Columns[i].Width;
        Title.Alignment := EhGrid.Columns[i].Title.Alignment;
        Font.Assign(EhGrid.Columns[i].Font);
        Title.Font.Assign(EhGrid.Columns[i].Title.Font);
        Alignment := EhGrid.Columns[i].Alignment;
       {$IFDEF EHLib25}
        DisplayFormat := EhGrid.Columns[i].DisplayFormat;
       {$ENDIF}
        FieldName := EhGrid.Columns[i].FieldName;
        if EhGrid.Columns[i].Tag = 1 then HideZero := True;
        if EhGrid.FooterRowCount > 0 then
        begin
          Footer.Alignment := EhGrid.Columns[i].Footer.Alignment;
          Footer.Font.Assign(EhGrid.Columns[i].Footer.Font);
          Footer.Caption := EhGrid.GetFooterValue(EhGrid.FooterRowCount - 1,EhGrid.Columns[i]);
          for j := 0 to EhGrid.Columns[i].Footers.Count - 1 do
          with Footers.Add do
          begin
            Alignment := EhGrid.Columns[i].Footers[j].Alignment;
            if cvFooterFont in EhGrid.Columns[i].Footer.AssignedValues then
              Font.Assign(EhGrid.Columns[i].Footers[j].Font);
            Caption := EhGrid.GetFooterValue(j,EhGrid.Columns[i]);
          end;
        end;
      end;
    end;
    Grid.FooterRowCount := EhGrid.FooterRowCount;
    if EhGrid.DataSource<>nil then
      DataSet := EhGrid.DataSource.DataSet;
    Grid.Font.Assign(EhGrid.Font);
    Grid.FooterFont.Assign(EhGrid.FooterFont);
    Grid.TitleFont.Assign(EhGrid.TitleFont);
    Grid.TitleMulti := EhGrid.UseMultiTitle;
    if (Grid.TitleMulti) or (EhGrid.TitleHeight = 0) then
      Grid.TitleHeight := QM_TextHeight(EhGrid.TitleFont) + EhGrid.VTitleMargin
    else
      Grid.TitleHeight := EhGrid.TitleHeight;
    if (EhGrid.RowHeight = 0) and (EhGrid.RowLines = 0) then
      Grid.RowHeight := QM_TextHeight(EhGrid.Font) + 5
    else
      Grid.RowHeight := EhGrid.RowLines*(QM_TextHeight(EhGrid.Font) + 4) + EhGrid.RowHeight;
    if not ((dgTitles in EhGrid.Options) and (rgTitles in Grid.Options)) then
      Grid.Options := Grid.Options - [rgTitles];
    if not ((dgRowLines in EhGrid.Options) and (rgRowLines in Grid.Options)) then
      Grid.Options := Grid.Options - [rgRowLines];
    if not ((dgColLines in EhGrid.Options) and (rgColLines in Grid.Options)) then
      Grid.Options := Grid.Options - [rgColLines];
  end else
  begin
    Grid.TitleHeight := QM_TextHeight(Font);
    Grid.RowHeight := Grid.TitleHeight + 5;
  end;
  if Assigned(OnBeforeDraw) then OnBeforeDraw(self);
  RepWidth := 0;
  for i:=0 to Grid.Columns.Count-1 do
    Inc(RepWidth, Grid.Columns[i].Width);
  FormatReport(RepWidth);
  inherited DrawReport;
  if RepWidth = 0 then exit;
  DrawQMGrid(True);
end;

function TQMPrintEhGrid.ColumnSetup: Boolean;
var
  tmpFrm: TQMSetColsForm;
  i,fcols: Integer;
begin
  Result := false;
  if EhGrid = nil then Exit;
  tmpFrm := TQMSetColsForm.Create(nil);
  with tmpFrm do
  begin
    QMSection := Section;
    With EhGrid do
    begin
      sgCol.RowCount := Columns.Count + 1;
      for i := 1 to sgCol.RowCount - 1 do
      begin
        sgCol.Cells[1,i] := Columns[i-1].Title.Caption;
        if Columns[i-1].Visible then
        begin
           sgCol.Cells[2,i] := 'Y';
           sgCol.Cells[3,i] := IntToStr(Columns[i-1].Width);
        end
        else
        begin
          sgCol.Cells[2,i] := '';
          Columns[i-1].Visible := True;
          sgCol.Cells[3,i] := IntToStr(Columns[i-1].Width);
          Columns[i-1].Visible := False;
        end;
        sgCol.Cells[4,i] := cbxAlign.Items[Integer(Columns[i-1].Alignment)];
      end;
    end;
    if ShowModal = mrOK then
    begin
      Result := True;
      fcols:=EhGrid.FrozenCols;
      EhGrid.FrozenCols := 0;
      for i := 1 to sgCol.RowCount - 1 do
      begin
        EhGrid.Columns[i-1].Alignment := TAlignment(QM_GetIntValue(cbxAlign.Items.IndexOf(sgCol.Cells[4,i]),0,2));
        if sgCol.Cells[2,i] = '' then
          EhGrid.Columns[i-1].Visible := false
        else EhGrid.Columns[i-1].Visible := true;
        EhGrid.Columns[i-1].Width := QM_GetStrIntValue(sgCol.Cells[3,i],0,500,64);
      end;
      if EhGrid.VisibleColumns.Count > 1 then
        if EhGrid.VisibleColumns.Count <= fcols then
          EhGrid.FrozenCols := EhGrid.VisibleColumns.Count-1
        else EhGrid.FrozenCols := fcols;
    end;
    free;
  end;
end;

procedure TQMPrintEhGrid.LoadColumnSetting;
var
  ay: TStringList;
  i,fcols: integer;
begin
  if EhGrid = nil then Exit;
  ay := TStringList.Create;
  try
    With EhGrid do
    begin
      ay.Clear;
      ay.Add(QMIniInfo.ReadString(Section,'Widths',''));
      QM_Split(ay,',',Columns.Count);
      for i := 0 to Columns.Count - 1 do
      begin
        if ay[i]='' then continue;
        Columns[i].Width := QM_GetStrIntValue(ay[i],0,500,64);
      end;
      ay.Clear;
      ay.Add(QMIniInfo.ReadString(Section,'Aligns',''));
      QM_Split(ay,',',Columns.Count);
      for i := 0 to Columns.Count - 1 do
      begin
        if ay[i]='' then continue;
        Columns[i].Alignment := TAlignment(QM_GetStrIntValue(ay[i],0,2,0));
      end;
      ay.Clear;
      ay.Add(QMIniInfo.ReadString(Section,'Visibles',''));
      QM_Split(ay,',',Columns.Count);
      fcols := FrozenCols;
      FrozenCols := 0;
      for i := 0 to Columns.Count - 1 do
      begin
        if ay[i] = '0' then
          Columns[i].Visible := False
        else Columns[i].Visible := True;
      end;
      if VisibleColumns.Count > 1 then
        if VisibleColumns.Count <= fcols then
          FrozenCols := VisibleColumns.Count-1
        else FrozenCols := fcols;
    end;
  finally
    ay.Free;
  end;  
end;

procedure TQMPrintEhGrid.SetDBGridEh(const Value: TCustomGrid);
begin
  if (Value <> nil) and (not (Value is TDBGridEh)) then
    FDBGridEh := nil
  else
    FDBGridEh := Value;
  if FDBGridEh = nil then EhGrid := nil
  else EhGrid := TDBGridEh(FDBGridEh);
  if Value <> nil then Value.FreeNotification(Self);
end;

procedure TQMPrintEhGrid.Notification(AComponent: TComponent;
  Operation: TOperation);
begin
  inherited Notification(AComponent, Operation);
  if (Operation = opRemove) and (AComponent = FDBGridEh) then FDBGridEh := nil;
end;

procedure TQMPrintEhGrid.ExportData;
begin
  if (EhGrid = nil) or (EhGrid.Columns.Count = 0) or
    (EhGrid.DataSource = nil) or
    (EhGrid.DataSource.DataSet = nil) or
    (EhGrid.DataSource.DataSet.Active = False) then exit;
  with TSaveDialog.Create(Application) do
  begin
    Title:= srvSaveDlgCaption;
    Filter := 'ehExport as XLS (*.XLS)|*.xls'+
     '|ehExport as Text (*.TXT)|*.txt|ehExport as Csv (*.CSV)|*.csv'+
     '|ehExport as HTML (*.HTM)|*.htm|ehExport as RTF (*.RTF)|*.rtf'+
     '|ehExport as VCLDBIF (*.VCL)|*.vcl';
    DefaultExt := 'xls';
    if Execute then
    begin
      try
        case FilterIndex of
          1 : SaveDBGridEhToExportFile(TDBGridEhExportAsXLS, EhGrid, Filename, true);
          2 : SaveDBGridEhToExportFile(TDBGridEhExportAsText, EhGrid, Filename, true);
          3 : SaveDBGridEhToExportFile(TDBGridEhExportAsCsv, EhGrid, Filename, true);
          4 : SaveDBGridEhToExportFile(TDBGridEhExportAsHTML, EhGrid, Filename, true);
          5 : SaveDBGridEhToExportFile(TDBGridEhExportAsRTF, EhGrid ,Filename, true);
          6 : SaveDBGridEhToExportFile(TDBGridEhExportAsVCLDBIF, EhGrid, Filename, true);
        end;
        MessageDlg(srvOutputed, mtInformation, [mbOk], 0);
      finally
      end;
    end;
    Free;
  end;
end;

function TQMPrintEhGrid.GridType: TQMGridType;
begin
  Result := gtEhGrid;
end;

function TQMPrintEhGrid.GetRecordCount: Integer;
begin
  if (EhGrid <> nil) and (EhGrid.DataSource <> nil) and
    (EhGrid.DataSource.DataSet <> nil) and (EhGrid.DataSource.DataSet.Active = True) then
    Result := EhGrid.DataSource.DataSet.RecordCount
  else Result := 0;
end;

initialization
  QM_RegEh := True;
{$ELSE}
procedure TQMPrintEhGrid.DrawReport; begin end;
function TQMPrintEhGrid.ColumnSetup: Boolean; begin Result := False end;
procedure TQMPrintEhGrid.LoadColumnSetting; begin end;
procedure TQMPrintEhGrid.ExportData; begin end;
function TQMPrintEhGrid.GridType: TQMGridType; begin Result := gtGrid end;
function TQMPrintEhGrid.GetRecordCount: Integer; begin Result := 0 end;
procedure TQMPrintEhGrid.SetDBGridEh(const Value: TCustomGrid); begin end;
procedure TQMPrintEhGrid.Notification(AComponent: TComponent;
  Operation: TOperation); begin end;
{$ENDIF}

end.