?? 18b20.asm
字號:
;本程序測量溫度范圍：0~125度，精確到0.06；
;********************************************************************************
;* 日期: 2008-2-25 *
;* 版本: 3.0 *
;* 作者: 深圳志博電子有限公司 專業8051單片機教學站 *
;* 郵箱: zty0012001@163.com *
;* 網站： http://www.elecmcu.com http://www.elecmcu.com 更多例程請登陸網站 *
;********************************************************************************
;* 硬件：此程序在本公司志博電子實驗儀運行通過 *
;********************************************************************************
;* 【版權】 Copyright(C)深圳志博電子有限公司 www.elecmcu.com All Rights Reserved *
;* 【聲明】 此程序僅用于學習與參考，引用請注明版權和作者信息！ *
;********************************************************************************
DAT BIT P1.7 ;數據通信口
WDLSB DATA 30H ;讀出的溫度低字節
WDMSB DATA 31H ;讀出的溫度高字節
DIS_1 BIT P0.5 ;第一個數碼管顯示選擇
DIS_2 BIT P0.6 ;第二個數碼管顯示選擇
DIS_3 BIT P0.7 ;第三個數碼管顯示選擇
DIS_4 BIT P1.0 ;第四個數碼管顯示選擇
DIS_5 BIT P1.1 ;第五個數碼管顯示選擇
DIS_6 BIT P0.4 ;第六個數碼管顯示選擇
DIS_DATA DATA P2 ;6位數碼管的公共數據口
DIS_INDEX DATA 32H ;顯示位序列，存儲目前顯示的是第幾位
DIS_BUFF DATA 40H ;顯示緩沖區首地址 一共從0X19-0X1E 六個字節
;***************************************************************
ORG 0000H
LJMP MAIN
ORG 000BH
SJMP TIMER0 ;定時顯示
;****************************************************************
;定時顯示子程序，采用循環掃描方式
;顯示緩沖區40H~47H
ORG 0040H
TIMER0:
;**********************************************************
; 數碼管顯示子程序
;**********************************************************
PLAY: ;顯示子程序開始
; MOV DIS_INDEX,#00 ;初始化顯示的數碼管是第0位
DISPLAY_START: ;顯示一位開始
CALL OFF_ALL ;調用子程序關閉所有數碼管的顯示
MOV DIS_DATA,#00 ; 6個數目管的公共顯示數據寫0關閉
MOV A, DIS_INDEX
DIS0_B: CJNE A,#0X00,DIS1_B
CLR DIS_1
JMP MOV_DAT
DIS1_B:
CJNE A,#0X01,DIS2_B
CLR DIS_2
JMP MOV_DAT
DIS2_B:
CJNE A,#0X02,DIS3_B
CLR DIS_3
JMP MOV_DAT
DIS3_B:
CJNE A,#0X03,DIS4_B
CLR DIS_4
JMP MOV_DAT
DIS4_B:
CJNE A,#0X04,DIS5_B
CLR DIS_5
JMP MOV_DAT
DIS5_B:
CJNE A,#0X05,DIS_END
CLR DIS_6
JMP MOV_DAT ;以上程序根據現在的顯示位數進行條件分支，分別打開相應的顯示使能位
MOV_DAT:
MOV A, DIS_INDEX
MOV R1,#DIS_BUFF
ADD A,R1
MOV R0,A
MOV A,@R0 ;獲得目前的顯示位所對應自己的緩沖數據
MOV DPTR,#DIS_TAB
MOVC A,@A+DPTR
ANL A,#0XDF
MOV 0X37,A
MOV A,DIS_INDEX
CJNE A,#03,RE_DIS
MOV A,0X37
ORL A,#0X20
JMP RE_DIS1
RE_DIS:
MOV A,0X37
RE_DIS1: MOV DIS_DATA,A ;將目前的顯示數據經過查表獲得對應的數碼管段碼
INC DIS_INDEX ;顯示位序加一，指向下一位
MOV A,DIS_INDEX
CJNE A,#6,DIS_END ;以上兩句判斷是否循環顯示夠6位是的話返回到被調用的位置 否則進行下一次循環
MOV DIS_INDEX,#00
DIS_END:
MOV TH0,#LOW(65536-40000) ;定時器10MS中斷
MOV TL0,#HIGH(65536-40000)
RETI
T1MS: mov r5,#00h ;延時子程序
tt: mov r6,#9
djnz r6,$
djnz r5,tt
ret
DELAY: ;延遲子程序
MOV R6,#0X01
DELAY0: MOV R5,#0XFF
DELAY1: MOV R4,#0XFF
DJNZ R4,$
DJNZ R5,DELAY1
DJNZ R6,DELAY0
RET
OFF_ALL: ;關閉所有顯示位的子程序
SETB DIS_1
SETB DIS_2
SETB DIS_3
SETB DIS_4
SETB DIS_5
SETB DIS_6
RET
DIS_TAB: ;0-9 所對應的數碼管段碼 最后一個00 是總關閉顯示
DB 0x7f,0x44,0xbd,0xf5,0xe6,0xf3,0xfb,0x65,0xff,0xf7,0x00
;*********************************************************
;主程序:
MAIN: MOV SP,#60H
MOV DIS_INDEX,#00
MOV R2,#8
MOV R0,#40H ;
OVER: MOV @R0,#00H
INC R0
DJNZ R2,OVER
MOV 40H,#10;
MOV 41H,#10;
MOV TMOD,#01H
MOV TH0,#LOW(65536-10000)
MOV TL0,#HIGH(65536-10000)
SETB EA
SETB ET0
SETB TR0
LOOP: LCALL DSWD ;調用讀出DS18B20溫度程序
SJMP LOOP ; 讀出DS18B20溫度程序
DSWD:
CLR EA
LCALL RST
JNB F0,KEND ;如果沒有應答，返回主程序
MOV R0,#0CCH
LCALL SEND_BYTE ;跳過ROM匹配
MOV R0,#44H ;發出溫度轉換命令
LCALL SEND_BYTE
SETB EA
;MOV P1,#00001111B
MOV 48H,#4 ;廷時75ms以上準備讀
SS2: MOV 49H,#255
SS1: MOV 4AH,#255
SS0: DJNZ 4AH,SS0
DJNZ 49H,SS1
DJNZ 48H,SS2
;MOV P1,#11111100B
CLR EA
LCALL RST
JNB F0,KEND
MOV R0,#0CCH ;跳過ROM匹配
LCALL SEND_BYTE
MOV R0,#0BEH ;發出讀溫度命令
LCALL SEND_BYTE
LCALL READ_BYTE
MOV WDLSB,A
LCALL READ_BYTE
MOV WDMSB,A
LCALL TRANS12
KEND: ;mov p1,#01010101b
SETB EA
RET
;**********************************************************
;溫度轉換程序：精確到：0.06 ;
TRANS12:MOV A,30H
ANL A,#0F0H
MOV 3AH,A
MOV A,31H
ANL A,#0FH
ORL A,3AH
SWAP A
MOV B,#10
DIV AB
MOV 42H,A
MOV 43H,B ;
MOV DPTR,#TABB
MOV A,30H
ANL A,#0FH
MOV B,#2
MUL AB
MOVC A,@A+DPTR
MOV 44H,A
MOV A,30H
ANL A,#0FH
MOV B,#2
MUL AB
INC A
MOVC A,@A+DPTR
MOV 45H,A
RET
TABB: DB 0,0,0,6,1,2,1,8,2,5,3,1,3,7,4,3,5,0
DB 5,6,6,2,6,8,7,5,8,1,8,7,9,3
;*************************************************
SEND_BYTE: ;發送一個字節程序
MOV A,R0
MOV R5,#8
SEN3: CLR C
RRC A
JC SEN1
LCALL WRITE_0
SJMP SEN2
SEN1: LCALL WRITE_1
SEN2: DJNZ R5,SEN3 ; 循環8次，寫一個字節
RET
READ_BYTE: ;讀一個字節程序
MOV R5,#8
READ1: LCALL READ
RRC A
DJNZ R5,READ1 ; 循環8次，讀一個字節
MOV R0,A
RET
;復位程序，如果復位置位F0,沒有就復位F0
RST: SETB DAT
NOP
NOP
CLR DAT
MOV R6,#250 ;主機發復位脈沖持續3μs50200=600μs
DJNZ R6,$
MOV R6,#50
DJNZ R6,$
MOV R6,#250 ;主機發復位脈沖持續3μ00=600μs
DJNZ R6,$
MOV R6,#50
DJNZ R6,$
MOV R6,#250 ;主機發復位脈沖持續3μs×200=600μs
DJNZ R6,$
MOV R6,#50
DJNZ R6,$
MOV R6,#250 ;主機發復位脈沖持續3μs×200=600μs
DJNZ R6,$
MOV R6,#50
DJNZ R6,$
SETB DAT ;主機釋放總線，口線改為輸入
MOV R6,#60
DJNZ R6,$
CALL CHCK ;調用應答檢查程序
MOV R6,#240
DJNZ R6,$
SETB DAT
RET
CHCK: MOV C,DAT
JC RST0
SETB F0 ;檢測到信號，置位F0
SJMP CHCK0
RST0: CLR F0 ;未準備好F0復位
CHCK0: RET
WRITE_0: ;寫0
CLR DAT
MOV R6,#120
DJNZ R6,$
SETB DAT
RET
WRITE_1:CLR DAT ;寫1
NOP
NOP
NOP
NOP
NOP
SETB DAT
MOV R6,#120
DJNZ R6,$
RET
;讀一位數據程序
READ: SETB DAT ;先復位至少1US產生讀起始信號
NOP
NOP
CLR DAT
NOP
NOP
SETB DAT ;置位DAT準備接收數據
NOP
NOP
NOP
NOP
NOP
NOP
NOP
MOV C,DAT
MOV R6,#92
DJNZ R6,$
RET
END
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -