;********************************************************************************    
;*  標題:  偉納電子ME300B單片機開發系統演示程序 - 矩陣鍵盤數碼管顯示鍵值        *    
;*  文件:  WL031.asm                                                            *    
;*  日期:  2005-3-20                                                            *    
;*  版本:  1.0                                                                  *    
;*  作者:  gguoqing                                                             *    
;*  郵箱:  gguoqing@willar.com                                                  *    
;*  網站： http://www.willar.com                                                *    
;********************************************************************************    
;*  描述:                                                                       *    
;*         矩陣鍵盤數碼管顯示鍵值                                               *    
;*                                                                              *    
;*         矩陣鍵盤定義：                                                       *
;*         P1.0-P1.3為列線,P1.4-P1.7為行線                                      *    
;*                                                                              *    
;*                                                                              *    
;********************************************************************************    
;* 【版權】 Copyright(C)偉納電子 www.willar.com  All Rights Reserved            *    
;* 【聲明】 此程序僅用于學習與參考，引用請注明版權和作者信息！                  *    
;********************************************************************************    


           RELAY  EQU  P1.3
           BEEP   EQU  P3.7
;------------------------------------------------------
           ORG  0000H
           JMP  MAIN
;------------------------------------------------------
MAIN:      MOV  SP,#60H
           MOV  30H,#00H          
LOOP1:
           CALL  KEY_IN
           CALL  KEY_PLAER
           JMP  LOOP1
;-----------------------------------------------------
KEY_IN:    MOV  P1,#0F0H          ;置列線為0，行線為1
           MOV  A,P1
           ANL  A,#0F0H
           MOV  B,A
           MOV  P1,#0FH           ;置列線為1，行線為0
           MOV  A,P1
           ANL  A,#0FH
           ORL  A,B               ;高四位與低四位重新組合
           CJNE  A,#0FFH,KEY_IN1  ;0FFH為末按鍵
           RET
KEY_IN1:   MOV  B,A
           MOV  DPTR,#KEYTABLE
           MOV  R3,#0FFH           ;
KEY_IN2:   INC  R3
           MOV  A,R3
           MOVC  A,@A+DPTR
           CJNE  A,B,KEY_IN3
           MOV  A,R3             ;找到，取順序碼            
           MOV  30H,A
           CALL  BEEP_BL
           RET
KEY_IN3:   CJNE  A,#0FFH,KEY_IN2  ;末完，繼續查
           RET                    ;0FFH為結束碼
;----------------------------------------------
;蜂鳴器響一聲子程序
;----------------------------------------------
BEEP_BL:
           MOV  R6,#100
  BL1:     CALL  DEX1
           CPL  BEEP
           DJNZ  R6,BL1
           MOV  R5,#25
           CALL  DELAY
           RET
 DEX1:     MOV  R7,#180
 DEX2:     NOP
           DJNZ  R7,DEX2
           RET
DELAY:                    ;延時R5×10MS
           MOV  R6,#50
DELAY1:    MOV  R7,#100
           DJNZ  R7,$
           DJNZ  R6,DELAY1
           DJNZ  R5,DELAY
           RET
;-----------------------------------------------------
KEYTABLE:
    DB  0EEH,0EDH,0EBH,0E7H,0DEH  ;0,1,2,3,4,  順序碼
    DB  0DDH,0DBH,0D7H,0BEH,0BDH  ;5,6,7,8,9,
    DB  0BBH,0B7H,07EH,07DH,07BH  ;A,B,C,D,E,
    DB  077H,0FFH                 ;F      0FF為結束碼
;-----------------------------------------------------
;鍵值顯示子程序
;使用一個數碼管顯示
;-----------------------------------------------------
KEY_PLAER:
            
             MOV  A,30H
             MOV  DPTR,#TAB      ;取段碼表地址
             MOVC  A,@A+DPTR     ;查顯示數據對應段碼
             MOV  P0,A           ;段碼放入P0口
             CLR  P2.7           ;第一個數碼管亮
             RET               
;-----------------------------------------------------
TAB:
 DB  0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H
 DB  80H,90H,88h,83h,0c6h,0a1h,86h,8eh
;-----------------------------------------------------

    END