?? logic_content.asp

?? 學習管理校友錄有關的系統本人學習的結果與大家共享
?? ASP
字號:
<%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_content.asp
'= CREATED TIME : 2006-5-8
'= LAST MODIFIED: 2006-5-8
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 內容系統管理
'= Change Log:
'==================================================================='
%>

<%
'== Const define
Const CONST_SORT_NOT_DEFAULT = 1	'== 非默認分類
Const CONST_SORT_DEFAULT = 0		'== 默認分類

Const CONST_SORT_OPEN = 0			'== 分類開啟狀態
Const CONST_SORT_CLOSE = 1			'== 分類關閉狀態


''===================================================================
'= Function    : GetArticlesLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : strWhere : 符合條件
'= Return      : boolean
'= Description : 取得文章集
'==================================================================='
Function GetArticlesLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT ARTICLE_ID,ARTICLE_TITLE,ARTICLE_ORDER,ARTICLE_SORT_ID,ARTICLE_ORDER,ARTICLE_ADD_TIME,ARTICLE_HITS FROM CLASS_ARTICLE  WHERE 1=1 " & strWhere & " ORDER BY ARTICLE_ORDER DESC,ARTICLE_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetArticlesLogic = False
		Exit Function
	End If
	GetArticlesLogic = True
End Function

''===================================================================
'= Function    : GetArticleLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : intArticleId : 文章ID
'= Return      : boolean
'= Description : 取單個文章記錄 
'==================================================================='
Function GetArticleLogic(intArticleId)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ARTICLE"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "ARTICLE_ID",""
	GBL_objPubDB.AddField "ARTICLE_TITLE",""
	GBL_objPubDB.AddField "ARTICLE_CONTENT",""
	GBL_objPubDB.AddField "ARTICLE_ADD_TIME",""
	GBL_objPubDB.AddField "ARTICLE_HITS",""
	GBL_objPubDB.AddField "ARTICLE_SORT_ID",""
	GBL_objPubDB.AddField "ARTICLE_ORDER",""
	GBL_objPubDB.AddField "ARTICLE_KEY",""
	GBL_objPubDB.Where = "ARTICLE_ID=" & intArticleId
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetArticleLogic = False
		Exit Function
	End If
	GetArticleLogic = True
End Function

