?? lm92saa1064.#1
字號:
;參考程序B : //LM92SAA1064.ASM
;WLM92SAA1064.ASM程序功能:讀/寫LM92并將溫度值顯示在SAA1064驅動的數碼管上.
;要顯示的數據在70H--7BH中.
$include (C8051F020.inc)
CHIP_A EQU 090H ; LM92芯片的寫地址
CHIP_B EQU 070H ; SAA1064芯片的寫地址
;SMBus狀態:
SMB_BUS_ERROR EQU 00H ;（所有方式）總線錯誤
SMB_START EQU 08H ;（MT＆MR）主收發器發送起始位成功.再將從機寫地址送SMB0DAT
SMB_RP_START EQU 10H ;（MT＆MR）主收發器重復發送起始位成功,再將從機讀地址送SMB0DAT
SMB_MTADDACK EQU 18H ;（MT）主收發器發送從地址＋W成功；收到 ACK(從機應答)
; 再將從器件的子地址送入SMB0DAT.
SMB_MTADDNACK EQU 20H ;（MT）主收發器發送從地址＋W成功；收到 NACK(從機無應答)
SMB_MTDBACK EQU 28H ;（MT）主收發器發送數據字節成功；收到ACK(從機應答)
SMB_MTDBNACK EQU 30H ;（MT）主發送器發送數據成功；收到NACK(從機無應答).
SMB_MTARBLOST EQU 38H ;（MT）總線競爭失敗
SMB_MRADDACK EQU 40H ;（MR）主收發器發送從地址＋R成功；收到 ACK(從機應答)
SMB_MRADDNACK EQU 48H ;（MR）主收發器發送從地址＋R成功；收到NACK(從機無應答)
SMB_MRDBACK EQU 50H ;（MR）主收發器接收數據成功；主機發送ACK
SMB_MRDBNACK EQU 58H ;（MR）主收發器接收數據成功；主機發送NACK
DSEG ; 數據段;
ORG 30H
RECEIVE_BYTEH: DS 1 ; 保存SMBus剛收到的16位數據的高字節
RECEIVE_BYTEL: DS 1 ; 保存SMBus剛收到的16位數據的低字節
TRANSMIT_BYTE: DS 1 ; 保存SMBus待發送的字節
SLA_ADD: DS 1 ; 保存從地址
WRI_ADD: DS 1 ; 保存從地址＋ WRITE
READ_ADD: DS 1 ; 保存從地址＋ READ
SUBADR_ADD: DS 1 ; 要訪問的器件地址
; 用于暫存數據的單元
DATA_COUNT: DS 1 ; 計數器單元
DATA_BYTE: DS 1 ; 數據單元
DATA_ADDR: DS 1 ; 地址單元
BSEG
ORG 00H
RW: DBIT 1 ;R／W命令位。l＝READ，0＝WRITE
SM_BUSY: DBIT 1 ;SMBus忙標志（軟件保存）
BYTE_SENT: DBIT 1 ;剛發送的字節為l,表示地址;為0是數據字節
CSEG ;代碼段
ORG 00H ;復位
LJMP MAIN
ORG 03BH ;SMBus中斷向量
LJMP SMBus_ISR
;主程序
MAIN: MOV SP,#7H
MOV R1,#50H
MOV WDTCN,#0DEH ;禁止看門狗定時器
MOV WDTCN,#0ADH;
LCALL PORT_Init ;初始化I/O端口
; 初始化SMBus程序段
MOV SMB0CN,#04H ; 配置 SMBus在確認周期發送 ACK
MOV SMB0CR,#0ECH ; 設置時鐘速率＝100 kHz (系統時鐘為4MHZ)
ORL SMB0CN,#40H ; 允許SMBus
ORL EIE1,#02H ; 允許SMBus中斷
CLR SM_BUSY ; 為第一次傳輸清除SM_Busy標志
SETB EA
; 配置LM92為連續采樣模式,向LM92配置寄存器寫數據0
MOV DATA_BYTE,#0 ;裝入待寫的數據
MOV DATA_ADDR,#00H ; 裝入待寫數據的首地址
MOV DATA_COUNT,#1H ; 裝入待寫數據塊的長度
WRITE: ;發送數據DATA_BYTE到存儲器地址DATA_ADDR
MOV SLA_ADD,#CHIP_A ; 裝入從器件的寫地址
MOV TRANSMIT_BYTE,DATA_BYTE ; 將待發送數據裝入TRANSMIT_BYTE
MOV SUBADR_ADD,DATA_ADDR ;將器件地址裝入 SUBADR_ADD
LCALL SEND ; 調用發送子程序
INC DATA_BYTE ;數據的值加一
INC DATA_ADDR ;地址加1
DJNZ DATA_COUNT,WRITE ; 計數器減1循環
READ:MOV R1,#50H
MOV DATA_ADDR,#00H ; 裝入首地址
MOV DATA_COUNT,#1H ; 裝入數據塊長度
SETB EA ;開中斷
MOV SLA_ADD,#CHIP_A ;裝入從器件的寫地址
MOV SUBADR_ADD,DATA_ADDR ;將存儲器地址裝入 SUBADR_ADD
LCALL RECEIVE ; 調用接收子程序
MOV 30H,RECEIVE_BYTEH ;從LM92讀出的數據的高8位存入30H
MOV 31H,RECEIVE_BYTEL ;從LM92讀出的數據的低8位存入31H
LCALL LDELAY
CLR SI
CLR EA
LCALL EXCHG ; 數據轉換子程序
LCALL SAA1064 ;SAA1064驅動四位數碼管顯示子程序
SJMP READ ; 運行結束,原地等待.
;發送子程序SEND;向LM92發送單字節寫操作。
SEND:
PUSH ACC ;保存累加器
JB SM_BUSY,$ ;等待SMBus空閑
CLR RW ; RW＝ 0（寫）
MOV A,SLA_ADD ; 取SLA_ADD到A
MOV WRI_ADD,A ;將SLA_ADD＋ WRITE保存到WRI_ADD
SETB SM_BUSY ; 占用SMBus
SETB STA ; 啟動發送過程
JB SM_BUSY,$ ;等待發送結束（在中斷中處理）
POP ACC
RET
; 接收子程序RECEIVE
;接收子程序RECEIVE執行一次讀出LM92溫度值(16位)的操作。讀出兩個字節.
RECEIVE:
PUSH ACC ;保存累加器
JB SM_BUSY,$ ;等待 SMBus空閑
SETB RW ;RW＝ l（讀）
MOV A,SLA_ADD ;取SLA_ADD到A
MOV WRI_ADD,A ;將SLA_ADD＋ WRITE保存到WRI_ADD
MOV A,SLA_ADD ;取SLA_ADD到A
ORL A,#01 ; 準備加讀命令
MOV READ_ADD,A ; 將SLA_ADD＋READ保存到 READ_ADD
SETB SM_BUSY ; 占用SMBus
SETB STA ; 啟動發送過程
JB SM_BUSY,$ ;等待接收結束（在中斷中處理）
POP ACC ; 恢復累加器
RET
;SMBus 中斷程序 ,處理SMBUS 中斷
SMBus_ISR:
PUSH PSW ; 保護現場
PUSH ACC ;
PUSH DPH ;
PUSH DPL ;
MOV A,SMB0STA ; 將當前SMBus狀態(SMB0STA)裝入累加器
; 每個狀態對應一個地址偏移量
ANL A,#7FH ; 屏蔽最高位
MOV @R1,A ;在50H---60H中存放SMB0STA和SMB0DAT,可查看中斷路徑
INC R1
MOV @R1,SMB0DAT;
INC R1
MOV DPTR,#SMB_STATE_TABLE ; DPTR指向狀態表的起始地址
JMP @A+DPTR ;轉移到當前狀態
;SMBuS狀態表 ;(SMB0STA =00H)
SMB_STATE_TABLE: ; SMB_BUS_ERROR總線錯誤(對所有方式)
ORG SMB_STATE_TABLE+SMB_BUS_ERROR
SETB STO ; 停止位置1,使硬件復位
JMP SMB_ISR_END ; 中斷返回
;SMB_START ; (SMB0STA =08H)
;主發送器／接收器發送起始位成功.再將從機寫地址送SMB0DAT并清除START位.
ORG SMB_STATE_TABLE+SMB_START
MOV SMB0DAT,WRI_ADD ; 裝載從地址＋ W````
CLR STA ; 清除START位
JMP SMB_ISR_END ; 中斷返回
;SMB_RP_START ;(SMB0STA =10H)
;主發送器／接收器發送重復起始位成功.
;再將從機讀地址送SMB0DAT并清除START位.
ORG SMB_STATE_TABLE+SMB_RP_START
MOV SMB0DAT,READ_ADD ;裝載從地址＋ R
CLR STA ; 清除START位
JMP SMB_ISR_END
;SMB_MTADDACK (SMB0STA =18H)
;主發送器（MT）發送從地址＋W成功；收到 ACK(從機應答)
;再將要發的子地址送入SMB0DAT.
ORG SMB_STATE_TABLE+SMB_MTADDACK
MOV SMB0DAT,SUBADR_ADD ;裝載從器件的子地址到SMB0DAT.
SETB BYTE_SENT ;BYTE_SENT＝1.在下一次中斷調用時存儲器地址剛被發送
JMP SMB_ISR_END
;SMB_MTADDNACK (SMB0STA =20H)
;主發送器（MT）發送從地址＋W成功；收到 NACK(從機無應答)
;用確認查詢重試。發送 STOP＋START
ORG SMB_STATE_TABLE + SMB_MTADDNACK
SETB STO
SETB STA
JMP SMB_ISR_END
;SMB_MTDBACK SMB0STA =28H)
;主發送器（MT）發送數據字節成功；收到ACK(從機應答)
;檢查BYTE_SENT：如果為1，說明剛發出的是存儲器地址；為0，剛發出的是數據字節
ORG SMB_STATE_TABLE+SMB_MTDBACK
JBC BYTE_SENT,ADDRESS_SENT ;如果BYTE_SENT＝1，清除該位并轉到
;ADDRESS_SENT去執行狀態表以外的處理程序
JMP DATA_SENT ; 如果BYTE_SENT＝0，數據剛被發出，
; 傳輸過程完成，轉到傳輸結束
;SMB_MTDBNACK ;(SMB0STA =30H)
;主發送器（MT）發送數據成功；收到NACK,從機無應答.
;用確認查詢重試。發送STOP＋START重試
ORG SMB_STATE_TABLE+SMB_MTDBNACK
SETB STO
SETB STA
JMP SMB_ISR_END
; SMB_MTARBLOST ;(SMB0STA =38H);競爭失敗.重新啟動傳輸.
ORG SMB_STATE_TABLE+SMB_MTARBLOST
SETB STO
SETB STA
JMP SMB_ISR_END
; SMB_MRADDACK ;(SMB0STA =40H)
;（MR）主收發器發送從地址＋R成功；收到 ACK(從機應答).主機發送ACK.
ORG SMB_STATE_TABLE+SMB_MRADDACK
SETB AA ;主機發送ACK,轉入SMB_MRDBACK
JMP SMB_ISR_END
; SMB_MRADDNACK ;(SMB0STA =48H)
;（MR）主收發器發送從地址＋R成功；收到NACK(從機無應答),發送重復起始位重試
ORG SMB_STATE_TABLE+SMB_MRADDNACK
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -