;***************************************************************
;*-----------------------遙控開關程序--------------------------*
;*-------------------------------------------------------------*
;*-----------------------MCS-51匯編語言----------------------- *
;*-------------------------------------------------------------*
;*-----------------------CPU: AT89C51--------------------------*
;*-------------------------------------------------------------*
;*-----------------------程序名:ykkg.asm-----------------------*
;*-------------------------------------------------------------*
;*-----------------------設計人:雷道仲 羅政球------------------*
;***************************************************************
                               ORG 0000H
     ljmp kkp                             ;搖控器采用常見的M50462AP遙控器
     ORG 0003H
     LJMP LOOP
 kkp:                 
     MOV P2,#0ffH                      ;主程序開放中斷
     SETB EA
     SETB EX0                           ;開放外部中斷0
     SETB IT0                           ;外部中斷0下降沿觸發有效
     MOV 50H,#00H
     mov 51h,#00h
     mov r1,#0ah
  rp:Cpl P3.5                           ;讓蜂鳴器響一會兒指示已經接通電源
     lcall d3s
     djnz r1,rp
     clr p3.5
LP2: MOV A,50H                            ;定時初始化
     CJNE A,#00H,LP                        
     SJMP LP2
 LP: LCALL D60S                           ;調用1 分鐘程序
     DJNZ 50H,LP                           ;判斷定時到了沒有
     MOV A,51H
     cjne A,#00H,RP2
     SJMP LP2
 RP2:MOV R1,#08H
 RP1:CLR P3.3                              ;定時結束
     CLR P3.5                              ;發光二極管閃爍8次
     LCALL D3S
     SETB P3.3                             ;蜂鳴器響8次
     SETB P3.5
     LCALL D3S
     LCALL D3S
     DJNZ R1,RP1
     MOV P2,#0FFH                          ;關閉電風扇電源
     MOV 50H,#00H                           ;定時清零
     MOV P1,#0FFH                          ; 關閉檔位顯示,數碼管不顯示
     MOV P0,#0FFH                          ;關閉定時指示燈
     clr P3.5
     SJMP LP2


LOOP:CLR EX0                             ;中斷子程序,關閉外部中斷
     MOV R0,#30H                          ;
     MOV R3,#00H                           ;8位計數清零
     LCALL IRIN                           ;調用紅外判斷程序
     SETB EX0                              ;開放中斷
     RETI                                  ;中斷返回
IRIN:JNB P3.2,ILL2                         ;等待紅外信號出現
     RET
ILL2:JB P3.2,IRIN
     LCALL DEL                             ;延遲一次
     JB P3.2,IRIN
