'== 設置文件上限
	intFileMaxSize = GBL_intAlbumMaxSize * 1000 

	'== 設置文件保存路徑
	strUpFilePath = GBL_strHomeUrl & GBL_strImgAlbum

	'== 設置文件名產生方式
	intNameSet = 1

	Set claUpLoad = New classFileUpLoad
	iCount = 0
	strAddInfo = "NULL"

	For Each strFormName In claUpLoad.objFile '== 列出所有上傳了的文件
		Set objFileUp = claUpLoad.file(strFormName)  '== 生成一個文件對象
		If objFileUp.FileSize > 0 Then   '== the file is not null
			If objFileUp.FileSize < intFileMaxSize Then 
				If strFileType <> "" Then	'== check the file type
					If Instr(strFileType,GetExtendName(objFileUp.FileName)) And CheckFileType(objFileUp.FileType) Then
						intTypeFlag = 1    
					 Else
						intTypeFlag = 0	
						strAddInfo = "不支持您所上傳的文件類型：" & GetExtendName(objFileUp.FileName)
						Call GBL_objException.catchErr(E_USER_PUB,strAddInfo)
						UpLoadAlbumFileLogic = False
						Exit Function
					End If
				Else
					intTypeFlag = 1	
				End If

				If intTypeFlag = 1 Then 
					strPicName = MakeFileName(Now())
					If intNameSet = 1 Then
						strPicName = strPicName & iCount & "." & GetExtendName(objFileUp.FileName)
					ElseIf intNameSet = 2 Then
						strPicName = objFileUp.FileName
					ElseIf intNameSet = 3 Then
						strPicName = strPicName & iCount & objFileUp.FileName
					End If
					objFileUp.SaveAs Server.Mappath(strUpFilePath & strPicName) 
					iCount = iCount + 1

					'== Get other form data
					objFormData.Item("PicTitle") = Trim(claUpload.form("iptPicTitle"))
					'strPicIntro = Trim(claUpload.form("txtPicIntro"))
					objFormData.Item("PicType") = Trim(claUpload.form("selPicType"))

				End If
			Else
				strAddInfo = "文件大小超出限制，您最多可以上傳 " & intFileMaxSize/1000	& "K字節的文件數據"
				Call GBL_objException.catchErr(E_USER_PUB,strAddInfo)
				UpLoadAlbumFileLogic = False
				Exit Function
			End If
		End If
		Set objFileUp = Nothing
	Next

	Set claUpLoad = Nothing 

	If iCount < 0 Then 
		Call GBL_objException.catchErr(E_USER_PUB,"上傳文件失敗")
		UpLoadAlbumFileLogic = False
		Exit Function
	End If

	UpLoadAlbumFileLogic = True
End Function

''===================================================================
'= Function    : SaveAlbumLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用戶ID
'= Input	   : objDataForm : 表單數據
'= Input	   : strPicName : 圖片文件名
'= Return      : boolean
'= Description : 保存上傳圖片記錄
'==================================================================='
Function SaveAlbumLogic(intUserId,objDataForm,strPicName)
	
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "INSERT"
	GBL_objPubDB.AddField "ALBUM_IMG_FILE",strPicName
	GBL_objPubDB.AddField "ALBUM_TITLE",objDataForm.Item("PicTitle")
	GBL_objPubDB.AddField "ALBUM_TYPE",objDataForm.Item("PicType")
	GBL_objPubDB.AddField "ALBUM_COLLECTIONID",1
	GBL_objPubDB.AddField "ALBUM_OWNER_ID",intUserId
	GBL_objPubDB.AddField "ALBUM_ADD_TIME",NOW()
	GBL_objPubDB.AddField "ALBUM_STATUS",CONST_ALBUM_UP_STATUS
	If Not GBL_objPubDB.SQLExecute() Then
		SaveAlbumLogic = False
		Exit Function
	End If
	SaveAlbumLogic = True
End Function

''===================================================================
'= Function    : SavePasteAlbumLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId : 用戶ID
'= Input	   : objDataForm : 表單數據
'= Input	   : strPicName : 圖片文件名
'= Return      : boolean
'= Description : 保存粘貼網絡圖片記錄
'==================================================================='
Function SavePasteAlbumLogic(intUserId,objDataForm)
	
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "INSERT"
	GBL_objPubDB.AddField "ALBUM_IMG_FILE",objDataForm.Item("PicUrl")
	GBL_objPubDB.AddField "ALBUM_TITLE",objDataForm.Item("PicTitle")
	GBL_objPubDB.AddField "ALBUM_TYPE",objDataForm.Item("PicType")
	GBL_objPubDB.AddField "ALBUM_COLLECTIONID",1
	GBL_objPubDB.AddField "ALBUM_OWNER_ID",intUserId
	GBL_objPubDB.AddField "ALBUM_ADD_TIME",NOW()
	GBL_objPubDB.AddField "ALBUM_STATUS",CONST_ALBUM_PASTE_STATUS
	If Not GBL_objPubDB.SQLExecute() Then
		SavePasteAlbumLogic = False
		Exit Function
	End If
	SavePasteAlbumLogic = True
End Function

''===================================================================
'= Function    : GetAlbumFileUrlLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : strDBRecord 
'= Input	   : intStatus 
'= Return      : boolean
'= Description : 取得圖片文件地址
'==================================================================='
Function GetAlbumFileUrlLogic(strDBRecord,intStatus)
	If intStatus = CONST_ALBUM_PASTE_STATUS Then
		GetAlbumFileUrlLogic = strDBRecord
	Else
		GetAlbumFileUrlLogic = GBL_strHomeUrl & GBL_strImgAlbum & strDBRecord
	End If
End Function

''===================================================================
'= Function    : GetLastNextAlbumIdLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intAlbumId 
'= Output	   : intLastId 
'= Output	   : intNextId 
'= Return      : boolean
'= Description : 取得上一張下一張ID
'==================================================================='
Function GetLastNextAlbumIdLogic(intAlbumId,ByRef intLastId,intNextId)
	intLastId = GetNextRS("ALBUM_ID","CLASS_ALBUM","ALBUM_ID>" & intAlbumId,"ALBUM_ID ASC")
	intNextId = GetNextRS("ALBUM_ID","CLASS_ALBUM","ALBUM_ID<" & intAlbumId,"ALBUM_ID DESC")
End Function

''===================================================================
'= Function    : SaveAlbumReviewLogic()
'= Time		   : Created At 2006-5-5
'= Input	   : intUserId 
'= Input	   : intAlbumId 
'= Input	   : objFormData 
'= Return      : boolean
'= Description : 保存相片評論
'==================================================================='
Function SaveAlbumReviewLogic(intUserId,intAlbumId,objFormData)
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM_REVIEW"
	GBL_objPubDB.SQLType = "INSERT"
	GBL_objPubDB.AddField "ALBUM_REVIEW_PHOTO_ID",intAlbumId
	GBL_objPubDB.AddField "ALBUM_REVIEW_CONTENT",objFormData.Item("Content")
	GBL_objPubDB.AddField "ALBUM_REVIEW_OWNER_ID",intUserId
	GBL_objPubDB.AddField "ALBUM_REVIEW_ADD_TIME",Now()
	GBL_objPubDB.AddField "ALBUM_REVIEW_LAST_TIME",Now()
	If Not GBL_objPubDB.SQLExecute() Then
		SaveAlbumReviewLogic = False
		Exit Function
	End If

	'== set this photo's review number
	GBL_objPubDB.Clear()
	GBL_objPubDB.TableName = "CLASS_ALBUM"
	GBL_objPubDB.SQLType = "UPDATE"
	GBL_objPubDB.Where = "ALBUM_ID=" & intAlbumId
	GBL_objPubDB.AddSet "ALBUM_REVIEW_NUM=ALBUM_REVIEW_NUM+1"
	If Not GBL_objPubDB.SQLExecute() Then
		SaveAlbumReviewLogic = False
		Exit Function
	End If
	
	SaveAlbumReviewLogic = True
End Function

''===================================================================
'= Function    : GetMyReviewLogic()
'= Time		   : Created At 2006-6-24
'= Input	   : intUserId 
'= Return      : 
'= Description : 取得用戶評論的相冊
'==================================================================='
Function GetMyReviewLogic(intUserId)
	Dim strSql
	strSql = "SELECT ALBUM_ID,ALBUM_TITLE,ALBUM_TYPE,ALBUM_HITS,ALBUM_OWNER_ID,USER_REALNAME,ALBUM_IMG_FILE,ALBUM_ADD_TIME,ALBUM_REVIEW_NUM,ALBUM_STATUS FROM CLASS_ALBUM,CLASS_USER WHERE USER_ID=ALBUM_OWNER_ID AND ALBUM_ID IN (SELECT ALBUM_ID FROM CLASS_ALBUM,CLASS_ALBUM_REVIEW WHERE  ALBUM_REVIEW_OWNER_ID=" & intUserId & " AND ALBUM_REVIEW_PHOTO_ID=ALBUM_ID  ) ORDER BY ALBUM_ID DESC"

	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSql = strSql
	If Not GBL_objPubDB.SQLRSExecute() Then
		GetMyReviewLogic = False
		Exit Function
	End If
	
	GetMyReviewLogic = True

End Function



%>