VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsCustService"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Dim m_tagErrInfo                As TYPE_ERRORINFO       ' 錯誤信息

Public Event ServerStop(ByVal iMode As Integer)
Public Event PrintInfo(ByVal iMode As Integer)

Public Property Get ConnectInfo() As Boolean
Attribute ConnectInfo.VB_Description = "判斷是否連接數據庫"
    ConnectInfo = bolDBStatus
End Property

Public Function AddQueue(ByVal sService As String, ByRef sCustCode As String) As Boolean
    On Error GoTo ERROR_EXIT
    Dim sCode As String, iCode As Long
    Dim rs As New ADODB.Recordset, cmd As New ADODB.Command
    Dim strSQL As String, iTrans As Integer
    Dim iServerID As Integer
    
    ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
    '判斷系統是否能啟動 - 啟動服務和時間檢查
    If Check_Set = False Then
        AddQueue = False
        RaiseEvent ServerStop(1)                        '1 - 沒有排隊啟動服務
        Exit Function
    End If
    
    iCode = 0
    If Check_Service_Code(sService, iServerID) = False Then
        AddQueue = False
        RaiseEvent ServerStop(2)                        '2 - 排隊隊列沒有登記
        Exit Function
    End If
    
    '連接數據庫
    cmd.ActiveConnection = dbMyDB
    cmd.CommandType = adCmdText
    
    strSQL = "SELECT TOP 1 * FROM CustomerQueue WHERE cq_start_data = '" & Date & "' ORDER BY cq_id DESC"
    cmd.CommandText = strSQL
    rs.CursorLocation = adUseClient
    rs.Open cmd, , adOpenStatic, adLockReadOnly
    If rs.EOF Or rs.RecordCount < 1 Then
        iCode = 0
    Else
        sCode = rs!cq_code
        If Not IsNumeric(sCode) Then
            AddQueue = False
            RaiseEvent ServerStop(3)                    '3 - 排隊顧客編號不正確
            Exit Function
        End If
        iCode = CLng(sCode)
    End If
    rs.Close
    
    iCode = iCode + 1
    '生成客戶編碼
    sCode = Format(iCode, "0000")
    
    iTrans = dbMyDB.BeginTrans
    
    dbMyDB.Execute "INSERT INTO CustomerQueue([cq_code], [cq_start_data]," _
                & "[cu_start_time],[cu_name]," _
                & "[cu_end_time],[service_time]," _
                & "[service_queue],[service_process], " _
                & "[service_state],[other_queue]) " _
                & "VALUES( '" _
                & sCode & "', '" & Date & "', '" _
                & Date & " " & Time & "', Null, " _
                & "Null, Null, '" _
                & iServerID & "', '" & 0 & "', " _
                & "Null, Null)"
                
    If iTrans > 0 Then
        dbMyDB.CommitTrans
        iTrans = 0
    End If
    
    '打印排隊數據
    If Print_Queue_Info(sCode) = False Then
        AddQueue = False
        RaiseEvent ServerStop(4)                        '4 - 打印票簽錯誤
        Exit Function
    End If
    
    If rs.State = adStateOpen Then rs.Close
    Set rs = Nothing
    Set cmd = Nothing
    
    sCustCode = sCode
    AddQueue = True
    RaiseEvent ServerStop(0)                            '0 - 排隊數據正確完成
    Exit Function
ERROR_EXIT:
    If iTrans > 0 Then dbMyDB.RollbackTrans
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "clsCustService"
    m_tagErrInfo.strErrFunc = "AddQueue"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
    
    sCustCode = ""
    AddQueue = False
    RaiseEvent ServerStop(9)                            '9 - 數據庫更新錯誤
End Function

'檢查服務類型是否存在
Private Function Check_Service_Code(ByVal sService As String, ByRef iService As Integer) As Boolean
    On Error GoTo ERROR_EXIT
    Dim rs As New ADODB.Recordset, cmd As New ADODB.Command
    Dim strSQL As String
    
    If Not IsNumeric(sService) Then GoTo ERROR_EXIT
    iService = CInt(sService)
    
    '連接數據庫
    cmd.ActiveConnection = dbMyDB
    cmd.CommandType = adCmdText
    
    strSQL = "SELECT * FROM Style WHERE st_code = '" & sService & "' AND st_type = 1"
    cmd.CommandText = strSQL
    rs.CursorLocation = adUseClient
    rs.Open cmd, , adOpenStatic, adLockReadOnly
    If rs.EOF Or rs.RecordCount > 1 Then
        GoTo ERROR_EXIT
    Else
        iService = rs!st_id
    End If
        
    If rs.State = adStateOpen Then rs.Close
    Set rs = Nothing
    Set cmd = Nothing
        
    Check_Service_Code = True
    Exit Function
