st0_temp	.usect		".b20",1			;
st1_temp	.usect		".b20",1			;
context	 	.usect		".b20",7			;62-68 

;INT2的中斷向量為0004H,T1PINT的外設中斷向量為0027H。
			.include  "F2407REGS.H" 	;引用頭部文件
			.def      _c_int0
;建立中斷向量表
			.sect	".vectors"			;定義主向量段
RSVECT	 		B    _c_int0			;PM 0	復位向量  		1
INT1	  		B    PHANTOM		;PM 2	中斷優先級1		4
INT2	  		B    GISR2			;PM 4	中斷優先級2		5
INT3	  		B    PHANTOM		;PM 6	中斷優先級3		6
INT4	  		B    PHANTOM		;PM 8	中斷優先級4		7
INT5	  		B    PHANTOM		;PM A	中斷優先級5		8
INT6	  		B    PHANTOM		;PM C	中斷優先級6		9
RESERVED  	B    PHANTOM		;PM E	 模擬量輸入中斷(保留)	10
SW_INT8   	B    PHANTOM		;PM 10  	用戶定義軟件中斷   	-
  					
SW_INT31  	B    PHANTOM		;PM 3E  	用戶定義軟件中斷     -
;中斷子向量入口定義pvecs
			.sect	".pvecs"			;定義子向量段
PVECTORS	B	PHANTOM		;保留向量地址偏移量  00H 
			B	PHANTOM		;保留向量地址偏移量  01H
  				
			B	PHANTOM		;保留向量地址偏移量  26H
			B	T1PINT_ISR		;保留向量地址偏移量  27H   T1PINT中斷
			B	PHANTOM		;保留向量地址偏移量  28H
  			
			B	PHANTOM		;保留向量地址偏移量  41H	
;主程序
         	.text
_c_int0    
		SETC 	INTM
        CLRC 	SXM
       	CLRC 	OVM
		CLRC 	CNF				;B0區被配置為數據空間
       	LDP 		#0E0H			;指向7000h-7080h區
        SPLK 		#81FEH,SCSR1   	;時鐘4倍頻,CLKIN=6M,CLKOUT=24M
        SPLK		#0E8H,WDCR		;不使能WDT
       	LDP			#0
		SPLK		#02H,IMR		;使能中斷優先級INT2
		SPLK		#0FFFFh,IFR		;清中斷標志
		LDP			#DP_EVA			;指向7400h-7480h區
		SPLK		#80H,EVAIMRA	;使能T1PINT 中斷
		SPLK		#0FFFFh,EVAIFRA	;清EVA中斷標志
		SPLK		#0,GPTCONA
		SPLK		#177H,T1PR		;使定時器每1ms產生一次中斷
		SPLK		#0,T1CNT
		SPLK		#0164CH,T1CON	;TMODE=10 連續增計數模式,TPS=110 預分頻為64
							;TENABLE=1 定時器計數使能,,TCLKS=00 內部時鐘
							;TECMPR=1 定時器1比較使能,,SELT1PR=0 
		CLRC	INTM			;開總中斷
WAIT:	NOP
		B		WAIT
;中斷程序
GISR2:							;優先級INT2中斷人口
		;保護現場
		LDP     #0              ;保存機器上下文
		SST		#0,st0_temp	    ;使用自動尋址,DP-0 
		SST		#1,st1_temp	    ;保存狀態寄存器到B2 DARAM.
		LDP		#0			  
        SACL	context			;保存ACC的低16位
		SACH	context+1		;保存ACC的高16位
		SAR		AR1,context+2
		SAR		AR2,context+3
		SAR		AR3,context+4
		SAR		AR4,context+5		
		SAR		AR5,context+6
		LDP		#0E0H
		LACC	PIVR,1			;讀取外設中斷向量寄存器（PIVR）,并左移一位
		ADD		#PVECTORS		;加上外設中斷人口地址
		BACC					;跳到相應的中斷服務子程序
T1PINT_ISR:						;通用定時器1中斷人口
		LDP		#DP_EVA	
		SPLK		#0,T1CNT
GISR2_RET:						;中斷返回
			;恢復現場
		LDP		#DP_EVA
		SPLK	#0FFFFH,EVAIFRA
		LDP		#0
		LAR		AR5,context+6	
		LAR		AR4,context+5	
		LAR		AR3,context+4		
		LAR		AR2,context+3		
		LAR		AR1,context+2
		LACC	context+1,16
		ADDS	context
		LST		#1, st1_temp
		LST		#0, st0_temp
		CLRC	INTM			;開總中斷,因為一進中斷就自動關閉總中斷
		RET
;假中斷程序
PHANTOM 	
KICK_DOG				;復位看門狗
		RET
		END