?? 6r.asm
?? 包含多個單片機程序（C語言）
?? ASM
字號:
??
; *************************************
; * (INCEPT3.ASM) *
; * 十五路遙控接收板 *
; * 2001.7.18 *
; * *
; *************************************
;
;**********************************************************************
;* *
;* A P1.0 1 40 VCC *
;* B P1.1 2 39 P0.0 LED0 *
;* C P1.2 3 38 P0.1 LED1 *
;* P1.3 4 37 P0.2 LED2 *
;* P1.4 5 36 P0.3 LED3 *
;* P1.5 6 35 P0.4 LED4 *
;* P1.6 7 34 P0.5 LED5 *
;* P1.7 8 33 P0.6 LED6 *
;* 100HZ RST 9 32 P0.7 LED7 *
;* P3.0 10 MCS-51 31 EA VDD *
;* P3.1 11 30 ALE *
;* REMOTEIN P3.2 12 29 PSEN *
;* P3.3 13 28 P2.7 調光脈沖 *
;* P3.4 14 27 P2.6 LED8 *
;* P3.5 15 26 P2.5 LED9 *
;* P3.6 16 25 P2.4 LED10 *
;* P3.7 17 24 P2.3 LED11 *
;* XTAL2 18 23 P2.2 LED12 *
;* XTAL1 19 22 P2.1 LED13 *
;* VSS 20 21 P2.0 DEV14(燈泡) *
;* *
;* *
;**********************************************************************
;注：P3.0為100HZ的交流電源過零點相位參考輸入
;
;
;*************************************
;* *
;* 主程序和中斷程序入口 *
;* *
;*************************************
ORG 0000H ;程序開始地址
LJMP START ;跳至START執行
ORG 0003H ;外中斷0中斷入口
LJMP INTEX0 ;跳至INTEX0執行中斷服務程序
ORG 000BH ;定時器T0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0013H ;外中斷1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 001BH ;定時器T1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0023H ;串行口中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 002BH ;定時器T2中斷入口地址
RETI ;中斷返回（不開中斷）
;
;***************************
;* *
;* 初始化程序 *
;* *
;****************************
CLEARMEMIO: CLR A ;
DEC A ;A為#0FFH
MOV P0,A ;P1-P3口置1
MOV P1,A ;
MOV P2,A ;
MOV P3,A ;
CLEARMEM: MOV IE,#00H ;關所有中斷
SETB EX0 ;開外中斷
SETB EA ;總中斷允許
RET ;子程序返回
;
;*************************************
;* *
;* 主程序 *
;* *
;*************************************
START: LCALL CLEARMEMIO ;上電初始化
LCALL LOOP ;調用調光控制程序
;
MAIN: JB P3.0,MAIN ;50HZ交流電未過零轉MAIN
LCALL DLX ;過零點時調用延時子程序（延時可變）
CLR P2.7 ;發調光脈沖
LCALL DELAY ;持續512微秒
SETB P2.7 ;關調光脈沖
LJMP MAIN ;轉MAIN循環
NOP ;PC值出錯處理
NOP
LJMP START ;出錯時重新初始化
;******************************
; 遙控接收程序
;******************************
;采用中斷接收
INTEX0: CLR EX0 ;關外中斷
JNB P3.1,READ1 ;P3.1口為低電平轉READ1
READOUTT0: SETB EX0 ;P3.1口為高電平開中斷（系干擾）
RETI ;退出中斷
;
READ1: CLR A ;清A
MOV DPH,A ;清DPTR
MOV DPL,A ;
HARD1: JB P3.1,HARD11 ;P3.1變高電平轉HARD11
INC DPTR ;用DPTR對低電平計數
NOP ;1微秒延時
NOP
AJMP HARD1 ;轉HARD1循環（循環周期為8微秒）
HARD11: MOV A,DPH ;DPTR高8位放入A
JZ READOUTT0 ;為0（脈寬小于8*255=2毫秒）退出
CLR A ;不為0，說明是第一個寬脈沖（3毫秒）
READ11: INC A ;脈沖個數計1
READ12: JNB P3.1,READ12 ;低電平時等待
MOV R1,#06H ;高電平寬度判斷定時值
READ13: JNB P3.1,READ11 ;變低電平時轉READ11脈沖計數
LCALL DELAY ;延時（512微秒）
DJNZ R1,READ13 ;6次延時不到轉READ13再延時
DEC A ;超過3毫秒判為結束，減1
DEC A ;減1
JZ FUN0 ;為0執行FUN0（2個脈沖）
DEC A ;減1
JZ FUN1 ;為0執行FUN1（3個脈沖）
DEC A ;
JZ FUN2 ;為0執行FUN2（4個脈沖）
DEC A ;
JZ FUN3 ;為0執行FUN3（5個脈沖）
DEC A ;
JZ FUN4 ;為0執行FUN4（6個脈沖）
DEC A ;
JZ FUN5 ;為0執行FUN5（7個脈沖）
DEC A ;
JZ FUN6 ;為0執行FUN6（8個脈沖）
DEC A ;
JZ FUN7 ;為0執行FUN7（9個脈沖）
DEC A ;
JZ FUN8 ;為0執行FUN8（10個脈沖）
DEC A ;
JZ FUN9 ;為0執行FUN9（11個脈沖）
DEC A ;
JZ FUN10 ;為0執行FUN10（12個脈沖）
DEC A ;
JZ FUN11 ;為0執行FUN11（13個脈沖）
DEC A ;
JZ FUN12 ;為0執行FUN12（14個脈沖）
DEC A ;
JZ FUN13 ;為0執行FUN13（15個脈沖）
DEC A ;
JZ FUN14 ;為0執行FUN14（16個脈沖）
DEC A ;
JZ FUN15 ;為0執行FUN15（17個脈沖）
NOP ;
NOP ;
LJMP READOUTT0 ;出錯退出
;
FUN0: CPL P0.0 ;P0口各端口開關輸出控制
LJMP READOUTT0 ;轉中斷退出
FUN1: CPL P0.1 ;
LJMP READOUTT0 ;
FUN2: CPL P0.2
LJMP READOUTT0
FUN3: CPL P0.3
LJMP READOUTT0
FUN4: CPL P0.4
LJMP READOUTT0
FUN5: CPL P0.5
LJMP READOUTT0
FUN6: CPL P0.6
LJMP READOUTT0
FUN7: CPL P0.7
LJMP READOUTT0
FUN8: CPL P2.6 ;P2口各端口開關輸出控制
LJMP READOUTT0 ;轉中斷退出
FUN9: CPL P2.5
LJMP READOUTT0
FUN10: CPL P2.4
LJMP READOUTT0
FUN11: CPL P2.3
LJMP READOUTT0
FUN12: CPL P2.2
LJMP READOUTT0
FUN13: CPL P2.1
LJMP READOUTT0
FUN14: CPL P2.0 ;P2.0口開關控制
LJMP READOUTT0 ;轉中斷退出
FUN15: DEC P1 ;P1口值減1
MOV A,P1 ;移入A
CJNE A,#0F7H,OUTT0 ;不等轉OUTT0（顯示值小于7）
CLR A ;相等清A
DEC A ;A為#0FFH
MOV P1,A ;放回P1（顯示值為7）
OUTT0: LCALL LOOP ;亮度調整
LJMP READOUTT0 ;中斷退出
;
;*************************************
;* 延時 255 X 2 ＝ 512 us *
;*************************************
;
DELAY: MOV R0,#0FFH
DELAY1: DJNZ R0,DELAY1
RET
;
;*************************************
;* 延時10 ms *
;*************************************
;
DL10MS: MOV R1,#14H
DL10MS1: LCALL DELAY
DJNZ R1,DL10MS1
RET
;
;*************************************
;* 調光延時時間控制 *
;*************************************
;
DLX: MOV R2,B ;置延時初值
DLX1: LCALL DELAY ;調512微秒延時子程序
DJNZ R2,DLX1 ;循環控制
RET ;返回
;
;*************************************
;* 調光控制程序 *
;*************************************
;根據數碼管指示值設置調光脈沖延時值
LOOP: MOV A,P1 ;讀入P1口值
SUBB A,#0FFH ;比較
JZ LOOP7 ;值為#0FFH（顯示7）時轉LOOP7
MOV A,P1 ;
SUBB A,#0FEH ;
JZ LOOP6 ;值為#0FEH（顯示6）時轉LOOP6
MOV A,P1 ;
SUBB A,#0FDH ;
JZ LOOP5 ;值為#0FDH（顯示5）時轉LOOP5
MOV A,P1 ;
SUBB A,#0FCH ;
JZ LOOP4 ;值為#0FCH（顯示4）時轉LOOP4
MOV A,P1 ;
SUBB A,#0FBH ;
JZ LOOP3 ;值為#0FBH（顯示3）時轉LOOP3
MOV A,P1 ;
SUBB A,#0FAH ;
JZ LOOP2 ;值為#0FAH（顯示2）時轉LOOP2
MOV A,P1 ;
SUBB A,#0F9H ;
JZ LOOP1 ;值為#0F9H（顯示1）時轉LOOP1
MOV A,P1 ;
SUBB A,#0F8H ;
JZ LOOP0 ;值為#0F8H（顯示0）時轉LOOP0
RET ;返回
;
LOOP7: MOV B,#01H ;設置延時值#01H（最亮）
RET ;返回
LOOP6: MOV B,#02H ;設置延時值#02H（次亮）
RET ;返回
LOOP5: MOV B,#04H ;
RET
LOOP4: MOV B,#06H ;
RET
LOOP3: MOV B,#08H ;
RET
LOOP2: MOV B,#0AH ;
RET
LOOP1: MOV B,#0CH ;設置延時值#0CH（次暗）
RET ;返回
LOOP0: MOV B,#0DH ;設置延時值#0DH（最暗）
RET ;返回
;
END ;程序結束
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -