{
=====================================================================
* 軟件名稱：PC與數控機床通信程序
* 單元名稱：發送數據到數控機床
* 單元作者：彭為 (pwzyp@fjsm.net)
* 備    注：用到了線程進行發送
* 開發平臺：PWin2000 SERVER + Delphi 7.0
* 兼容測試：PWin9X/2000/XP + Delphi 6/7
* 采用控件：Raize 3.12 ,SPCOMM
* 修改記錄：V1.0  by pengwei
=====================================================================
}
unit ExportFrm; //本單元用來發送數據

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, jpeg, ExtCtrls, RzTabs, RzButton, StdCtrls, RzLabel, RzBorder,
  Grids, ValEdit, RzPrgres, ScktComp, SPComm, DB, ADODB;
type
  TExportData = class(TForm)
    Panel1: TPanel;
    pgcMain: TRzPageControl;
    TabSheet1: TRzTabSheet;
    TabSheet2: TRzTabSheet;
    Image1: TImage;
    Panel2: TPanel;
    btnFinish: TRzBitBtn;
    btnNext: TRzBitBtn;
    btnPrior: TRzBitBtn;
    RzLabel1: TRzLabel;
    RzLabel2: TRzLabel;
    RzLabel3: TRzLabel;
    Image2: TImage;
    RzBorder1: TRzBorder;
    RzLabel4: TRzLabel;
    RzLabel5: TRzLabel;
    RzLabel6: TRzLabel;
    edtUser: TEdit;
    edtMemo: TEdit;
    TabSheet3: TRzTabSheet;
    Image4: TImage;
    RzLabel12: TRzLabel;
    RzBorder3: TRzBorder;
    Lbl1: TRzLabel;
    Lbl2: TRzLabel;
    Lbl3: TRzLabel;
    pgb1: TRzProgressBar;
    Lbl4: TRzLabel;
    LblErr: TRzLabel;
    Lbl5: TRzLabel;
    RzLabel7: TRzLabel;
    RzLabel8: TRzLabel;
    cboChannel: TComboBox;
    RzBorder4: TRzBorder;
    RzLabel9: TRzLabel;
    cboComm: TComboBox;
    Comm1: TComm;
    Query: TADOQuery;
    LblCommErr: TRzLabel;
    procedure FormCreate(Sender: TObject); //界面初始化代碼
    procedure btnNextClick(Sender: TObject); //“下一步”按鈕點擊事件
    procedure btnPriorClick(Sender: TObject); //“上一步”按鈕點擊事件
    procedure btnFinishClick(Sender: TObject); //“完成”按鈕點擊事件
    procedure cboChannelEnter(Sender: TObject); //用戶改變“設備”的事件
    procedure FormDestroy(Sender: TObject); //銷毀對象時執行
    procedure Comm1ReceiveError(Sender: TObject; EventMask: Cardinal); //SPCOMM接收數據錯誤事件
    procedure Comm1ReceiveData(Sender: TObject; Buffer: Pointer;
      BufferLength: Word); //SPCOMM接收數據事件（很關鍵）
    procedure FormShow(Sender: TObject);
  private
    Fid: Integer; //局部變量存放ID
    Channel: Integer; //
    SendText: Tstrings; //發送的內容(數據機床命令，存在TSTRINGS對象中）
    { Private declarations }
  public
    bStart: Boolean; //是否已開始發送標志（用于線程與主界面同步）
    TickCount: Longword; //機床號
    procedure showForm(const id: integer);
    constructor Create(const id: Integer); reintroduce; overload;
    { Public declarations }
  end;
  //發送數據的線程，系統啟動發送后，其它的回復等由該線程進行

  TSendThread = class(TThread)
  private
    Pos, Len: LongWord; //當前位置，總長度
    CurrChar: Char; // 當前發送的字符
    FSendText: string; //全部長度
    procedure Ok; //發送完成后執行的過程
    procedure Percent; //顯示百分比過程
  public
    constructor Create(SendText: string); //線程的構造過程
    procedure Execute; override; //線程的執行體
  end;

var
  ExportData: TExportData;
  SendThread: TSendThread;

implementation

uses Include, Mainfrm, ConfigFrm;

{$R *.dfm}

procedure TExportData.FormCreate(Sender: TObject);
begin
  Caption := sExportCaption; //sExportCaption是窗口名'發送數據至數控機床'
  SendText := TStringlist.Create; //構造臨時變量

end;

procedure TExportData.btnNextClick(Sender: TObject);
var
  FileName, sTemp: string;
  BeginChar: Byte; //初始標志位
  BeginChannel: array[1..2] of Byte; //2位字節數組
