;**********************************************************************
;   保護模式下的編程示例 (MASM6.0)			陳家祺	1996.6
;
;   1 實模式進入保護模式及保護模式返回實模式方法
;   2 保護模式下的指令操作(直接寫屏,滿屏顯示'A')
;   * 環境: MASM6.0,TASM3.0, DOS6.2, 80486主機, Himem.sys, 不能裝載Emm386.exe
;**********************************************************************
.MODEL SMALL
jumpfar	MACRO	segf,offsetf		;保護模式跳轉指令
	db 0eah				;功能與目的:
	dw (offset offsetf)		; 1. 清除指令隊列
	dw segf				; 2. 指定代碼段segf -> CS
	ENDM

desc 	struc			;全局描述符GDT的選擇器結構
  limit_15_0    dw ?		;界限15-0
  base_15_0   	dw ?		;基地址15-0
  base_23_16   	db ?		;基地址23-16
  access   	db ?		;訪問權
  gran     	db ?		;粒度,類型,界限19-16
  base_31_24   	db ?		;基地址31-24
desc 	ends
.DATA				;數據段
save_gdt	dw 4 dup (?)	;GDT保存區
save_ss		dw ?		;SS保存區

;	*****	GDT 描述符表	*****
gdt_def		LABEL	BYTE
		desc < >		;必須為空描述符
gdt_kcs		desc <0ffffh,0000h,00h,9ah,0fh,00h>	;00000 - fffffH (1Mb)
gdt_kds		desc <0ffffh,0000h,00h,92h,0fh,00h> 	;00000 - fffffH (1Mb)
gdt_kss		desc <00000h,0000h,00h,96h,00h,00h>
gdt_uds		desc <0ffffh,0000h,00h,92h,0fh,00h>	;00000 - fffffH (1Mb)
gdt_end		LABEL	BYTE
					;設置GDTR用
gdtsize		dw gdt_end-gdt_def	;GDT描述符表的長度
gdtload		dw ?			;GDT描述符表的線性基地址15-0,
		dw ?			;GDT描述符表的線性基地址31-16
gdt_kcs_sel 	equ 08h		; CS選擇器
gdt_kds_sel 	equ 10h		; DS選擇器
gdt_kss_sel 	equ 18h		; SS選擇器
gdt_uds_sel 	equ 20h		; 用戶DS選擇器

char		db   'A'	; 要顯示的字符

.STACK				;堆棧段, 堆棧空間為1024
.CODE   			;代碼段

	.STARTUP			; 設置CS,SS和SP
	cli
	mov ax,ss			; 設置SS
	mov save_ss,ax			; 保存SS
	call prot			; 調用保護模式操作子程
	sti
	mov	ah,0
	int	16h			; BIOS鍵盤中斷調用,等待按鍵!
	.EXIT 0				; 返回DOS!

.386p
prot 	proc near
	SGDT fword ptr save_gdt		; 保存原GDT

	mov di,offset gdt_kcs		; 設置CS描述符的基地址
	mov ax,cs			; 將實模式DOS的段地址
	call copy_desc			; 換算為線性基地址

	mov di,offset gdt_kds		; 設置DS描述符的基地址
	mov ax,ds			; 將實模式DOS的段地址
	call copy_desc			; 換算為線性基地址

	mov di,offset gdt_kss		; 設置SS描述符的基地址
	mov ax,ss			; 將實模式DOS的段地址
	call copy_desc			; 換算為線性基地址

	mov ax,ds			; 計算GTD表的線性地址
	mov cx,10h
	mul cx
	add ax,offset gdt_def
	adc dx,0
	mov gdtload,ax
	mov gdtload+2,dx

	LGDT fword ptr gdtsize		; 裝載GDT

	mov eax,cr0			
	or  al,1			; 設置控制寄存器CR0的PE位
	mov cr0,eax			; 進入保護模式
	jumpfar	gdt_kcs_sel,prot_user	; 清除指令隊列,
prot_user:				; CS=gdt_kcs_sel(保護模式碼段)
	call vram_disp			; 調用保護模式下顯示子程

	mov eax,cr0			
	and al,0feh			;清除控制寄存器CR0的PE位
	mov cr0,eax			;切換到實模式
	jumpfar	_TEXT,real_mode		;清除指令隊列,CS=CODE(實模式碼段) 
real_mode:				
	mov ax,_DATA
	mov ds,ax			;恢復DOS數據段

	LGDT fword ptr save_gdt		;恢復原GDT
	mov ss,save_ss			;恢復DOS堆棧段
	ret
prot  endp

vram_disp proc near			;保護模式下直接寫屏子程
	pushad
	mov ax,gdt_kds_sel
	mov ds,ax
	mov dl,char			;顯示字符'A'
	mov ax,gdt_uds_sel
	mov ds,ax
	mov cx,80*25			;滿屏字符數.
	mov ebx,0b8000h
	mov ah,17h			;字符顏色屬性,藍底白字
	mov al,dl			;顯示字符'A'
l1:	mov [ebx],ax
	add ebx,2
	loop l1
	popad
	ret
vram_disp endp	

copy_desc proc near			;設置GDT描述符的基地址
	mov cx,10h			;將實模式DOS的段地址
	mul cx				;換算為24位線性地址
	mov [di].base_15_0,ax		;存入GDT描述符中
	mov [di].base_23_16 ,dl
	ret
copy_desc endp

   	END 
;****************************** 源程序結束 ******************************