''===================================================================
'= Function    : SaveArticleLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : intAdminId :  操作管理員ID
'= Input	   : intArticleId : ""--add other--edit
'= Input	   : objFormData : 表單數據
'= Return      : boolean
'= Description : 添加/編輯文章
'==================================================================='
Function SaveArticleLogic(intAdminId,intArticleId,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ARTICLE"
	If intArticleId = "" Then
		GBL_objPubDB.SQLType = "INSERT"
		GBL_objPubDB.AddField "ARTICLE_ADD_TIME",Now()
		GBL_objPubDB.AddField "ARTICLE_ADD_ADMIN_ID",intAdminId
	Else
		GBL_objPubDB.SQLType = "UPDATE"
	End If
	GBL_objPubDB.AddField "ARTICLE_CONTENT",objFormData.Item("Content")
	GBL_objPubDB.AddField "ARTICLE_TITLE",objFormData.Item("Title")
	GBL_objPubDB.AddField "ARTICLE_KEY",objFormData.Item("Key")
	GBL_objPubDB.AddField "ARTICLE_ORDER",objFormData.Item("Order")
	GBL_objPubDB.AddField "ARTICLE_LAST_TIME",Now()
	GBL_objPubDB.AddField "ARTICLE_LAST_ADMIN_ID",intAdminId
	GBL_objPubDB.AddField "ARTICLE_SORT_ID",objFormData.Item("SortId")

	If intArticleId <> "" Then GBL_objPubDB.Where = "ARTICLE_ID=" & intArticleId

	If Not GBL_objPubDB.SQLExecute() Then
		SaveArticleLogic = False
		Exit Function
	End If

	'== 重新統計文章數
	If Not StatArticleNum(objFormData.Item("SortId")) Then 
		SaveArticleLogic = False
		Exit Function
	End If

	SaveArticleLogic = True
End Function

''===================================================================
'= Function    : RemoveArticlesLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : strWhere : 刪除條件
'= Input	   : intSortId : 分類id
'= Return      : boolean
'= Description : 刪除文章
'==================================================================='
Function RemoveArticlesLogic(strWhere,intSortId)	
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ARTICLE"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveArticlesLogic = False
		Exit Function
	End If

	If intSortId <> "" Then
		'== 重新統計文章數
		If Not StatArticleNum(intSortId) Then 
			RemoveArticlesLogic = False
			Exit Function
		End If
	End If

	RemoveArticlesLogic = True
End Function

''===================================================================
'= Function    : GetSortsLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : strWhere : 符合條件
'= Return      : boolean
'= Description : 取得文章類型集
'==================================================================='
Function GetSortsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT SORT_ID,SORT_NAME,SORT_ADD_TIME,SORT_IS_OPEN,SORT_ORDER,SORT_DESC,SORT_IS_DEFAULT,SORT_ARTICLE_NUM FROM CLASS_SORT WHERE 1=1 " & strWhere & " ORDER BY SORT_ORDER DESC,SORT_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetSortsLogic = False
		Exit Function
	End If
	GetSortsLogic = True
End Function

''===================================================================
'= Function    : GetSortLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : intSortId : 信息分類ID
'= Return      : boolean
'= Description : 取單個類型記錄 
'==================================================================='
Function GetSortLogic(intSortId)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SORT"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "SORT_ID",""
	GBL_objPubDB.AddField "SORT_NAME",""
	GBL_objPubDB.AddField "SORT_ORDER",""
	GBL_objPubDB.AddField "SORT_DESC",""
	GBL_objPubDB.AddField "SORT_ADD_TIME",""
	GBL_objPubDB.AddField "SORT_ARTICLE_NUM",""
	GBL_objPubDB.AddField "SORT_IS_OPEN",""
	GBL_objPubDB.Where = "SORT_ID=" & intSortId
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetSortLogic = False
		Exit Function
	End If
	GetSortLogic = True
End Function

''===================================================================
'= Function    : SaveSortLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : intAdminId :  操作管理員ID
'= Input	   : intSortId : ""--add other--edit
'= Input	   : objFormData : 表單數據
'= Return      : boolean
'= Description : 添加/編輯文章類型
'==================================================================='
Function SaveSortLogic(intAdminId,intSortId,objFormData)

	'== 校驗是否重復
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SORT"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "SORT_ID",""
	If intSortId = "" Then
		GBL_objPubDB.Where = "SORT_NAME='" & objFormData.Item("Name") & "'"
	Else
		GBL_objPubDB.Where = "SORT_NAME='" & objFormData.Item("Name") & "' AND SORT_ID <>" & intSortId
	End If
	If Not GBL_objPubDB.SQLRSExecute() Then
		SaveSortLogic = False
		Exit Function
	End If
	If GBL_objPubDB.intRSNum > 0 Then
		Call GBL_objException.catchErr(E_USER_PUB,"該信息分類名(" & objFormData.Item("Name") & ")已存在")
		SaveSortLogic = False
		Exit Function
	End If

	'== 保存記錄
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SORT"
	If intSortId = "" Then
		GBL_objPubDB.SQLType = "INSERT"
		GBL_objPubDB.AddField "SORT_ADD_TIME",Now()
		GBL_objPubDB.AddField "SORT_ADD_ADMIN_ID",intAdminId
		GBL_objPubDB.AddField "SORT_IS_DEFAULT",CONST_SORT_NOT_DEFAULT
	Else
		GBL_objPubDB.SQLType = "UPDATE"
	End If
	GBL_objPubDB.AddField "SORT_NAME",objFormData.Item("Name")
	GBL_objPubDB.AddField "SORT_DESC",objFormData.Item("Desc")
	GBL_objPubDB.AddField "SORT_ORDER",objFormData.Item("Order")
	GBL_objPubDB.AddField "SORT_LAST_TIME",Now()
	GBL_objPubDB.AddField "SORT_LAST_ADMIN_ID",intAdminId
	GBL_objPubDB.AddField "SORT_IS_OPEN",objFormData.Item("IsOpen")
	
	If intSortId <> "" Then GBL_objPubDB.Where = "SORT_ID=" & intSortId

	If Not GBL_objPubDB.SQLExecute() Then
		SaveSortLogic = False
		Exit Function
	End If
	SaveSortLogic = True
End Function

''===================================================================
'= Function    : RemoveSortsLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : strWhere : 刪除條件
'= Return      : boolean
'= Description : 刪除信息分類
'==================================================================='
Function RemoveSortsLogic(strWhere)	
	Dim strSql

	'== 該分類是否可以刪除
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SORT"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "SORT_NAME",""
	GBL_objPubDB.Where = "1=1 " & strWhere & " AND SORT_IS_DEFAULT=" & CONST_SORT_DEFAULT
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveSortsLogic = False
		Exit Function
	End If
	If GBL_objPubDB.intRSNum > 0 Then
		Call GBL_objException.catchErr(E_USER_PUB,"存在默認分類("&GBL_objPubDB.objPubRS("SORT_NAME")& "),不能進行刪除操作")
		RemoveSortsLogic = False
		Exit Function
	End If

	'== 刪除文章
	strSql = " AND ARTICLE_SORT_ID IN (SELECT SORT_ID FROM CLASS_SORT WHERE 1=1 " & strWhere & ")"
	If Not RemoveArticlesLogic(strSql,"") Then 
		RemoveSortsLogic = False
		Exit Function
	End If

	'== 刪除分類記錄
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SORT"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveSortsLogic = False
		Exit Function
	End If
	RemoveSortsLogic = True
End Function

''===================================================================
'= Function    : StatArticleNum()
'= Time		   : Created At 2006-5-8
'= Input	   : intSortId
'= Return      : boolean
'= Description : 統計某一信息分類的數目并更新
'==================================================================='
Function StatArticleNum(intSortId)
	Dim intArticleNum

	'== 取得數目
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ARTICLE"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "COUNT(ARTICLE_ID)",""
	GBL_objPubDB.Where = "ARTICLE_SORT_ID=" & intSortId
	If Not GBL_objPubDB.SQLRSExecute() Then
		StatArticleNum = False
		Exit Function
	End If
	intArticleNum = GBL_objPubDB.objPubRS(0)

	'== 更新記錄
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_SORT"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.AddField "SORT_ARTICLE_NUM",intArticleNum
	GBL_objPubDB.Where = "SORT_ID=" & intSortId
	If Not GBL_objPubDB.SQLExecute() Then
		StatArticleNum = False
		Exit Function
	End If

	StatArticleNum = True
End Function

''===================================================================
'= Function    : GetSortIsDefaultLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : intValue : 信息分類的數字
'= Return      : 信息分類默認的中文含義
'= Description : 取信息分類是否默認
'==================================================================='
Function GetSortIsDefaultLogic(intValue)
	Dim strTmp
	Select Case intValue
		Case CONST_SORT_DEFAULT:
			strTmp = "默認分類"
		Case CONST_SORT_NOT_DEFAULT:
			strTmp = "非默認分類"
		Case CONST_SORT_NOT_DEFAULT:
			strTmp = "非默認分類"
	End Select
	GetSortIsDefaultLogic = strTmp
End Function


''===================================================================
'= Function    : GetSortOpenLogic()
'= Time		   : Created At 2006-5-8
'= Input	   : intValue : 信息分類的狀態
'= Return      : 信息分類的狀態的中文含義
'= Description : 取信息分類的狀態
'==================================================================='
Function GetSortOpenLogic(intValue)
	Dim strTmp
	Select Case intValue
		Case CONST_SORT_OPEN:
			strTmp = "開啟"
		Case CONST_SORT_CLOSE:
			strTmp = "關閉"
		Case CONST_SORT_OPEN:
			strTmp = "開啟"
	End Select
	GetSortOpenLogic = strTmp
End Function

''===================================================================
'= Function    : GetArticleNavLogic()
'= Time		   : Created At 2006-5-9
'= Input	   : strWhere : 符合條件
'= Input	   : intNowId : 當前文章ID
'= Input	   : strUrl : url地址
'= Return      : html
'= Description : 構造文件導航條
'==================================================================='
Function GetArticleNavLogic(intNowId,strWhere,strUrl)
	Dim strTmp

	'== 上一篇
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ARTICLE"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "TOP 1 ARTICLE_TITLE",""
	GBL_objPubDB.AddField "ARTICLE_SORT_ID",""
	GBL_objPubDB.AddField "ARTICLE_ID",""
	GBL_objPubDB.Where = " 1=1 " & strWhere & " AND ARTICLE_ID>" & intNowId
	GBL_objPubDB.Order = "ARTICLE_ORDER DESC,ARTICLE_ID ASC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		strTmp = ""
	End If
	If GBL_objPubDB.intRSNum > 0 Then
		strTmp = strTmp & "<a href=""" & strUrl & "?intArticleId=" & GBL_objPubDB.objPubRS("ARTICLE_ID") & "&intSortId=" & GBL_objPubDB.objPubRS("ARTICLE_SORT_ID") & """>" & "上一篇:" & GBL_objPubDB.objPubRS("ARTICLE_TITLE") & "</a><br>"
	Else
		strTmp = strTmp & "上一篇:已經沒有了<br>"
	End If

	'== 下一篇
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ARTICLE"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "TOP 1  ARTICLE_TITLE",""
	GBL_objPubDB.AddField "ARTICLE_SORT_ID",""
	GBL_objPubDB.AddField "ARTICLE_ID",""
	GBL_objPubDB.Where = " 1=1 " & strWhere & " AND ARTICLE_ID<" & intNowId
	GBL_objPubDB.Order = "ARTICLE_ORDER DESC,ARTICLE_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		strTmp = strTmp & ""
	End If
	If GBL_objPubDB.intRSNum > 0 Then
		strTmp = strTmp & "<a href=""" & strUrl & "?intArticleId=" & GBL_objPubDB.objPubRS("ARTICLE_ID") & "&intSortId=" & GBL_objPubDB.objPubRS("ARTICLE_SORT_ID") & """>" & "下一篇:" & GBL_objPubDB.objPubRS("ARTICLE_TITLE") & "</a><br>"
	Else
		strTmp = strTmp & "下一篇:已經沒有了"
	End If

	GetArticleNavLogic = strTmp
End Function
%>
?? 文件大小 4414 K
?? 上傳用戶 moxcki
?? 所屬分類匯編語言
??? 相關標簽

#家
?? 快捷鍵說明

復制代碼 Ctrl + C
搜索代碼 Ctrl + F
全屏模式 F11
切換主題 Ctrl + Shift + D
顯示快捷鍵 ?
增大字號 Ctrl + =
減小字號 Ctrl + -
亚洲欧美第一页_禁久久精品乱码_粉嫩av一区二区三区免费野_久草精品视频

?? logic_content.asp

?? 快捷鍵說明
