<%
''===================================================================
'= ASP FILENAME	: /inc/logic/logic_album.asp
'= CREATED TIME : 2006-5-1
'= LAST MODIFIED: 2006-5-1
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用戶相冊處理邏輯
'= Change Log:
'==================================================================='
%>

<%
'== 常/變量定義
Const CONST_ALBUM_UP_STATUS = 0
Const CONST_ALBUM_PASTE_STATUS = 10

''===================================================================
'= Function    : GetAlbumsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 查詢條件
'= Return      : boolean
'= Description : 取相冊記錄集
'==================================================================='
Function GetAlbumsLogic(strWhere)
	GBL_objPubDB.Clear()
	If Instr(strWhere,"ORDER BY") > 0 Then
		GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_REALNAME,ALBUM_STATUS,ALBUM_TITLE,ALBUM_ID,ALBUM_IMG_FILE,ALBUM_HITS,ALBUM_TYPE,ALBUM_REVIEW_NUM,ALBUM_ADD_TIME FROM CLASS_USER,CLASS_ALBUM WHERE ALBUM_OWNER_ID=USER_ID " & strWhere 
	Else
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_REALNAME,ALBUM_STATUS,ALBUM_TITLE,ALBUM_ID,ALBUM_IMG_FILE,ALBUM_HITS,ALBUM_TYPE,ALBUM_REVIEW_NUM,ALBUM_ADD_TIME FROM CLASS_USER,CLASS_ALBUM WHERE ALBUM_OWNER_ID=USER_ID " & strWhere & " ORDER BY ALBUM_ID DESC"
	End If
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetAlbumsLogic = False
		Exit Function
	End If
	GetAlbumsLogic = True
End Function

''===================================================================
'= Function    : GetAlbumReviewsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 查詢條件
'= Return      : boolean
'= Description : 取相冊評論記錄集
'==================================================================='
Function GetAlbumReviewsLogic(strWhere)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_ID,USER_REALNAME,ALBUM_REVIEW_ID,ALBUM_REVIEW_OWNER_ID,ALBUM_REVIEW_PHOTO_ID,ALBUM_REVIEW_CONTENT,ALBUM_REVIEW_ADD_TIME FROM CLASS_USER,CLASS_ALBUM_REVIEW WHERE ALBUM_REVIEW_OWNER_ID=USER_ID " & strWhere & " ORDER BY ALBUM_REVIEW_ID DESC"
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetAlbumReviewsLogic = False
		Exit Function
	End If
	GetAlbumReviewsLogic = True
End Function

''===================================================================
'= Function    : GetAlbumLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intAlbumId : 相冊ID
'= Return      : boolean
'= Description : 取相冊
'==================================================================='
Function GetAlbumLogic(intAlbumId)
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT USER_ACCOUNT,USER_ID,USER_REALNAME,ALBUM_STATUS,ALBUM_TITLE,ALBUM_ID,ALBUM_IMG_FILE,ALBUM_HITS,ALBUM_TYPE,ALBUM_REVIEW_NUM,ALBUM_ADD_TIME FROM CLASS_USER,CLASS_ALBUM WHERE ALBUM_OWNER_ID=USER_ID AND ALBUM_ID=" & intAlbumId
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetAlbumLogic = False
		Exit Function
	End If
	GetAlbumLogic = True
End Function

''===================================================================
'= Function    : RemoveAlbumsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 相冊刪除條件
'= Return      : boolean
'= Description : 刪除相冊
'==================================================================='
Function RemoveAlbumsLogic(strWhere)
	Dim strSql

	'== 刪除相片評論
	strSql = " AND ALBUM_REVIEW_PHOTO_ID IN (SELECT ALBUM_ID FROM CLASS_ALBUM WHERE 1=1 " & strWhere & ")"
	If Not RemoveAlbumReviewsLogic(strSql,0) Then
		RemoveAlbumsLogic = False
		Exit Function
	End If
	
	'== 刪除圖片文件
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "SELECT"
	GBL_objPubDB.AddField  "ALBUM_IMG_FILE",""
	GBL_objPubDB.Where = " ALBUM_STATUS=" & CONST_ALBUM_UP_STATUS & " " & strWhere
	If Not GBL_objPubDB.SQLRSExecute() Then
		RemoveAlbumsLogic = False
		Exit Function
	End If
	While Not GBL_objPubDB.objPubRS.Eof
		Call fsoDeleteFile(GBL_strHomeURL & GBL_strImgAlbum & GBL_objPubDB.objPubRS("ALBUM_IMG_FILE"))
		Response.Write GBL_strHomeURL & GBL_strImgAlbum & GBL_objPubDB.objPubRS("ALBUM_IMG_FILE")
		GBL_objPubDB.objPubRS.MoveNext
	Wend

	'== 刪除相冊記錄
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLExecute() Then
		RemoveAlbumsLogic = False
		Exit Function
	End If

	RemoveAlbumsLogic = True
