;=========================================
; NAME: 2410INIT.S
; DESC: C start up codes
;       Configure memory, ISR ,stacks
;	Initialize C-variables
; HISTORY:
; 2002.02.25:kwtark: ver 0.0
; 2002.03.20:purnnamu: Add some functions for testing STOP,POWER_OFF mode
;=========================================

;include頭文件
	GET option.inc
	GET memcfg.inc
	GET 2410addr.inc

BIT_SELFREFRESH EQU	(1<<22)

;下面是對arm處理器模式寄存器對應值的常數定意
;arm處理器中有一個CPSR程序狀態寄存器 它的后五位決定目前的處理器模式
;Pre-defined constants
USERMODE    EQU 	0x10
FIQMODE     EQU 	0x11
IRQMODE     EQU 	0x12
SVCMODE     EQU 	0x13
ABORTMODE   EQU 	0x17
UNDEFMODE   EQU 	0x1b
MODEMASK    EQU 	0x1f
NOINT       EQU 	0xc0

;The location of stacks
UserStack	EQU	(_STACK_BASEADDRESS-0x3800)	;0x33ff4800 ~ 
SVCStack	EQU	(_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack	EQU	(_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack	EQU	(_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack	EQU	(_STACK_BASEADDRESS-0x1000)	;0x33ff7000 ~
FIQStack	EQU	(_STACK_BASEADDRESS-0x0)	;0x33ff8000 ~ 

;arm處理器有兩種工作狀態 1.arm:32位 這種工作狀態下執行字對準的arm指令 2.Thumb:16位 這種工作狀
;態執行半字對準的Thumb指令 
;因為處理器分為16位 32位兩種工作狀態 程序的編譯器也是分16位和32兩種編譯方式 所以下面的程序用
;于根據處理器工作狀態確定編譯器編譯方式 
;code16偽指令指示匯編編譯器后面的指令為16位的thumb指令 
;code32偽指令指示匯編編譯器后面的指令為32位的arm指令 
;這段是為了統一目前的處理器工作狀態和軟件編譯方式（16位編譯環境使用tasm.exe編譯

;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
	GBLL    THUMBCODE
	[ {CONFIG} = 16 
THUMBCODE SETL  {TRUE}
	    CODE32
    	|   
THUMBCODE SETL  {FALSE}
    	]

    	MACRO
	MOV_PC_LR
    	[ THUMBCODE
            bx lr  ;分支到Thumb代碼
    	|
            mov	pc,lr
    	]
	MEND

    	MACRO
	MOVEQ_PC_LR
    	[ THUMBCODE
    	    bxeq lr
    	|
            moveq pc,lr
    	]
	MEND

;下面這段程序是個宏定義，用來處理中斷。
;下面包含的HandlerXXX HANDLER HandleXXX將都被下面這段程序展開 
;這段程序用于把中斷服務程序的首地址裝載到pc中，有人稱之為“加載程序”。 
;本初始化程序定義了一個數據區（在文件最后），34個字空間，存放相應中斷服務程序的首地址。每個字
;空間都有一個標號，以Handle***命名。 
;在向量中斷模式下使用“加載程序”來執行中斷服務程序。 
;這里就必須講一下向量中斷模式和非向量中斷模式的概念 
;向量中斷模式是當cpu讀取位于0x18處的IRQ中斷指令的時候，系統自動讀取對應于該中斷源確定地址上的
;指令取代0x18處的指令，通過跳轉指令系統就直接跳轉到對應地址 
;函數中 節省了中斷處理時間提高了中斷處理速度標 例如 ADC中斷的向量地址為0xC0,則在0xC0處放如下
;代碼：ldr PC,=HandlerADC 當ADC中斷產生的時候系統會 
;自動跳轉到HandlerADC函數中 
;非向量中斷模式處理方式是一種傳統的中斷處理方法，當系統產生中斷的時候，系統將interrupt 
;pending寄存器中對應標志位置位 然后跳轉到位于0x18處的統一中斷 
;函數中 該函數通過讀取interrupt pending寄存器中對應標志位 來判斷中斷源 并根據優先級關系再跳到
;對應中斷源的處理代碼中

    	MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
	sub	sp,sp,#4        ;decrement sp(to store jump address)
;將要使用的r0寄存器入棧（需要把r0作為臨時寄存器，所以使用前要保存）
	stmfd	sp!,{r0}        ;PUSH the work register to stack(lr does't push because it return to original address)
	ldr     r0,=$HandleLabel;load the address of HandleXXX to r0
	ldr     r0,[r0]         ;load the contents(service routine start address) of HandleXXX
;將對應的中斷函數首地址入棧
	str     r0,[sp,#4]      ;store the contents(ISR) of HandleXXX to stack
;將中斷函數首地址出棧 放入程序指針中 系統將跳轉到對應中斷處理函數
	ldmfd   sp!,{r0,pc}     ;POP the work register and pc(jump to ISR)
	MEND
	
	
;一個arm由RO,RW,ZI三個斷組成 其中RO為代碼段，RW是已經初始化的全局變量，ZI是未初始化的全局變量
;（對于GNU工具 對應的概念是TEXT ,DATA,BSS）bootloader 
;bootloader要將RW段復制到ram中并將ZI段清零 編譯器使用下列段來記錄各段的起始和結束地址
; |Image$$RO$$Base| ; RO段起始地址 
; |Image$$RO$$Limit| ; RO段結束地址加1 
; |Image$$RW$$Base| ; RW段起始地址 
; |Image$$RW$$Limit| ; RW段結束地址加1 
; |Image$$ZI$$Base| ; ZI段起始地址 
; |Image$$ZI$$Limit| ; ZI段結束地址加1 
;這些標號的值是通過編譯器的設定來確定的 如編譯軟件中對ro-base和rw-base的設定
;例如 ro-base=0xc000000 rw-base=0xc5f0000

	IMPORT  |Image$$RO$$Base|	; Base of ROM code
	IMPORT  |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)
	IMPORT  |Image$$RW$$Base|   ; Base of RAM to initialise
	IMPORT  |Image$$ZI$$Base|   ; Base and limit of area
	IMPORT  |Image$$ZI$$Limit|  ; to zero initialise	

	
	AREA    SelfBoot, CODE, READONLY
	
;異常中斷矢量表（每個表項占4個字節） 下面是中斷向量表 一旦系統運行時有中斷發生 即使移植了操作
;系統 如linux 處理器已經把控制權交給了操作系統 一旦發生中斷 處理器還是會跳轉到從0x0開始執行 
;中斷向量表中某個中斷表項（依據中斷類型）
;具體中斷向量布局請參考s3c44b0 spec 例如 adc中斷向量為 0x000000c0下面對應表中第49項位置
;向量地址0x0+4*(49-1)=0x000000c0 

	ENTRY
	
;板子上電和復位后 程序開始從位于0x0處開始執行。硬件剛剛上電復位后 程序從這里開始執行跳轉到標號
;為ResetHandler處執行

	EXPORT	__ENTRY
__ENTRY	
ResetEntry
	;1)The code, which converts to Big-endian, should be in little endian code.
	;2)The following little endian code will be compiled in Big-Endian mode. 
	;  The code byte order should be changed as the memory bus width.
	;3)The pseudo instruction,DCD can't be used here because the linker generates error.
	
;總線寬度判斷
;DCD用于分配一段字內存單片，并用后面的偽指令初始化
;分配字節由expr 個數決定

	ASSERT	:DEF:ENDIAN_CHANGE
	[ ENDIAN_CHANGE
	    ASSERT  :DEF:ENTRY_BUS_WIDTH
	    [ ENTRY_BUS_WIDTH=32
			b	ChangeBigEndian	    ;DCD 0xea000007 
	    ]
	    
	    [ ENTRY_BUS_WIDTH=16
		andeq	r14,r7,r0,lsl #20   ;DCD 0x0007ea00
	    ]
	    
	    [ ENTRY_BUS_WIDTH=8
		streq	r0,[r0,-r10,ror #1] ;DCD 0x070000ea
        ]
	|
	b	ResetHandler	;0x00
    ]
	b	HandlerUndef	;0x04	handler for Undefined mode
	b	HandlerSWI	;0x08	;handler for SWI interrupt
	b	HandlerPabort	;0x0c	handler for PAbort
	b	HandlerDabort	;0x10	handler for DAbort
	b	.		;0x14		;reserved
	b	HandlerIRQ	;0x18	;handler for IRQ interrupt 
	b	HandlerFIQ	;0x1c	;handler for FIQ interrupt

;@0x20
	b	EnterPWDN
	
;大小端判斷
ChangeBigEndian
;@0x24
	[ ENTRY_BUS_WIDTH=32
	    DCD	0xee110f10	;0xee110f10 => mrc p15,0,r0,c1,c0,0
	    DCD	0xe3800080	;0xe3800080 => orr r0,r0,#0x80;  //Big-endian
	    DCD	0xee010f10	;0xee010f10 => mcr p15,0,r0,c1,c0,0
	]
	[ ENTRY_BUS_WIDTH=16
	    DCD 0x0f10ee11
	    DCD 0x0080e380	
	    DCD 0x0f10ee01	
	]
	[ ENTRY_BUS_WIDTH=8
	    DCD 0x100f11ee	
	    DCD 0x800080e3	
	    DCD 0x100f01ee	
    	]
	DCD 0xffffffff  ;swinv 0xffffff is similar with NOP and run well in both endian mode. 
	DCD 0xffffffff
	DCD 0xffffffff
	DCD 0xffffffff
	DCD 0xffffffff
	b ResetHandler
	
;Function for entering power down mode
; 1. SDRAM should be in self-refresh mode.
; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.
; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.
; 4. The I-cache may have to be turned on. 
; 5. The location of the following code may have not to be changed.
;進入掉電模式功能
; 1. SDRAM 必須在自刷新模式.
; 2. 所有中斷必須屏蔽 for SDRAM/DRAM self-refresh.
; 3. LCD 關閉for SDRAM/DRAM self-refresh.
; 4. The I-cache 可能需要開啟. 
; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON); 
EnterPWDN			
	mov r2,r0		;r2=rCLKCON
	tst r0,#0x8		;POWER_OFF mode?
	bne ENTER_POWER_OFF

ENTER_STOP	
	ldr r0,=REFRESH		
	ldr r3,[r0]		;r3=rREFRESH	
	mov r1, r3
	orr r1, r1, #BIT_SELFREFRESH
	str r1, [r0]		;Enable SDRAM self-refresh

	mov r1,#16	   	;wait until self-refresh is issued. may not be needed.
0	subs r1,r1,#1
	bne %B0

	ldr r0,=CLKCON		;enter STOP mode.
	str r2,[r0]    

	mov r1,#32
0	subs r1,r1,#1	;1) wait until the STOP mode is in effect.
	bne %B0		;2) Or wait here until the CPU&Peripherals will be turned-off
			;   Entering POWER_OFF mode, only the reset by wake-up is available.

	ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
	str r3,[r0]
	
	MOV_PC_LR

