<%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_collection.asp
'= CREATED TIME : 2006-5-6
'= LAST MODIFIED: 2006-5-6
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用戶收藏業(yè)務(wù)邏輯
'= Change Log:
'==================================================================='
%>

<%
Const CONST_COLLECTION_TYPE_USER	= 0		'== 用戶收藏
Const CONST_COLLECTION_TYPE_TOPIC	= 1		'== 帖子收藏
Const CONST_COLLECTION_TYPE_ALBUM	= 2		'== 相片收藏

''===================================================================
'= Function    : GetCollectionLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合條件
'= Return      : boolean
'= Description : 取得收藏記錄
'==================================================================='
Function GetCollectionLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_COLLECTION"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField "COLLECTION_ID",""
	GBL_objPubDB.AddField "COLLECTION_OID",""
	GBL_objPubDB.AddField "COLLECTION_TYPE",""
	GBL_objPubDB.AddField "COLLECTION_OWNER_ID",""
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetCollectionLogic = False
		Exit Function
	End If
	GetCollectionLogic = True
End Function

''===================================================================
'= Function    : GetCollectionsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合條件
'= Return      : boolean
'= Description : 取得收藏記錄
'==================================================================='
Function GetCollectionsLogic(intType,strWhere)
	Dim strSql
	If intType = CONST_COLLECTION_TYPE_USER Then
		strSql = "SELECT USER_REALNAME,USER_ADD_DATE,USER_CLASS,USER_SEX,USER_ACCOUNT,USER_ID, CLASS_COLLECTION.* FROM CLASS_USER,CLASS_COLLECTION WHERE COLLECTION_OID=USER_ID AND COLLECTION_TYPE=" & intType & strWhere
	ElseIf intType = CONST_COLLECTION_TYPE_TOPIC Then
		strSql = "SELECT TOPICS_LAST_POSTER,TOPICS_LAST_POST,TOPICS_REPLY_FORBID,FORUM_NAME,TOPICS_FORUM_ID,TOPICS_CONTENT,TOPICS_OWNER,TOPICS_TITLE,TOPICS_ID,TOPICS_STATUS,TOPICS_HITS,TOPICS_REPLIES,CLASS_COLLECTION.* FROM CLASS_TOPICS,CLASS_FORUM,CLASS_COLLECTION WHERE TOPICS_FORUM_ID=FORUM_ID AND  COLLECTION_OID=TOPICS_ID AND COLLECTION_TYPE=" & intType & strWhere
	ElseIf intType = CONST_COLLECTION_TYPE_ALBUM Then
		strSql = "SELECT ALBUM_IMG_FILE,ALBUM_ADD_TIME,ALBUM_TITLE,ALBUM_OWNER_ID,ALBUM_STATUS,USER_REALNAME,CLASS_COLLECTION.* FROM CLASS_USER,CLASS_ALBUM,CLASS_COLLECTION WHERE USER_ID=ALBUM_OWNER_ID AND  COLLECTION_OID=ALBUM_ID AND COLLECTION_TYPE=" & intType & strWhere
	End If
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = strSql
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetCollectionsLogic = False
		Exit Function
	End If
	GetCollectionsLogic = True
End Function

''===================================================================
'= Function    : SaveCollectionLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用戶ID
'= Input	   : objFormData : 表單數(shù)據(jù)(OID,Type)
'= Return      : boolean
'= Description : 新收藏
'==================================================================='
Function SaveCollectionLogic(intUserId,objFormData)
	Dim strSql

	'== 校驗是否存在
	strSql = " AND COLLECTION_OWNER_ID=" & intUserId & " AND COLLECTION_OID=" & objFormData.Item("OID") & " AND COLLECTION_TYPE=" &  objFormData.Item("Type")
	If Not GetCollectionLogic(strSql) Then 
		SaveCollectionLogic = False
		Exit Function
	End If
	If GBL_objPubDB.intRSNum > 0 Then
		Call GBL_objException.catchErr(E_USER_PUB,"您已添加該收藏")
		SaveCollectionLogic = False
		Exit Function
	End If

	'== 保存記錄
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_COLLECTION"
	GBL_objPubDB.SQLType = "INSERT"
	GBL_objPubDB.AddField "COLLECTION_TYPE",objFormData.Item("Type")
	GBL_objPubDB.AddField "COLLECTION_OID",objFormData.Item("OID")
	GBL_objPubDB.AddField "COLLECTION_OWNER_ID",intUserId
	GBL_objPubDB.AddField "COLLECTION_ADD_TIME",Now()
	If Not GBL_objPubDB.SQLExecute() Then
		SaveCollectionLogic = False
		Exit Function
	End If
	SaveCollectionLogic = True
End Function

''===================================================================
'= Function    : RemoveCollectionLogic(intUserId,strWhere)
'= Time		   : Created At 2006-6-24
'= Input	   : intUserId : 用戶ID
'= Input	   : strWhere : 
'= Return      : boolean
'= Description : 刪除收藏
'==================================================================='
Function RemoveCollectionLogic(intUserId,strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_COLLECTION"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.AddField "COLLECTION_OWNER_ID",intUserId
	GBL_objPubDB.WHERE = "1=1" & strWhere
	If Not GBL_objPubDB.SQLExecute() Then
		RemoveCollectionLogic = False
		Exit Function
	End If
	RemoveCollectionLogic = True
End Function
%>