?? os_cpu_a_task16.asm
字號(hào):
;*********************************************************************************************************
;** Small RTOS 51
;** The Real-Time Kernel For Keil c51
;**
;** (c) Copyright 2002-2002, chenmingji
;** All Rights Reserved
;**
;** V1.00
;**
;**
;** 文件名: OS_CPU_A.ASM
;** 創(chuàng)建人: 陳明計(jì)
;** 日 期: 2002年6月20日
;** 描 述: 16任務(wù)版的Small RTOS 51 與CPU(8051系列)相關(guān)的匯編程序
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人:
;** 日 期:
;** 描 述:
;**
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
#include "OS_CPU.H"
NAME OS_CPU_A_ASM
?PR?OSCtxSw?OS_CPU_A SEGMENT CODE ;INBLOCK
?PR?OSIntCtxSw?OS_CPU_A SEGMENT CODE ;INBLOCK
?PR?LoadCtx?OS_CPU_A SEGMENT CODE ;INBLOCK
?PR?C_OSCtxSw?OS_CPU_C SEGMENT CODE
; EXTRN CODE (C_OSCtxSw)
EXTRN CODE (OSMapTbl)
EXTRN DATA (OSFastSwap)
EXTRN DATA (OSTaskID)
EXTRN DATA (OSNextTaskID)
EXTRN DATA (OSTsakStackBotton)
IF EN_SP2 <> 0
EXTRN IDATA (Sp2)
ENDIF
PUBLIC LoadCtx
PUBLIC OSIntCtxSw
PUBLIC OSCtxSw
PUBLIC STACK
;****************************************************************************************
;?STACK SEGMENT IDATA
?STACK SEGMENT IDATA
RSEG ?STACK
STACK:
DS 1
;****************************************************************************************
;/*********************************************************************************************************
;** 函數(shù)名稱: LoadCtx
;** 功能描述: 任務(wù)環(huán)境恢復(fù)函數(shù)
;** 輸 入: OSTaskID,OSFastSwap
;** 輸 出 : 無
;** 全局變量: 無
;** 調(diào)用模塊: 無
;**
;** 作 者: 陳明計(jì)
;** 日 期: 2002年2月22日
;**-------------------------------------------------------------------------------------------------------
;** 修 改:
;** 日 期:
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
RSEG ?PR?LoadCtx?OS_CPU_A
LoadCtx:
USING 0
MOV R2,OSFastSwap+1
MOV R1,OSFastSwap
MOV R0,OSTaskID
INC R0
LoadCtx_1:
MOV A,R1
RRC A
MOV R1,A
MOV A,R2
RRC A
MOV R2,A
DJNZ R0,LoadCtx_1
JC LoadCtx_2
POP 7
POP 6
POP 5
POP 4
POP 3
POP 2
POP 1
POP 0
POP PSW
POP DPL
POP DPH
POP B
POP ACC
LoadCtx_2:
SET_EA
RET
;****************************************************************************************
;/*********************************************************************************************************
;** 函數(shù)名稱: OSCtxSw
;** 功能描述: 任務(wù)主動(dòng)放棄CPU環(huán)境保存函數(shù)
;** 輸 入: OSTaskID
;** 輸 出 : 無
;** 全局變量: OSFastSwap
;** 調(diào)用模塊: 無
;**
;** 作 者: 陳明計(jì)
;** 日 期: 2002年2月22日
;**-------------------------------------------------------------------------------------------------------
;** 修 改:
;** 日 期:
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
RSEG ?PR?OSCtxSw?OS_CPU_A
OSCtxSw:
USING 0
MOV DPTR,#OSMapTbl
MOV A,OSTaskID
CLR C
SUBB A,#8
JC OSCtxSw_1
MOVC A,@A+DPTR
ORL A,OSFastSwap
MOV OSFastSwap,A
LJMP C_OSCtxSw
OSCtxSw_1:
MOV A,OSTaskID
MOVC A,@A+DPTR
ORL A,OSFastSwap+1
MOV OSFastSwap+1,A
LJMP C_OSCtxSw
;****************************************************************************************
;/*********************************************************************************************************
;** 函數(shù)名稱: C_OSCtxSw
;** 功能描述: 堆棧處理函數(shù)
;** 輸 入: 無
;** 輸 出 : 無
;** 全局變量: OSTaskID,OSTsakStackBotton,SP
;** 調(diào)用模塊: LoadCtx
;**
;** 作 者: 陳明計(jì)
;** 日 期: 2002年2月22日
;**-------------------------------------------------------------------------------------------------------
;** 修 改:
;** 日 期:
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
RSEG ?PR?C_OSCtxSw?OS_CPU_C
C_OSCtxSw:
mov r2,sp
; cp1 = (unsigned char idata *)SP +1;
MOV R0,SP
IF EN_SP2 <> 0
mov sp,#(Sp2-1)
ENDIF
INC R0
; temp = (unsigned char )OSTsakStackBotton[OSNextTaskID+1];
MOV A,#LOW (OSTsakStackBotton+01H)
ADD A,OSNextTaskID
MOV R1,A
MOV A,@R1
MOV R7,A
; cp2 = OSTsakStackBotton[OSTaskID+1];
MOV A,#LOW (OSTsakStackBotton+01H)
ADD A,OSTaskID
MOV R1,A
MOV A,@R1
MOV R1,A
; if( OSNextTaskID > OSTaskID)
MOV A,OSNextTaskID
SETB C
SUBB A,OSTaskID
JC ?C0001
; {
; while(cp2 != (unsigned char idata *)temp)
; {
; *cp1++ = *cp2++;
; }
MOV A,R7
CLR C
SUBB A,R1
MOV R6,A
?C0002:
MOV A,@R1
MOV @R0,A
INC R0
INC R1
DJNZ R6,?C0002
?C0003:
; temp = OSTsakStackBotton[OSTaskID+1] - (unsigned char idata *)SP-1;
MOV A,#LOW (OSTsakStackBotton+1)
ADD A,OSTaskID
MOV R1,A
MOV A,@R1
SETB C
;SUBB A,sp
SUBB A,r2
MOV R7,A
; SP = (unsigned char )cp1 - 1;
DEC R0;
MOV SP,R0
; for(i = OSTaskID+1;i < OSNextTaskID+1; i++)
; {
; OSTsakStackBotton[i] -= temp;
; }
MOV A,OSNextTaskID
CLR C
SUBB A,OSTaskID
MOV R6,A
JZ ?C0005
MOV A,#LOW (OSTsakStackBotton)
ADD A,OSTaskID
MOV R1,A
MOV A,R7
CPL A
INC A
MOV R7,A
?C0004:
INC R1
MOV A,R7
ADD A,@R1
MOV @R1,A
DJNZ R6,?C0004
?C0005:
; OSTaskID = OSNextTaskID;
MOV OSTaskID,OSNextTaskID
; LoadCtx();
LJMP LoadCtx
; }
?C0001:
;
; if( OSNextTaskID != OSTaskID)
MOV A,OSNextTaskID
XRL A,OSTaskID
JZ ?C000r
; {
; cp2--;
; cp1--;
; while(cp2 != (unsigned char idata *)temp)
; {
; *cp2-- = *cp1--;
; }
;MOV A,R7
;CLR C
;SUBB A,R1
;MOV R6,A
mov a,r0
clr c
subb a,r7
mov r6,a
?C0008:
DEC R0
DEC R1
MOV A,@R0
MOV @R1,A
DJNZ R6,?C0008
?C0009:
; temp = OSTsakStackBotton[OSTaskID+1] - (unsigned char idata *)SP-1;
MOV A,#LOW (OSTsakStackBotton+01H)
ADD A,OSTaskID
MOV R1,A
MOV A,@R1
SETB C
;SUBB A,SP
SUBB A,r2
MOV R7,A
; SP = (unsigned char )OSTsakStackBotton[OSNextTaskID+1];
MOV A,#LOW (OSTsakStackBotton+01H)
ADD A,OSNextTaskID
MOV R1,A
MOV A,@R1
MOV SP,A
; for(i = OSNextTaskID+1;i < OSTaskID+1; i++)
; {
; OSTsakStackBotton[i] += temp;
; }
MOV A,OSTaskID
CLR C
SUBB A,OSNextTaskID
JZ ?C0011
MOV R6,A
MOV A,#LOW (OSTsakStackBotton)
ADD A,OSNextTaskID
MOV R1,A
?C0010:
INC R1
MOV A,R7
ADD A,@R1
MOV @R1,A
DJNZ R6,?C0010
?C0011:
; OSTaskID = OSNextTaskID;
MOV OSTaskID,OSNextTaskID
; SP--;
DEC SP
; }
?C0007:
; LoadCtx();
LJMP LoadCtx
?C000r:
mov SP,r2
LJMP LoadCtx
;****************************************************************************************
;/*********************************************************************************************************
;** 函數(shù)名稱: OSIntCtxSw
;** 功能描述: 中斷使任務(wù)放棄CPU環(huán)境保存函數(shù)
;** 輸 入: OSTaskID
;** 輸 出 : 無
;** 全局變量: OSFastSwap
;** 調(diào)用模塊: 無
;**
;** 作 者: 陳明計(jì)
;** 日 期: 2002年2月22日
;**-------------------------------------------------------------------------------------------------------
;** 修 改:
;** 日 期:
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
RSEG ?PR?OSIntCtxSw?OS_CPU_A
OSIntCtxSw:
USING 0
MOV DPTR,#OSMapTbl
MOV A,OSTaskID
CLR C
SUBB A,#8
JC OSIntCtxSw_1
MOVC A,@A+DPTR
CPL A
ANL A,OSFastSwap
MOV OSFastSwap,A
SJMP OSIntCtxSw_2
OSIntCtxSw_1:
MOV A,OSTaskID
MOVC A,@A+DPTR
CPL A
ANL A,OSFastSwap+1
MOV OSFastSwap+1,A
OSIntCtxSw_2:
;SP=SP-4
MOV A,#0FCH
ADD A,SP
MOV SP,A
MOV A, #LOW C_OSCtxSw
PUSH ACC
MOV A, #HIGH C_OSCtxSw
PUSH ACC
RETI
;****************************************************************************************
END
?? 快捷鍵說明
復(fù)制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號(hào)
Ctrl + =
減小字號(hào)
Ctrl + -