VERSION 5.00
Begin VB.Form dlgDepartSet 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "營業廳部門設置"
   ClientHeight    =   2295
   ClientLeft      =   45
   ClientTop       =   330
   ClientWidth     =   4560
   Icon            =   "dlgDepartSet.frx":0000
   LinkTopic       =   "Form1"
   LockControls    =   -1  'True
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   2295
   ScaleWidth      =   4560
   ShowInTaskbar   =   0   'False
   StartUpPosition =   1  '所有者中心
   Begin VB.CommandButton cmdCancel 
      Cancel          =   -1  'True
      Caption         =   "取消(&C)"
      Height          =   375
      Left            =   3360
      TabIndex        =   4
      Top             =   1800
      Width           =   975
   End
   Begin VB.TextBox txtMode 
      Height          =   615
      Left            =   1320
      MultiLine       =   -1  'True
      TabIndex        =   2
      Top             =   1080
      Width           =   3015
   End
   Begin VB.TextBox txtCode 
      Enabled         =   0   'False
      Height          =   270
      Left            =   1320
      TabIndex        =   0
      Top             =   120
      Width           =   3015
   End
   Begin VB.TextBox txtName 
      Height          =   270
      Left            =   1320
      TabIndex        =   1
      Top             =   600
      Width           =   3015
   End
   Begin VB.CommandButton cmdOK 
      Caption         =   "確定(&O)"
      Height          =   375
      Left            =   2400
      TabIndex        =   3
      Top             =   1800
      Width           =   975
   End
   Begin VB.Label lblInfo 
      Caption         =   "部門編號："
      Height          =   195
      Index           =   0
      Left            =   240
      TabIndex        =   7
      Top             =   165
      Width           =   975
   End
   Begin VB.Label lblInfo 
      Caption         =   "部門名稱："
      Height          =   195
      Index           =   1
      Left            =   240
      TabIndex        =   6
      Top             =   645
      Width           =   975
   End
   Begin VB.Label lblInfo 
      Caption         =   "工作描述："
      Height          =   195
      Index           =   3
      Left            =   240
      TabIndex        =   5
      Top             =   1080
      Width           =   975
   End
End
Attribute VB_Name = "dlgDepartSet"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Dim m_tagErrInfo    As TYPE_ERRORINFO

Dim m_iCode         As Integer
Dim m_sCode         As String
Dim m_bChange       As Boolean

Private Sub cmdCancel_Click()
    On Error Resume Next
    Unload Me
End Sub

Private Sub cmdOK_Click()
    On Error GoTo ERROR_EXIT
    Dim iTrans As Integer, i As Integer
    
    If Not IsNumeric(txtCode.Text) Then
        MsgBox "請輸入正確的部門編號！", vbOKOnly, "系統提示"
        Exit Sub
    End If
    If Trim$(txtName.Text) = "" Then
        MsgBox "請輸入正確的部門名稱！", vbOKOnly, "系統提示"
        Exit Sub
    End If
    
    '修改數據庫
    iTrans = dbMyDB.BeginTrans
    
    If m_bChange = False Then
        dbMyDB.Execute "INSERT INTO Department([dp_name],[dp_code],[dp_type],[father_id],[shap_index],[date_end],[note],[nouse_yesno])" _
                & "VALUES( '" & txtName.Text & "', '" & txtCode.Text & "', '0', '0', '0', NULL, '" & txtMode.Text & "', '0')"
    Else
        dbMyDB.Execute "UPDATE Department SET dp_name = '" & txtName.Text & "', note = '" & txtMode.Text & "', " & _
                "dp_code = '" & txtCode.Text & "' WHERE dp_id = '" & m_iCode & "'"
    End If
    
    If iTrans > 0 Then
        dbMyDB.CommitTrans
        iTrans = 0
    End If
    
    Unload Me
    
    Exit Sub
ERROR_EXIT:
    If iTrans > 0 Then dbMyDB.RollbackTrans
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "dlgDepartSet"
    m_tagErrInfo.strErrFunc = "cmdOK_Click"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
End Sub