begin
  case pgcmain.activepageindex of
    0: //如果是第一頁
      begin
        //初始化第二頁的控件
        //清空機床的列表框
        cboChannel.Clear;
        cboChannel.Items := Config.ChannelList;
        //從數據庫中查詢出要發送的文件的內容
        with Query do
        begin
          Close;
          SQL.Clear;
          SQL.Add('Select * from Data where id=' + IntToStr(Fid));
          Open;
          FileName := FieldByName('filename').AsString;
          if FileExists(FileName) then //如果文件存在的話
          begin
            Application.ProcessMessages;
            SendText.LoadFromFile(FileName);
            //如果內容是空的
            if Trim(SendText.Text) = '' then
            begin
              MessageBox(Self.Handle, PChar(sFileEmpty), PChar(sTitleErr), MB_OK
                +
                MB_ICONERROR);
              exit;
            end;
          end
          else
          begin //如果文件不存在
            MessageBox(Self.Handle, PChar(sNotFile), PChar(sTitleErr), MB_OK +
              MB_ICONERROR);
            exit;
          end;
          //初始化必要的信息
          edtUser.Text := FieldByName('Author').AsString;
          edtMemo.Text := FieldByName('sMemo').AsString;
          Channel := FieldByName('Channel').AsInteger;
          cboChannel.ItemIndex := Channel - 1;
          cboComm.ItemIndex := cboComm.Items.IndexOf(Config.CommName);
          Close;
        end;
        LblCommErr.Visible := False;
      end;
    1: //如果是第二頁
      begin
        //初始化發送前的準備工作
        Config.CommName := cboComm.Text; //串口
        Channel := cboChannel.ItemIndex + 1; //機床號

        //啟動SPCOMM控件COMM1
        Comm1.CommName := Config.CommName;
        //先關閉
        Comm1.StopComm;
        try
          //再打開
          Comm1.StartComm;
        except
          //捕獲異常
          LblCommErr.Visible := True;
          Exit;
        end;
        //起始字節為01，具體請參看通訊協議
        BeginChar := 01;
        //把機床號變成2位的ASCII碼
        sTemp := Format('%.2d', [channel]);
        //把它的ASCII值送到臨時數組中去
        BeginChannel[1] := Ord(sTemp[1]);
        BeginChannel[2] := Ord(sTemp[2]);

        //        ShowMessage(Format('%x %x %x', [beginchar[1], beginchar[2],beginchar[3]]));
        Sleep(100); //如果不休眠100毫秒，可能會發生錯誤，因為打開串口需要時間，以下類同
        Comm1.WriteCommData(@BeginChar, 1); //用SPCOMM往端口發送啟始位01H
        Sleep(100);
        Comm1.WriteCommData(@BeginChannel, 2); //用SPCOMM發送機床號（選床）

        //開始發送正式的數據標志置FALSE
        bStart := False;

        //界面代碼，使界面上的字變粗顯示表示當前進度
        Lbl1.Font.Style := [fsBold];
        Lbl2.Font.Style := [fsBold];
        Lbl3.Font.Style := [];
        Lbl4.Font.Style := [];
        Lbl5.Visible := False;
        LblErr.Visible := False;
        pgb1.Percent := 0;
      end;
  else
    ;
  end;
  //轉下一頁
  pgcMain.ActivePageIndex := pgcMain.ActivePageIndex + 1;
  btnPrior.Enabled := True;
  if pgcMain.ActivePageIndex = pgcMain.PageCount - 1 then
    btnNext.Enabled := False;
end;

procedure TExportData.btnPriorClick(Sender: TObject);
begin
  //轉前一頁
  pgcMain.ActivePageIndex := pgcMain.ActivePageIndex - 1;
  btnNext.Enabled := True;
  if pgcMain.ActivePageIndex = 0 then
    btnPrior.Enabled := False;
end;

procedure TExportData.showForm(const id: integer);
begin
  //顯示窗體的函數（實際調用時用本函數即可）
  if ExportData = nil then
    ExportData := TExportData.Create(id);
  ExportData.ShowModal;
end;

procedure TExportData.btnFinishClick(Sender: TObject);
begin
  //點擊了完成 或取消
  if bStart then
  begin
    // 如果正在發送，則關閉線程
    bStart := False;
    SendThread.Terminate;
    //中斷發送數據線程
  end;
  //關閉串口
  Comm1.StopComm;
  Close;
end;

procedure TExportData.cboChannelEnter(Sender: TObject);
begin
  LblCommErr.Visible := False;
end;

procedure TExportData.FormDestroy(Sender: TObject);
begin
  //釋放內存
  SendText.Free;
end;

procedure TExportData.Comm1ReceiveError(Sender: TObject;
  EventMask: Cardinal);
begin
  LblErr.Caption := '串口接收數據出現錯誤';
  LblErr.Visible := True;
end;

procedure TExportData.Comm1ReceiveData(Sender: TObject; Buffer: Pointer;
  BufferLength: Word);
var
  ReceivedBuf: array of Byte;
  stemp: string;
  BeginChar: array[1..2] of Byte;
  SendChar: Byte;
  i: Integer;