ILL:JB P3.2,I5                              ;確認紅外信號出現
    SJMP ILL
 I5:MOV R2,#00H                           ;脈沖寬度計數
 L1:LCALL DEL                              ;0.1ms計數
    JNB P3.2,L3                            ;等待紅外信號變為高電平
    INC R2
    CJNE R2,#1DH,L1
    RET
 L3:MOV A,#13                                ;判斷0和1裝入數據
    CLR C
    SUBB A,R2                                ;判斷高低位
    MOV A,@R0
    RRC A
    MOV @R0,A
    INC R3
    CJNE R3,#8,ILL                           ;8位用戶碼接收完了嗎
    MOV R3,#00H
    INC R0

 ILL1:JB P3.2,I51                              ;接收8位功能碼
    SJMP ILL1
 I51:MOV R2,#00H
 L11:LCALL DEL                                  ;調用0.1MS延時程序
    JNB P3.2,L31
    INC R2                                       
    CJNE R2,#1DH,L11
 kp:RET

 L31:MOV A,#13                              ;判斷0和1裝入數據
    CLR C
    SUBB A,R2
    MOV A,@R0
    RRC A
    MOV @R0,A
    INC R3
    CJNE R3,#8,ILL1                          ;8位功能碼接收完了嗎
    ;*************************

 
    MOV A,30H                        ;判斷用戶碼=47H嗎
    CJNE A,#47H,KP
      CLR P3.3                       ;蜂鳴器響一下
      LCALL D3S
      SETB P3.3
      MOV A,31H                       ;將31H的功能碼送入A
      CJNE A,#00H,KP1                 ;判斷功能碼進入相應的子程序
      MOV P2,#0FEH                   ;1檔(最慢)
      MOV P1,#0F9H                    ;數碼管顯示1
      SETB P3.5
      LCALL D3S
      RET
  KP1:CJNE A,#08H,KP2                 ;2檔
      MOV P2,#0FDH
      MOV P1,#0a4h                    ;數碼管顯示2
      SETB P3.5
      LCALL D3S
      RET
    KP2:CJNE A,#10H,KP3               ;3檔
       MOV P2,#0FBH
       MOV P1,#0b0h                   ;數碼管顯示3
       SETB P3.5
       LCALL D3S
       RET

  KP3:CJNE A,#18H,KP4                 ;4檔
      MOV P2,#0F7H
      MOV P1,#99h                        ;數碼管顯示4
      SETB P3.5
      LCALL D3S
     RET

  KP4:CJNE A,#20H,KP5                 ;5檔(最快)
       MOV P2,#0EFH
      MOV P1,#92h                      ;數碼管顯示5
      SETB P3.5
      LCALL D3S
      RET

  KP5:CJNE A,#22H,KP6                     ;定時判斷
      MOV A,51H
      CJNE A,#01H,OP6
      MOV P0,#0FDH                        ;音量增大鍵第二次按下定時30分鐘
      mov 50h,#30
      MOV 51H,#02H
      lcall D3S
      RET
  OP6:jc OP7
      CJNE A,#02H,OP8                      ;音量增大鍵第三次按下定時45分鐘
      MOV P0,#0FBH
      MOV 50H,#45
      MOV 51H,#03H
      LCALL D3S
      RET
 OP7:MOV P0,#0FEH                          ;音量增大鍵第一次按下定時15分鐘
     MOV 50H,#15
     MOV 51H,#01H
     LCALL D3S
     RET
 OP8:CJNE A,#03H,OP9                       ;音量增大鍵第四次按下定時60分鐘
     MOV P0,#0FAH
     MOV 50H,#60
     MOV 51H,#04H
     LCALL D3S
     RET
 OP9:CJNE A,#04H,OP10                     ;音量增大鍵第五次按下定時90分鐘
     MOV P0,#0F8H
     MOV 50H,#90
     MOV 51H,#05H
     LCALL D3S
     RET
 OP10:MOV P0,#0FFH                        ;音量增大鍵第六次按下取消定時
      MOV 50H,#01H
      mov 51H,#00H
      lcall d3s
      ret

 kp6:CJNE A,#02H,KP8                       ;紅色關機鍵按下時關機
     MOV P1,#0FFH
     MOV P2,#0FFH
     CLR P3.5
     MOV P0,#0FFH
     MOV 50H,#01H
     mov 51h,#00h
     LCALL D3S
     RET
 KP8:RET
 DEL:MOV R5,#01H                        ;時間1ms
 DELAY1:MOV R6,#02H
 E1:MOV R7,#11H
 E2:DJNZ R7,E2
    DJNZ R6,E1
    DJNZ R5,DELAY1
    RET

  D3S:MOV R4,#01H                      ;時間260MS
  TP14: MOV R6,#0FFH
  TP12: MOV R5,#0FFH
  TP11: NOP
      NOP
      DJNZ R5,TP11
      DJNZ R6,TP12
      DJNZ R4,TP14
      RET

D60S:MOV R4,#0C0H                      ;1分鐘
 QP3:MOV R6,#0ECH
 QP2:MOV R5,#0FDH
 QP1: NOP
      NOP
      NOP
      DJNZ R5,QP1
      DJNZ R6,QP2
      DJNZ R4,QP3
      RET