Private Sub Form_Load()
    On Error GoTo ERROR_EXIT
    Dim rs As New ADODB.Recordset, cmd As New ADODB.Command
    Dim strSQL As String, i As Integer
    
    m_bChange = False
    
    '連接數據庫
    cmd.ActiveConnection = dbMyDB
    cmd.CommandType = adCmdText
    
    '查詢數據庫
    strSQL = "SELECT TOP 1 * FROM Department ORDER BY dp_id DESC"
    cmd.CommandText = strSQL
    rs.CursorLocation = adUseClient
    rs.Open cmd, , adOpenStatic, adLockReadOnly
    If Not rs.EOF And rs.RecordCount > 0 Then
        rs.MoveFirst
        If Not IsNumeric(rs!dp_code) Then GoTo ERROR_EXIT
        i = CInt(rs!dp_code) + 1
        m_sCode = CStr(i)
    Else
        m_sCode = "1"
    End If
    rs.Close
    
    If rs.State = adStateOpen Then rs.Close
    Set rs = Nothing
    Set cmd = Nothing
    
    Exit Sub
ERROR_EXIT:
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "dlgDepartSet"
    m_tagErrInfo.strErrFunc = "Form_Load"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
End Sub

Private Sub Form_Terminate()
    On Error Resume Next
    Set dlgDepartSet = Nothing
End Sub

Private Sub txtCode_GotFocus()
    On Error Resume Next
    txtCode.BackColor = &H80000018
End Sub

Private Sub txtCode_KeyPress(KeyAscii As Integer)
    On Error Resume Next
    If KeyAscii = 13 Then  '是回車鍵？
    KeyAscii = 0 '0取消輸入
    SendKeys "{tab}"
    End If
End Sub

Private Sub txtCode_LostFocus()
    On Error Resume Next
    txtCode.BackColor = &H80000005
End Sub

Private Sub txtMode_GotFocus()
    On Error Resume Next
    txtMode.BackColor = &H80000018
End Sub

Private Sub txtMode_KeyPress(KeyAscii As Integer)
    On Error Resume Next
    If KeyAscii = 13 Then  '是回車鍵？
    KeyAscii = 0 '0取消輸入
    SendKeys "{tab}"
    End If
End Sub

Private Sub txtMode_LostFocus()
    On Error Resume Next
    txtMode.BackColor = &H80000005
End Sub

Private Sub txtName_GotFocus()
    On Error Resume Next
    txtName.BackColor = &H80000018
End Sub

Private Sub txtName_KeyPress(KeyAscii As Integer)
    On Error Resume Next
    If KeyAscii = 13 Then  '是回車鍵？
    KeyAscii = 0 '0取消輸入
    SendKeys "{tab}"
    End If
End Sub

Private Sub txtName_LostFocus()
    On Error Resume Next
    txtName.BackColor = &H80000005
End Sub

'//////////////////////////////////////////////////////////////////////////////////////////
'/設定服務編號
Public Property Let DepartCode(ByVal vNewValue As Integer)
    On Error Resume Next
    m_iCode = vNewValue
    m_bChange = True
End Property

'初始化對話框
Public Function InitSet() As Boolean
    On Error GoTo ERROR_EXIT
    Dim rs As New ADODB.Recordset, cmd As New ADODB.Command
    Dim strSQL As String
    
    '連接數據庫
    cmd.ActiveConnection = dbMyDB
    cmd.CommandType = adCmdText
        
    If m_bChange = False Then
        txtCode.Text = m_sCode
    Else
        '查詢數據庫
        strSQL = "SELECT * FROM Department WHERE dp_id = '" & m_iCode & "'"
        cmd.CommandText = strSQL
        rs.CursorLocation = adUseClient
        rs.Open cmd, , adOpenStatic, adLockReadOnly
        If Not rs.EOF And rs.RecordCount > 0 Then
            If Not IsNull(rs!dp_code) Then
                m_sCode = rs!dp_code
                txtCode.Text = m_sCode
            End If
            If Not IsNull(rs!dp_name) Then txtName.Text = rs!dp_name
            If Not IsNull(rs!note) Then txtMode.Text = rs!note
        Else
            GoTo ERROR_EXIT
        End If
        rs.Close
    End If
    
    If rs.State = adStateOpen Then rs.Close
    Set rs = Nothing
    Set cmd = Nothing
    
    InitSet = True
    Exit Function
ERROR_EXIT:
    m_tagErrInfo.strErrDate = Format(Now, "yyyy-mm-dd hh:mm:ss")
    m_tagErrInfo.strErrFile = "dlgDepartSet"
    m_tagErrInfo.strErrFunc = "InitSet"
    m_tagErrInfo.nErrNum = Err.Number
    m_tagErrInfo.strErrDesc = Error(Err.Number)
    If Err.Number <> 0 Then Err.Clear
    modErrorInfo.WriteErrLog m_tagErrInfo
End Function