begin
  SetLength(ReceivedBuf, BufferLength);
  try
    //把接收到的字符放入BUFFER
    Move(Buffer^, Pchar(@ReceivedBuf[0])^, BufferLength);
  except
    ShowMsg(sErrReceive1);
    exit;
  end;
  if not bStart then
  begin //尚未開始，根據協議，接收到的應該就是具體的機床號與前面的機床號相同
    stemp := Format('%.2d', [Channel]);
    BeginChar[1] := Ord(sTemp[1]);
    BeginChar[2] := Ord(sTemp[2]);

    if ((ReceivedBuf[0] = BeginChar[1]) and (ReceivedBuf[1] = BeginChar[2])) then
    begin //床號正確//開始回發床號，并發數據 置start為True
      //根據協議，02H為發送數據的功能
      SendChar := 02;
      Comm1.WriteCommData(@SendChar, 1);
      bstart := True;
      //發數據
      Lbl3.Font.Style := [fsBold];
      pgb1.Percent := 0;
      //啟動數據發送線程
      SendThread := TSendThread.Create(SendText.Text);
    end
    else
    begin //床號不正確，顯示錯誤并返回
      LblErr.Caption := '設備號選擇出錯！';
      LblErr.Visible := True;
    end;
  end
  else
    //其它情況正在正在發送，檢測是否是07H(錯誤)
    //設置停止標志終止線程的發送
    for i := 0 to BufferLength - 1 do
    begin
      if ReceivedBuf[i] = $07 then
      begin
        bStart := false;
        SendThread.Terminate;

        LblErr.Caption := '數控機床設備返回錯誤信息，終止發送！';
        LblErr.Visible := True;
        Exit;
      end
      else if ReceivedBuf[i] = $17 then //完成了
      begin
        bStart := False;
        pgb1.Percent := 100;
        Lbl4.Font.Style := [fsbold];
        Lbl5.Caption := '花費時間:' + IntToStr(GetTickCount - TickCount) +
          '毫秒';
        btnFinish.Caption := '完成';
        Exit;
      end;
    end;
end;

{ TSendThread }

constructor TSendThread.Create(SendText: string);
begin
  //線程的構造線程
  FSendText := Copy(SendText, 1, Length(SendText) - 2);
  inherited Create(False);
end;

procedure TSendThread.Execute;
var
  isSend: Boolean;
begin
  FreeOnTerminate := True; //控制線程空閑時自動中斷
  ExportData.TickCount := GetTickCount; //時間戳（用來計算發送時間）

  if not TestEOF(FSendText) then //如果沒有結束符加入結束符
    //TESTEOF的函數在INCLUDE單元中定義，請查看所有源代碼
    FSendText := FSendText + Chr(26);

  //開始發送之前記載發送的總長度
  Len := Length(FSendtext);
  //當前位置是第一個字符
  Pos := 1;
  //當發送數據未完而且主窗口的bstart為True則發送（如果主界面要取消，只要置bstart為false即可）
  while (Pos <= Len) and ExportData.bstart do
  begin
    //檢查是否發送該字節
    isSend := True;
    CurrChar := FSendText[pos];
    case CurrChar of
      'a'..'z': CurrChar := UpperCase(CurrChar)[1];
      'A'..'Z', '0'..'9', '+', '-', '/', '.', Chr(26), '%', Chr(00), Chr($0A): ;
    else
      isSend := False;
    end;

    if isSend then
    begin
      //暫停若干秒
      Sleep(Config.Delaytime);
      //發送
      ExportData.Comm1.WriteCommData(@CurrChar, 1);
    end;
    //當前位置增量
    Inc(Pos);
    //線程調用函數輸出進度信息
    Synchronize(Percent);
  end;
  //如果發送完了
  if Pos = Len + 1 then
  begin
    CurrChar := Chr($17);
    Sleep(100);
    //輸出結束標志17H，參看通訊協議
    ExportData.Comm1.WriteCommData(@CurrChar, 1);
    Synchronize(ok);
  end;
  //  Self.Terminate;
  //  PostMessage(Application.Handle, WM_QUIT, 0, 0); ;
end;

procedure TSendThread.Ok;
begin
  ExportData.pgb1.Percent := 100;
  ExportData.Lbl4.Font.Style := [fsbold];
  ExportData.Lbl5.Visible := True;
  ExportData.Lbl5.Caption := '花費時間:' + IntToStr(GetTickCount -
    ExportData.TickCount) +
    '毫秒';
  ExportData.btnFinish.Caption := '完成';
  ExportData.bstart := False;
end;

procedure TSendThread.Percent;
begin
  ExportData.pgb1.Percent := trunc((Pos / Len) * 100);
end;

procedure TExportData.FormShow(Sender: TObject);
begin
  //顯示窗體時初始化
  pgcMain.ActivePageIndex := 0;
  btnPrior.Enabled := False;
  btnNext.Enabled := True;
  btnFinish.Caption := '取消';
  Comm1.StopComm;

  SendText.Clear;
end;

constructor TExportData.Create(const id: Integer);
begin
  inherited Create(Application);
  Fid := id;
end;

end.