<%
'=====================================================================
' 軟件名稱：清風信息自動采集生成系統
' 官方網站：(www.iising.com) 在線QQ：24387481
' 利用服務器端緩存技術可以很好解決這方面的矛盾，大大加速ASP運行和改善效率。 
'===================================================================== 
class SK_clsCache
'----------------------------
private cache           '緩存內容
private cacheName       '緩存Application名稱
private expireTime      '緩存過期時間
private expireTimeName  '緩存過期時間Application名稱
private path            '緩存頁URL路徑
private vaild           'ansir添加
private sub class_initialize()
path=request.servervariables("url")
path=left(path,instrRev(path,"/"))
end sub

private sub class_terminate()
end sub

Public Property Get Version
	Version="緩存類2006"
End Property

public property get valid '讀取緩存是否有效/屬性
	if isempty(cache) or (not isdate(expireTime)) then
	vaild=false
	else
	valid=true
	end if
	end property
	
public property get value '讀取當前緩存內容/屬性
	if isempty(cache) or (not isDate(expireTime)) then
	value=null
	elseif CDate(expireTime)<now then
	value=null
	else
	value=cache
	end if
end property

public property let name(str) '設置緩存名稱/屬性
	cacheName=str&path
	cache=application(cacheName)
	expireTimeName=str&"expire"&path
	expireTime=application(expireTimeName)
end property

public property let expire(tm) '設置緩存過期時間/屬性
	expireTime=tm
	application.Lock()
	application(expireTimeName)=expireTime
	application.UnLock()
end property

public sub add(varCache,varExpireTime) '對緩存賦值/方法
	if isempty(varCache) or not isDate(varExpireTime) then
	exit sub
	end if
	cache=varCache
	expireTime=varExpireTime
	application.lock
	application(cacheName)=cache
	application(expireTimeName)=expireTime
	application.unlock
end sub

public sub clean() '釋放緩存/方法
	application.lock
	application(cacheName)=empty
	application(expireTimeName)=empty
	application.unlock
	cache=empty
	expireTime=empty
end sub
 
public function verify(varcache2) '比較緩存值是否相同/方法——返回是或否
	if typename(cache)<>typename(varcache2) then
		verify=false
	elseif typename(cache)="Object" then
		if cache is varcache2 then
			verify=true
		else
			verify=false
		end if
	elseif typename(cache)="Variant()" then
		if join(cache,"^")=join(varcache2,"^") then
			verify=true
		else
			verify=false
		end if
	else
		if cache=varcache2 then
			verify=true
		else
			verify=false
		end if
	end if
end function
end class
%>