ERROR_EXIT:
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "clsCustService"
    m_tagErrInfo.strErrFunc = "Check_Service_Code"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
    
    iService = -1
    Check_Service_Code = False
End Function

'啟動服務和時間檢查
Private Function Check_Set() As Boolean
    On Error GoTo ERROR_EXIT
    Dim rs As New ADODB.Recordset, cmd As New ADODB.Command
    Dim strSQL As String, bServer As Boolean
    Dim iResult As Integer, sTime As String
    
    '連接數據庫
    cmd.ActiveConnection = dbMyDB
    cmd.CommandType = adCmdText
    
    iResult = 0
    bServer = False
    
    '判斷是否服務
    strSQL = "SELECT TOP 1 * FROM QueueSystemServer WHERE qs_code = 'QueueServer' ORDER BY qs_id DESC"
    cmd.CommandText = strSQL
    rs.CursorLocation = adUseClient
    rs.Open cmd, , adOpenStatic, adLockReadOnly
    If Not rs.EOF Or rs.RecordCount > 0 Then
        iResult = rs!qs_type
        sTime = rs!qs_time
    End If
    
    If rs.State = adStateOpen Then rs.Close
    Set rs = Nothing
    Set cmd = Nothing
    
    sTime = DateValue(sTime)
    If sTime <> Date Then
        bServer = False
    Else
        If iResult = 1 Then
            bServer = True
        Else
            bServer = False
        End If
    End If
    
    '沒有啟動服務
    If bServer = False Then
        If my_service_stop_print.stop_service_set = True Then
            '打印停止服務信息
            Print_Stop_Info my_service_stop_print.print_date
        End If
        Check_Set = False
        Exit Function
    End If
    
    '檢查是否到啟動服務的時間
    If my_time_set.time_use = True Then
        If Time < TimeValue(my_time_set.time_start) Or Time > TimeValue(my_time_set.time_end) Then
            '不在服務時間內
            Check_Set = False
            Exit Function
        End If
    End If
    
    Check_Set = True
    Exit Function
ERROR_EXIT:
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "clsCustService"
    m_tagErrInfo.strErrFunc = "Check_Service_Code"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
    Check_Set = False
End Function

'打印客戶排隊票簽
Private Function Print_Queue_Info(ByVal sCode As String) As Boolean
    On Error GoTo ERROR_EXIT
    Dim dlgReport As rptPrintQueue                      ' 報表控件窗體
    Dim sCustomerCode As String, sDate As String
    
    sCustomerCode = sCode
    sDate = Date
        
    Set dlgReport = New rptPrintQueue
    If Not dlgReport.ShowReport(sCustomerCode, sDate) Then GoTo ERROR_EXIT
    dlgReport.PrintReport False
    
    Unload dlgReport
    Set dlgReport = Nothing
    
    Print_Queue_Info = True
    RaiseEvent PrintInfo(0)                             '0 - 打印正常完成
    Exit Function
ERROR_EXIT:
    Unload dlgReport
    Set dlgReport = Nothing
    
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "clsCustService"
    m_tagErrInfo.strErrFunc = "Print_Queue_Info"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
    
    Print_Queue_Info = False
    RaiseEvent PrintInfo(9)                             '9 - 其他打印錯誤,數據庫類
End Function

'打印停止服務信息
Private Sub Print_Stop_Info(ByVal sInfo As String)
    On Error GoTo ERROR_EXIT
    Dim dlgReport As rptPrintStop                       '報表控件窗體
    Dim sPrintInfo As String, sDate As String
    
    sPrintInfo = sInfo
    sDate = Date
     
    Set dlgReport = New rptPrintStop
    If Not dlgReport.ShowReport(sPrintInfo, sDate) Then GoTo ERROR_EXIT
    dlgReport.PrintReport False
    
    Unload dlgReport
    Set dlgReport = Nothing
    
    RaiseEvent PrintInfo(0)                             '0 - 打印正常完成
    Exit Sub
ERROR_EXIT:
    Unload dlgReport
    Set dlgReport = Nothing
    
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "clsCustService"
    m_tagErrInfo.strErrFunc = "Print_Stop_Info"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
    
    RaiseEvent PrintInfo(9)                             '9 - 其他打印錯誤,數據庫類
End Sub