;運算程序
         ADDD:MOV A,R7      ;加
              ADD A,R3
              MOV R3,A
              MOV A,R6
              ADDC A,R2
              MOV R2,A
              RET
         SUBD:CLR C         ;減
              MOV A,R3
              SUBB A,R7
              MOV R3,A
              MOV A,R2
              SUBB A,R6
              MOV R2,A
              RET
         COMP:MOV A,R3      ;取補
              CPL A
              ADD A,#01H
              MOV R3,A
              MOV A,R2
              CPL A
              ADDC A,#00H
              MOV R2,A
              RET
         MULD:MOV A,R3      ;乘
              MOV B,R7
              MUL AB
              MOV R4,B
              MOV R5,A
              MOV A,R3
              MOV B,R6
              MUL AB
              ADD A,R4
              MOV R4,A
              CLR A
              ADDC A,B
              MOV R3,A
              MOV A,R2
              MOV B,R7
              MUL AB
              ADD A,R4
              MOV R4,A
              MOV A,R3
              ADDC A,B
              MOV R3,A
              CLR A
              RLC A
              XCH A,R2
              MOV B,R6
              MUL AB
              ADD A,R3
              MOV R3,A
              MOV A,R2 
              ADDC A,B 
              MOV R2,A
              RET
           SHCH4:MOV A,R2                ;開方程序
	      ORL A,R3     
	      ORL A,R4
	      ORL A,R5
	      JNZ SHCH40
	      RET
       SHCH40:MOV R7,#0
	      MOV A,R2
       SHCH41:ANL A,#0C0H
	      JNZ SQRH
	      MOV R6,#2
       SHCH42:CLR C
	      MOV A,R5
	      RLC A
	      MOV R5,A
	      MOV A,R4
	      RLC A
	      MOV R4,A
	      MOV A,R3
	      RLC A
	      MOV R3,A
	      MOV A,R2
	      RLC A
	      MOV R2,A
	      DJNZ R6,SHCH42
	      INC R7
	      SJMP SHCH41
         SQRH:MOV A,R2
	      ADD A,#57H
	      JC SQR2
	      ADD A,#45H
	      JC SQR1
	      ADD A,#24H
	      MOV B,#0E3H
	      MOV R4,#80H
    	      SJMP SQR3
         SQR1:MOV B,#0B2H
	      MOV R4,#0A0H
 	      SJMP SQR3
         SQR2:MOV B,#8DH
	      MOV R4,#0D0H
         SQR3:MUL AB
	      MOV A,B
	      ADD A,R4
	      MOV R4,A
	      MOV B,A
	      MUL AB
	      XCH A,R3
	      CLR C
 	      SUBB A,R3
	      MOV R3,A
	      MOV A,R2
	      SUBB A,B
	      MOV R2,A
         SQR4:SETB C
	      MOV A,R4
	      RLC A
	      MOV R6,A
	      CLR A
	      RLC A
	      MOV R5,A
	      MOV A,R3
	      SUBB A,R6
	      MOV B,A
	      MOV A,R2
	      SUBB A,R5
	      JC SQR5
	      INC R4
	      MOV R2,A
	      MOV R3,B
	      SJMP SQR4
         SQR5:MOV A,R4
	      XCH A,R2
	      RRC A
	      MOV PSW.5,C
	      MOV A,R3
	      MOV R5,A
 	      MOV R4,#8H
         SQR6:CLR C
	      MOV A,R3
	      RLC A
	      MOV R3,A
	      CLR C
	      MOV A,R5
	      SUBB A,R2
	      JB PSW.5,SQR7
	      JC SQR8
         SQR7:MOV R5,A
   	      INC R3
         SQR8:CLR C
	      MOV A,R5
	      RLC A
	      MOV R5,A
	      MOV PSW.5,C
	      DJNZ R4,SQR6
	      MOV A,R7
	      JZ SQRE
         SQR9:CLR C
	      MOV A,R2
	      RRC A
	      MOV R2,A
 	      MOV A,R3
	      RRC A
	      MOV R3,A
              DJNZ R7,SQR9
         SQRE:RET