VERSION 5.00
Object = "{5E9E78A0-531B-11CF-91F6-C2863C385E30}#1.0#0"; "MSFLXGRD.OCX"
Begin VB.Form frmVehicle 
   Caption         =   "車輛列表"
   ClientHeight    =   4368
   ClientLeft      =   60
   ClientTop       =   348
   ClientWidth     =   6804
   LinkTopic       =   "Form1"
   MDIChild        =   -1  'True
   ScaleHeight     =   4368
   ScaleWidth      =   6804
   WindowState     =   2  'Maximized
   Begin MSFlexGridLib.MSFlexGrid msgList 
      Height          =   3135
      Left            =   120
      TabIndex        =   1
      Top             =   600
      Width           =   6255
      _ExtentX        =   11028
      _ExtentY        =   5525
      _Version        =   393216
      Cols            =   4
      FixedCols       =   3
      AllowUserResizing=   1
   End
   Begin VB.Label lblTitle 
      Caption         =   "車    輛    列    表"
      BeginProperty Font 
         Name            =   "宋體"
         Size            =   12
         Charset         =   134
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      ForeColor       =   &H8000000D&
      Height          =   255
      Left            =   240
      TabIndex        =   0
      Top             =   120
      Width           =   3015
   End
End
Attribute VB_Name = "frmVehicle"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Public txtSQL As String
Dim mrc As ADODB.Recordset
Dim MsgText As String
Private Sub Form_Load()
    ShowTitle
    ShowData
    flagvEdit = True
    
    
End Sub

Private Sub Form_Resize()
    If Me.WindowState <> vbMinimized And fMainForm.WindowState <> vbMinimized Then
        '邊界處理
        If Me.ScaleHeight < 10 * lblTitle.Height Then
            
            Exit Sub
        End If
        If Me.ScaleWidth < lblTitle.Width + lblTitle.Width / 2 Then
            
            Exit Sub
        End If
        '控制控件的位置
                
        lblTitle.Top = lblTitle.Height
        lblTitle.Left = (Me.Width - lblTitle.Width) / 2
        
        msgList.Top = lblTitle.Top + lblTitle.Height + lblTitle.Height / 2
        msgList.Width = Me.ScaleWidth - 200
        msgList.Left = Me.ScaleLeft + 100
        msgList.Height = Me.ScaleHeight - msgList.Top - 200
    End If
End Sub

Public Sub RecordEdit()
    Dim intCount As Integer
    
    If msgList.Rows > 1 Then
        gintmode = EDIT
        intCount = msgList.Row
        gsSql = " where clid='" & Trim(msgList.TextMatrix(msgList.Row, 1)) & "'"
        frmVehicle1.Show 1
        ShowData
        Call MovCursor(intCount, msgList)
    Else
        Call RecordAdd
    End If
        
End Sub

Public Sub FormClose()
    Unload Me
End Sub

'刪除記錄
Public Sub RecordDelete()
    Dim sSql As String
    Dim intCount As Integer
    
  On Error GoTo myErr
    
    If msgList.Rows > 1 Then
        If MsgBox("真的要?jiǎng)h除這條文件記錄么？", vbOKCancel + vbExclamation, "警告") = vbOK Then
            intCount = msgList.Row
            sSql = "delete from " & msTableName & " where clid='" & Trim(msgList.TextMatrix(msgList.Row, 1)) & "'"

            dbHuaxia.Execute sSql, dbSQLPassThrough
            ShowData
            If msgList.Rows > 1 Then
                If intCount = msgList.Rows Then
                    MovCursor msgList.Rows - 1, msgList
                Else
                    MovCursor intCount, msgList
                End If
            End If
        End If
    End If
    
    Exit Sub
    
myErr:
    ShowError
End Sub
Public Sub RecordRefresh()
    '設(shè)置msSql
    msSql = msSelect & msTableName & msOrderBy
        
    '顯示數(shù)據(jù)
    msBarText = "當(dāng)前數(shù)據(jù)時(shí)間范圍：所有時(shí)間段"
    sOrder0 = "+ {clid}"
    sOrder1 = ""
    ShowData
End Sub


Public Sub RecordAdd()
    gintmode = Add
    frmVehicle1.Show 1
    ShowData
End Sub

Public Sub RecordFind()
    frmVehicle2.Show 1
    If Trim(frmVehicle2.sQSql & " ") <> "" Then

        msSql = msSelect & msTableName & " where" & frmVehicle2.sQSql & msOrderBy

        ShowData
    End If
    Unload frmVehicle2
End Sub

Private Sub Form_Unload(Cancel As Integer)
    flagvEdit = False
    gintvMode = 0
End Sub
'顯示Grid的內(nèi)容

Private Sub ShowData()
    Dim j As Integer
    Dim i As Integer


    Set mrc = ExecuteSQL(txtSQL, MsgText)
    With msgList
        .Rows = 1
        
        Do While Not mrc.EOF
            .Rows = .Rows + 1
            For i = 1 To mrc.Fields.Count
                Select Case mrc.Fields(i - 1).Type
                    Case adDBDate
                        .TextMatrix(.Rows - 1, i) = Format(mrc.Fields(i - 1) & "", "yyyy-mm-dd")
                    Case Else
                        .TextMatrix(.Rows - 1, i) = mrc.Fields(i - 1) & ""
                End Select
            Next i
            mrc.MoveNext
        Loop
    End With
    mrc.Close
End Sub


'顯示Grid表頭
Private Sub ShowTitle()
    Dim i As Integer
    
    With msgList
        .Cols = 13
        .TextMatrix(0, 1) = "車號(hào)"
        .TextMatrix(0, 2) = "類型"
        .TextMatrix(0, 3) = "車主"
        .TextMatrix(0, 4) = "發(fā)動(dòng)機(jī)號(hào)"
        .TextMatrix(0, 5) = "車架號(hào)"
        .TextMatrix(0, 6) = "廠牌型號(hào)"
        .TextMatrix(0, 7) = "總質(zhì)量"
        .TextMatrix(0, 8) = "核定載客"
        .TextMatrix(0, 9) = "登記時(shí)間"
        .TextMatrix(0, 10) = "發(fā)證時(shí)間"
        .TextMatrix(0, 11) = "顏色"
        .TextMatrix(0, 12) = "主要司機(jī)"
        
        '固定表頭
        .FixedRows = 1
                
        '設(shè)置各列的對(duì)齊方式
        For i = 0 To 6
            .ColAlignment(i) = 0
        Next i
        For i = 7 To 8
            .ColAlignment(i) = 7
        Next i
        For i = 9 To 12
            .ColAlignment(i) = 0
        Next i
        
        '表頭項(xiàng)居中
        .FillStyle = flexFillRepeat
        .Col = 0
        .Row = 0
        .RowSel = 1
        .ColSel = .Cols - 1
        .CellAlignment = 4
        
        '設(shè)置單元大小
        .ColWidth(0) = 300
        .ColWidth(1) = 1000
        .ColWidth(2) = 1000
        .ColWidth(3) = 2000
        .ColWidth(4) = 1000
        .ColWidth(5) = 1000
        .ColWidth(6) = 2000
        .ColWidth(7) = 1000
        .ColWidth(8) = 1000
        .ColWidth(9) = 1000
        .ColWidth(10) = 1000
        .ColWidth(11) = 1000
        .ColWidth(12) = 1000
        .Row = 1
    End With
End Sub


Private Sub msgList_MouseUp(Button As Integer, Shift As Integer, x As Single, y As Single)
    '右鍵彈出
    If Button = 2 And Shift = 0 Then
        PopupMenu fMainForm.menuCars
    End If
    
    
End Sub