ENTER_POWER_OFF	
	;NOTE.
	;1) rGSTATUS3 should have the return address after wake-up from POWER_OFF mode.
	
	;開啟2410
	ldr r0,=REFRESH		
	ldr r1,[r0]		;r1=rREFRESH	
	orr r1, r1, #BIT_SELFREFRESH
	str r1, [r0]		;Enable SDRAM self-refresh

	mov r1,#16	   	;Wait until self-refresh is issued,which may not be needed.
0	subs r1,r1,#1
	bne %B0

	ldr 	r1,=MISCCR
	ldr	r0,[r1]
	orr	r0,r0,#(7<<17)  ;Make sure that SCLK0:SCLK->0, SCLK1:SCLK->0, SCKE=L during boot-up 
	str	r0,[r1]

	ldr r0,=CLKCON
	str r2,[r0]    

	b .			;CPU will die here.
	

WAKEUP_POWER_OFF
	;Release SCLKn after wake-up from the POWER_OFF mode.

	ldr r1,=MISCCR
	ldr	r0,[r1]
	bic	r0,r0,#(7<<17)  ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:L->H
	str	r0,[r1]

	;Set memory control registers
	ldr	r0,=SMRDATA
	ldr	r1,=BWSCON	;BWSCON Address
	add	r2, r0, #52	;End address of SMRDATA
