<%@ Language=VBScript CODEPAGE=936%>
<% Option Explicit %>
<%
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
'★                                                                  ★
'☆                eWebEditor - eWebSoft在線文本編輯器               ☆
'★                                                                  ★
'☆  版權所有:                                           ☆
'★                                                                  ★
'☆  程序制作: eWeb開發(fā)團隊                                          ☆
'★            email:webmaster@webasp.net                            ★
'☆            QQ:589808                                             ☆
'★                                                                  ★
'☆  相關網(wǎng)址: [產(chǎn)品介紹]http://www./Product/eWebEditor/ ☆
'★            [支持論壇]http://bbs./                    ★
'☆                                                                  ☆
'★  主頁地址: http://www./   eWebSoft團隊及產(chǎn)品         ★
'☆            http://www.webasp.net/     WEB技術及應用資源網(wǎng)站      ☆
'★            http://bbs.webasp.net/     WEB技術交流論壇            ★
'★                                                                  ★
'☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆★☆
%>

<%

' ============================================
' 常用全局變量
' ============================================
' 數(shù)據(jù)庫對象
Dim oConn, oRs, sSql


' ============================================
' 初始數(shù)據(jù)處理
' ============================================
' 執(zhí)行每天只需處理一次的事件
Call BrandNewDay()

' 初始化數(shù)據(jù)庫連接
Call DBConnBegin()


' ********************************************
' 以下為初始函數(shù)
' ********************************************
' ============================================
' 執(zhí)行每天只需處理一次的事件
' ============================================
Sub BrandNewDay()
	Dim sDate, y, m, d, w
	Dim sDateChinese
	sDate = Date()
	If Application("date_today") = sDate Then Exit Sub

	y = CStr(Year(sDate))
	m = CStr(Month(sDate))
	If Len(m) = 1 Then m = "0" & m
	d = CStr(Day(sDate))
	If Len(d) = 1 Then d = "0" & d
	w = WeekdayName(Weekday(sDate))
	sDateChinese = y & "年" & m & "月" & d & "日&nbsp;" & w

	Application.Lock
	Application("date_today") = sDate
	Application("date_chinese") = sDateChinese		'今天的中文樣式
	Application.Unlock
End Sub



' ********************************************
' 以下為數(shù)據(jù)庫相關函數(shù)
' ********************************************
' ============================================
' 初始化數(shù)據(jù)庫連接對象
' 使用原則：最遲調(diào)用，最早釋放
' ============================================
Sub DBConnBegin()
	' 如果數(shù)據(jù)庫對象已打開，不要再打開
	If IsObject(oConn) = True Then Exit Sub

	' 你可以不需要打開數(shù)據(jù)庫連接對象而直接打開記錄集對象，但如果你需要打開多個記錄集對象的話，效率是很低的。
	' 如果你不創(chuàng)建一個數(shù)據(jù)庫連接對象，ADO會在每個記錄集打開時自動創(chuàng)建一個新的數(shù)據(jù)庫連接對象，就算你用的是相同的SQL語句。
	Set oConn = Server.CreateObject("ADODB.Connection")

	On Error Resume Next
	' Access數(shù)據(jù)庫
	oConn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("db/ewebeditor.mdb")
	' SQL Server 2000數(shù)據(jù)庫
	'oConn.Open "Provider=SQLOLEDB.1;Server=localhost;UID=ewebeditor;PWD=123456;Database=ewebeditor"
	
	If Err.Number > 0 Then
		' 顯示錯誤信息,并且發(fā)送郵件通知管理員
		'Call DBConnError(Err)
		
		' 完全地退出正在運行的腳本
		Response.End
	End If

	' 創(chuàng)建一個記錄集
	Set oRs = Server.CreateObject( "ADODB.Recordset" )
End Sub

' ============================================
' 釋放數(shù)據(jù)庫連接對象
' ============================================
Sub DBConnEnd()
	On Error Resume Next
	oRs.Close
	Set oRs = Nothing
	oConn.Close
	Set oConn = Nothing
End Sub



' ********************************************
' 以下為常用函數(shù)
' ********************************************
' ============================================
' 錯誤返回處理
' ============================================
Sub Go_Error(str)
	Call DBConnEnd()
	Response.Write "<script language=javascript>alert('" & str & "\n\n系統(tǒng)將自動返回前一頁面...');history.back();</script>"
	Response.End
End Sub

' ============================================
' 格式化時間(顯示)
' 參數(shù)：n_Flag
'	1:"yyyy-mm-dd hh:mm:ss"
'	2:"yyyy-mm-dd"
'	3:"hh:mm:ss"
'	4:"yyyy年mm月dd日"
' ============================================
Function Format_Time(s_Time, n_Flag)
	Dim y, m, d, h, mi, s
	Format_Time = ""
	If IsDate(s_Time) = False Then Exit Function
	y = cstr(year(s_Time))
	m = cstr(month(s_Time))
	If len(m) = 1 Then m = "0" & m
	d = cstr(day(s_Time))
	If len(d) = 1 Then d = "0" & d
	h = cstr(hour(s_Time))
	If len(h) = 1 Then h = "0" & h
	mi = cstr(minute(s_Time))
	If len(mi) = 1 Then mi = "0" & mi
	s = cstr(second(s_Time))
	If len(s) = 1 Then s = "0" & s
	Select Case n_Flag
	Case 1
		' yyyy-mm-dd hh:mm:ss
		Format_Time = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
	Case 2
		' yyyy-mm-dd
		Format_Time = y & "-" & m & "-" & d
	Case 3
		' hh:mm:ss
		Format_Time = h & ":" & mi & ":" & s
	Case 4
		' yyyy年mm月dd日
		Format_Time = y & "年" & m & "月" & d & "日"
	End Select
End Function

' ============================================
' 把字符串進行HTML解碼,替換server.htmlencode
' 去除Html格式，用于顯示輸出
' ============================================
Function outHTML(str)
	Dim sTemp
	sTemp = str
	outHTML = ""
	If IsNull(sTemp) = True Then
		Exit Function
	End If
	sTemp = Replace(sTemp, "&", "&amp;")
	sTemp = Replace(sTemp, "<", "&lt;")
	sTemp = Replace(sTemp, ">", "&gt;")
	sTemp = Replace(sTemp, Chr(34), "&quot;")
	sTemp = Replace(sTemp, Chr(10), "<br>")
	outHTML = sTemp
End Function

' ============================================
' 去除Html格式，用于從數(shù)據(jù)庫中取出值填入輸入框時
' 注意：value="?"這邊一定要用雙引號
' ============================================
Function inHTML(str)
	Dim sTemp
	sTemp = str
	inHTML = ""
	If IsNull(sTemp) = True Then
		Exit Function
	End If
	sTemp = Replace(sTemp, "&", "&amp;")
	sTemp = Replace(sTemp, "<", "&lt;")
	sTemp = Replace(sTemp, ">", "&gt;")
	sTemp = Replace(sTemp, Chr(34), "&quot;")
	inHTML = sTemp
End Function

' ============================================
' 檢測上頁是否從本站提交
' 返回:True,False
' ============================================
Function IsSelfRefer()
	Dim sHttp_Referer, sServer_Name
	sHttp_Referer = CStr(Request.ServerVariables("HTTP_REFERER"))
	sServer_Name = CStr(Request.ServerVariables("SERVER_NAME"))
	If Mid(sHttp_Referer, 8, Len(sServer_Name)) = sServer_Name Then
		IsSelfRefer = True
	Else
		IsSelfRefer = False
	End If
End Function

' ============================================
' 得到安全字符串,在查詢中使用
' ============================================
Function Get_SafeStr(str)
	Get_SafeStr = Replace(Replace(Replace(Trim(str), "'", ""), Chr(34), ""), ";", "")
End Function

' ============================================
' 取實際字符長度
' ============================================
Function Get_TrueLen(str)
	Dim l, t, c, i
	l = Len(str)
	t = l
	For i = 1 To l
		c = Asc(Mid(str, i, 1))
		If c < 0 Then c = c + 65536
		If c > 255 Then t = t + 1
	Next
	Get_TrueLen = t
End Function

' ============================================
' 判斷是否安全字符串,在注冊登錄等特殊字段中使用
' ============================================
Function IsSafeStr(str)
	Dim s_BadStr, n, i
	s_BadStr = "' 　&<>?%,;:()`~!@#$^*{}[]|+-=" & Chr(34) & Chr(9) & Chr(32)
	n = Len(s_BadStr)
	IsSafeStr = True
	For i = 1 To n
		If Instr(str, Mid(s_BadStr, i, 1)) > 0 Then
			IsSafeStr = False
			Exit Function
		End If
	Next
End Function


%>