End Function
''===================================================================
'= Function    : StatisticsAlbumReviewNums()
'= Time		   : Created At 2006-5-7
'= Input	   : strWhere : 符合條件
'= Return      : boolean
'= Description : 重新統計相冊的評論數
'==================================================================='
Function StatisticsAlbumReviewNums(strWhere)
	Dim intNum,arrTmp,i,strIds

	'== 取得刪除評論所涉及到的相片及其評論數
	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "SELECT ALBUM_REVIEW_PHOTO_ID,COUNT(ALBUM_REVIEW_ID) FROM CLASS_ALBUM_REVIEW,CLASS_ALBUM WHERE ALBUM_ID=ALBUM_REVIEW_PHOTO_ID AND 1=1 " & strWhere & "  GROUP BY ALBUM_REVIEW_PHOTO_ID" 
	If Not GBL_objPubDB.SQLRSExecute() Then
		StatisticsAlbumReviewNums = False
		Exit Function
	End If
	intNum = GBL_objPubDB.intRsNum

	If intNum > 0 Then
		arrTmp = GBL_objPubDB.objPubRS.GetRows(-1)
		'== 更新相片評論數
		For i = 0 To intNum - 1
			GBL_objPubDB.Clear()
			GBL_objPubDB.AllSQL = "UPDATE CLASS_ALBUM SET ALBUM_REVIEW_NUM=" & arrTmp(1,i) & " WHERE ALBUM_ID=" & arrTmp(0,i)
			If Not GBL_objPubDB.SQLExecute() Then
				StatisticsAlbumReviewNums = False
				Exit Function
			End If
		Next
	End If

	If IsArray(arrTmp) Then Erase arrTmp

	StatisticsAlbumReviewNums = True
End Function

''===================================================================
'= Function    : RemoveAlbumReviewsLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strWhere : 符合條件
'= Input	   : intAlbumId : 若存在且大于0,則僅對該相片重新統計評論數,若為0則不統計
'= Return      : boolean
'= Description : 刪除相冊評論
'==================================================================='
Function RemoveAlbumReviewsLogic(strWhere,intAlbumId)
	'== 刪除記錄
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM_REVIEW"
	GBL_objPubDB.SQLType = "DELETE"
	GBL_objPubDB.Where = " 1=1 " & strWhere
	If Not GBL_objPubDB.SQLExecute() Then
		RemoveAlbumReviewsLogic = False
		Exit Function
	End If

	'== 更新相冊評論數
	If IsNumeric(intAlbumId) And intAlbumId > 0 Then
		If Not StatisticsAlbumReviewNums(" AND ALBUM_ID=" &intAlbumId) Then
			RemoveAlbumReviewsLogic = False
			Exit Function
		End If
	ElseIf intAlbumId = "" Then
		If Not StatisticsAlbumReviewNums("") Then
			RemoveAlbumReviewsLogic = False
			Exit Function
		End If
	End If

	RemoveAlbumReviewsLogic = True
End Function

''===================================================================
'= Function    : GetAlbumImgLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strImg : 圖片文件記錄
'= Input	   : strStatus : 圖片文件狀態(0--本地文件 10--網絡文件)
'= Return      : 圖片文件地址
'= Description : 取圖片文件地址
'==================================================================='
Function GetAlbumImgLogic(strImg,strStatus)
	If strStatus = 10 Then
		GetAlbumImgLogic = strImg
	Else
		GetAlbumImgLogic = GBL_strHomeURL & GBL_strImgAlbum & strImg 
	End If
End Function

''===================================================================
'= Function    : UpLoadAlbumFileLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strFormName : 文件提交表單名
'= Input	   : strPicName : 圖片文件名
'= Input	   : objDataForm : 表單數據
'= Return      : boolean
'= Description : 上傳圖片文件
'==================================================================='
Function UpLoadAlbumFileLogic(strFormName,ByRef strPicName,ByRef objFormData)
	Dim claUpLoad,objFileUp,iCount,strUpFilePath,intFileMaxSize,strFileType,intNameSet
	Dim intTypeFlag,strAddInfo
	'== 設置文件類型
	strFileType = GBL_strAlbumFileType