0       
	ldr	r3, [r0], #4
	str	r3, [r1], #4
	cmp	r2, r0
	bne	%B0

	mov r1,#256
0	subs r1,r1,#1		;1) wait until the SelfRefresh is released.
	bne %B0		
	
	ldr r1,=GSTATUS3 	;GSTATUS3 has the start address just after POWER_OFF wake-up
	ldr r0,[r1]
	mov pc,r0

	LTORG   
	
;下面是具體的中斷處理函數跳轉的宏，通過上面的$HandlerLabel的宏定義展開后跳轉到對應的中斷處理
;函數（對于向量中斷）
HandlerFIQ      HANDLER HandleFIQ
HandlerIRQ      HANDLER HandleIRQ
HandlerUndef    HANDLER HandleUndef
;HandlerUndef
;	sub	sp, sp, #4			;decrement sp(to store jump address)
;	stmfd	sp!, {r14}		;PUSH the work register to stack(lr does't push because it return to original address)
;	ldr	r0, =HandleUndef	;load the address of HandleXXX to r0
;	ldr	r0, [r0]         	;load the contents(service routine start address) of HandleXXX
;	str	r0, [sp, #4]		;store the contents(ISR) of HandleXXX to stack
;	ldmfd	sp!, {r0, pc}	
HandlerSWI      HANDLER HandleSWI
HandlerDabort   HANDLER HandleDabort
HandlerPabort   HANDLER HandlePabort

;下面這段程序是用來處理非向量中斷，具體判斷I_ISPR中各位是否置1 置1表示目前此中斷等待響應
;（每次只能有一位置1），從最高優先級中斷位開始判斷，檢測到等待服務 
;中斷就將pc置為中斷服務函數首地址
IsrIRQ  
	sub	sp, sp, #4       ;reserved for PC
	stmfd	sp!, {r8-r9}
	
	ldr	r9, =INTOFFSET
	ldr	r9, [r9]
	ldr	r8, =HandleEINT0
	add	r8, r8,r9,lsl #2
	ldr	r8, [r8]
	str	r8, [sp,#8]
	ldmfd	sp!,{r8-r9,pc}

;=======
; ENTRY  
;=======
;扳子上電和復位后 程序開始從位于0x0執行b ResetHandler 程序從跳轉到這里執行 
;板子上電復位后 執行幾個步驟這里通過標號在注釋中加1，2，3....標示 標號表示執行順序 

;1.禁止看門狗 屏蔽所有中斷

ResetHandler
	ldr	r0,=WTCON       ;watch dog disable 
	ldr	r1,=0x0         
	str	r1,[r0]

	ldr	r0,=INTMSK
	ldr	r1,=0xffffffff  ;all interrupt disable
	str	r1,[r0]

	ldr	r0,=INTSUBMSK
	ldr	r1,=0x3ff		;all sub interrupt disable
	str	r1,[r0]

	[ {FALSE}
	; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);    
	; Led_Display
	ldr	r0,=GPFCON
	ldr	r1,=0x5500		
	str	r1,[r0]
	ldr	r0,=GPFDAT
	ldr	r1,=0x10
	str	r1,[r0]
	]
	
	
;2.根據工作頻率設置pll 
;這里介紹一下計算公式 
;Fpllo=(m*Fin)/(p*2^s) 
;m=MDIV+8,p=PDIV+2,s=SDIV 
;Fpllo必須大于20Mhz小于66Mhz 
;Fpllo*2^s必須小于170Mhz 
;如下面的PLLCON設定中的M_DIV P_DIV S_DIV是取自option.h中 
;#elif (MCLK==40000000) 
;#define PLL_M (0x48) 
;#define PLL_P (0x3) 
;#define PLL_S (0x2) 
;所以m=MDIV+8=80,p=PDIV+2=5,s=SDIV=2 
;硬件使用晶振為10Mhz,即Fin=10Mhz 
;Fpllo=80*10/5*2^2=40Mhz
	
	;To reduce PLL lock time, adjust the LOCKTIME register. 
	ldr	r0,=LOCKTIME
	ldr	r1,=0xffffff
	str	r1,[r0]
        
    [ PLL_ON_START
	;Configure MPLL
	ldr	r0,=MPLLCON
	ldr	r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV)  ;Fin=12MHz,Fout=50MHz
	str	r1,[r0]
	]

	;Check if the boot is caused by the wake-up from POWER_OFF mode.
;	ldr	r1,=GSTATUS2
;	ldr	r0,[r1]
;	tst	r0,#0x2
	;In case of the wake-up from POWER_OFF mode, go to POWER_OFF_WAKEUP handler. 
;	bne	WAKEUP_POWER_OFF

	EXPORT StartPointAfterPowerOffWakeUp
StartPointAfterPowerOffWakeUp


;3.置存儲相關寄存器的程序 
;這是設置SDRAM,flash ROM 存儲器連接和工作時序的程序,片選定義的程序 
;SMRDATA map在下面的程序中定義 
;SMRDATA中涉及的值請參考memcfg.s程序 
;具體寄存器各位含義請參考s3c44b0 spec

	;Set memory control registers
	adr	r0, SMRDATA	;can't use ldr r0, =xxxx important!!!
	ldr	r1, =BWSCON	;BWSCON Address
	add	r2, r0, #52	;End address of SMRDATA
0       
	ldr	r3, [r0], #4    
	str	r3, [r1], #4    
	cmp	r2, r0		
	bne	%B0

;4 初始化堆棧