<p>VB下如何編寫CRC校驗程序</p>
<p></p>
<p></p>
<p>欒金奎</p>
<p></p>
<p>　　隨著計算機技術的不斷發展，在現代工業中，利用微機進行數據通訊的工業控制應用得也越來越廣泛。由于傳輸距離、現場狀況等諸多可能出現的因素影響，計算機與受控設備之間的通訊數據常會發生無法預測的錯誤。為了防止錯誤所帶來的影響，一般在通訊時采取數據校驗的辦法，而循環冗余碼校驗是最常用的校驗方法之一。</p>
<p></p>
<p>一、 循環冗余碼校驗原理</p>
<p></p>
<p>　　循環冗余碼校驗英文名稱為Cyclical Redundancy Check，簡稱CRC。它是利用除法及余數的原理來作錯誤偵測（Error Detecting）的。實際應用時，發送裝置計算出CRC值并隨數據一同發送給接收裝置，接收裝置對收到的數據重新計算CRC并與收到的CRC相比較，若兩個CRC值不同，則說明數據通訊出現錯誤。</p>
<p>根據應用環境與習慣的不同，CRC又可分為以下幾種標準：</p>
<p>　　①CRC-12碼；</p>
<p>　　②CRC-16碼；</p>
<p>　　③CRC-CCITT碼；</p>
<p>　　④CRC-32碼。</p>
<p>　　CRC-12碼通常用來傳送6-bit字符串。CRC-16及CRC-CCITT碼則用是來傳送8-bit字符，其中CRC-16為美國采用，而CRC-CCITT為歐洲國家所采用。CRC-32碼大都被采用在一種稱為Point-to-Point的同步傳輸中。</p>
<p>下面以最常用的CRC-16為例來說明其生成過程。</p>
<p>　　CRC-16碼由兩個字節構成，在開始時CRC寄存器的每一位都預置為1，然后把CRC寄存器與8-bit的數據進行異或，之后對CRC寄存器從高到低進行移位，在最高位（MSB）的位置補零，而最低位（LSB，移位后已經被移出CRC寄存器）如果為1，則把寄存器與預定義的多項式碼進行異或，否則如果LSB為零，則無需進行異或。重復上述的由高至低的移位8次，第一個8-bit數據處理完畢，用此時CRC寄存器的值與下一個8-bit數據異或并進行如前一個數據似的8次移位。所有的字符處理完成后CRC寄存器內的值即為最終的CRC值。</p>
<p>　　下面為CRC的計算過程：</p>
<p>　　1．設置CRC寄存器，并給其賦值FFFF(hex)。</p>
<p>　　2．將數據的第一個8-bit字符與16位CRC寄存器的低8位進行異或，并把結果存入CRC寄存器。</p>
<p>　　3．CRC寄存器向右移一位，MSB補零，移出并檢查LSB。</p>
<p>　　4．如果LSB為0，重復第三步；若LSB為1，CRC寄存器與多項式碼相異或。</p>
<p>　　5．重復第3與第4步直到8次移位全部完成。此時一個8-bit數據處理完畢。</p>
<p>　　6．重復第2至第5步直到所有數據全部處理完成。</p>
<p>　　7．最終CRC寄存器的內容即為CRC值。</p>
<p></p>
<p>二、 循環冗余碼校驗程序的編寫</p>
<p></p>
<p>　　明白了CRC校驗碼的產生過程，編寫起程序來就非常容易了。由于Visual Basic的廣泛普及以及其在數據通訊中的重要地位，下面就以VB語言來編寫CRC的生成程序，其它語言只需稍做修改即可。</p>
<p>　　編寫CRC校驗程序有兩種辦法：一種為計算法，一種為查表法。下面對兩種方法分別討論。</p>
<p></p>
<p>　　1．計算法</p>
<p>　　計算法就是依據CRC校驗碼的產生原理來設計程序。其優點是模塊代碼少，修改靈活，可移植性好。其缺點為計算量大。為了便于理解，這里假定了三位數據，而多項式碼為A001(hex)。</p>
<p>　　在窗體上放置一命令按鈕Command1，并添加如下代碼：</p>
<p></p>
<p>　　Private Sub Command1_Click()</p>
<p>　　　Dim CRC() As Byte</p>
<p>　　　Dim d() As Byte '待傳輸數據</p>
<p>　　　ReDim d(2) As Byte</p>
<p>　　　d(0) = 123</p>
<p>　　　d(1) = 112</p>
<p>　　　d(2) = 135</p>
<p>　　　CRC = CRC16(d) '調用CRC16計算函數</p>
<p>　　　'CRC(0)為高位</p>
<p>　　　'CRC(1)為低位</p>
<p>　　End Sub</p>
<p>　　注意：在數據傳輸時CRC的低位可能在前，而高位在后。</p>
<p></p>
<p>　　Function CRC16(data() As Byte) As String</p>
<p>　　　Dim CRC16Lo As Byte, CRC16Hi As Byte　　　'CRC寄存器</p>
<p>　　　Dim CL As Byte, CH As Byte　　　　　　　　'多項式碼&HA001</p>
<p>　　　Dim SaveHi As Byte, SaveLo As Byte</p>
<p>　　　Dim i As Integer</p>
<p>　　　Dim Flag As Integer</p>
<p>　　　CRC16Lo = &HFF</p>
<p>　　　CRC16Hi = &HFF</p>
<p>　　　CL = &H1</p>
<p>　　　CH = &HA0</p>
<p>　　　For i = 0 To UBound(data)</p>
<p>　　　　CRC16Lo = CRC16Lo Xor data(i) '每一個數據與CRC寄存器進行異或</p>
<p>　　　　For Flag = 0 To 7</p>
<p>　　　　　SaveHi = CRC16Hi</p>
<p>　　　　　SaveLo = CRC16Lo</p>
<p>　　　　　CRC16Hi = CRC16Hi \ 2　　　　　　'高位右移一位</p>
<p>　　　　　CRC16Lo = CRC16Lo \ 2　　　　　　'低位右移一位</p>
<p>　　　　　If ((SaveHi And &H1) = &H1) Then '如果高位字節最后一位為1</p>
<p>　　　　　　CRC16Lo = CRC16Lo Or &H80　　　'則低位字節右移后前面補1</p>
<p>　　　　　End If　　　　　　　　　　　　　 '否則自動補0</p>
<p>　　　　　If ((SaveLo And &H1) = &H1) Then '如果LSB為1，則與多項式碼進行異或</p>
<p>　　　　　　CRC16Hi = CRC16Hi Xor CH</p>
<p>　　　　　　CRC16Lo = CRC16Lo Xor CL</p>
<p>　　　　　End If</p>
<p>　　　　Next Flag</p>
<p>　　　Next i</p>
<p>　　　Dim ReturnData(1) As Byte</p>
<p>　　　ReturnData(0) = CRC16Hi　　　　　　　'CRC高位</p>
<p>　　　ReturnData(1) = CRC16Lo　　　　　　　'CRC低位</p>
<p>　　　CRC16 = ReturnData</p>
<p>　　End Function</p>
<p></p>
<p>　　2．查表法</p>
<p>　　查表法的優缺點與計算法的正好相反。為了便于比較，這里所有的假定與計算法的完全相同，都而在窗體上放置一個Command1的按鈕，其代碼部分與上面的也完全一致。下面只介紹CRC函數的編寫源代碼。</p>
<p></p>
<p>　　Private Function CRC16(data() As Byte) As String</p>
<p>　　　Dim CRC16Hi As Byte</p>
<p>　　　Dim CRC16Lo As Byte</p>
<p>　　　CRC16Hi = &HFF</p>
<p>　　　CRC16Lo = &HFF</p>
<p>　　　Dim i As Integer</p>
<p>　　　Dim iIndex As Long</p>
<p>　　　For i = 0 To UBound(data)</p>
<p>　　　　iIndex = CRC16Lo Xor data(i)</p>
<p>　　　　CRC16Lo = CRC16Hi Xor GetCRCLo(iIndex)　　　　'低位處理</p>
<p>　　　　CRC16Hi = GetCRCHi(iIndex)　　　　　　　　　　'高位處理</p>
<p>　　　Next i</p>
<p>　　　Dim ReturnData(1) As Byte</p>
<p>　　　ReturnData(0) = CRC16Hi　　　　'CRC高位</p>
<p>　　　ReturnData(1) = CRC16Lo　　　　'CRC低位</p>
<p>　　　CRC16 = ReturnData</p>
<p>　　End Function</p>
<p></p>
<p>　　'CRC低位字節值表</p>
<p>　　Function GetCRCLo(Ind As Long) As Byte</p>
<p>　　　GetCRCLo = Choose(Ind + 1, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, _</p>
<p>&H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40, &H1, &HC0, &H80, &H41, &H1, &HC0, &H80, &H41, &H0, &HC1, &H81, &H40)</p>
<p>　　End Function</p>
<p></p>
<p>　　'CRC高位字節值表</p>
<p>　　Function GetCRCHi(Ind As Long) As Byte</p>
<p>　　　GetCRCHi = Choose(Ind + 1, &H0, &HC0, &HC1, &H1, &HC3, &H3, &H2, &HC2, &HC6, &H6, &H7, &HC7, &H5, &HC5, &HC4, &H4, &HCC, &HC, &HD, &HCD, &HF, &HCF, &HCE, &HE, &HA, &HCA, &HCB, &HB, &HC9, &H9, &H8, &HC8, &HD8, &H18, &H19, &HD9, &H1B, &HDB, &HDA, &H1A, &H1E, &HDE, &HDF, &H1F, &HDD, &H1D, &H1C, &HDC, &H14, &HD4, &HD5, &H15, &HD7, &H17, &H16, &HD6, &HD2, &H12, &H13, &HD3, &H11, &HD1, &HD0, &H10, &HF0, &H30, &H31, &HF1, &H33, &HF3, &HF2, &H32, &H36, &HF6, &HF7, &H37, &HF5, &H35, &H34, &HF4, &H3C, &HFC, &HFD, &H3D, &HFF, &H3F, &H3E, &HFE, &HFA, &H3A, &H3B, &HFB, &H39, &HF9, &HF8, &H38, &H28, &HE8, &HE9, &H29, &HEB, &H2B, &H2A, &HEA, &HEE, &H2E, &H2F, &HEF, &H2D, &HED, &HEC, &H2C, &HE4, &H24, &H25, &HE5, &H27, &HE7, &HE6, &H26, &H22, &HE2, &HE3, &H23, &HE1, &H21, &H20, &HE0, &HA0, &H60, _</p>
<p>&H61, &HA1, &H63, &HA3, &HA2, &H62, &H66, &HA6, &HA7, &H67, &HA5, &H65, &H64, &HA4, &H6C, &HAC, &HAD, &H6D, &HAF, &H6F, &H6E, &HAE, &HAA, &H6A, &H6B, &HAB, &H69, &HA9, &HA8, &H68, &H78, &HB8, &HB9, &H79, &HBB, &H7B, &H7A, &HBA, &HBE, &H7E, &H7F, &HBF, &H7D, &HBD, &HBC, &H7C, &HB4, &H74, &H75, &HB5, &H77, &HB7, &HB6, &H76, &H72, &HB2, &HB3, &H73, &HB1, &H71, &H70, &HB0, &H50, &H90, &H91, &H51, &H93, &H53, &H52, &H92, &H96, &H56, &H57, &H97, &H55, &H95, &H94, &H54, &H9C, &H5C, &H5D, &H9D, &H5F, &H9F, &H9E, &H5E, &H5A, &H9A, &H9B, &H5B, &H99, &H59, &H58, &H98, &H88, &H48, &H49, &H89, &H4B, &H8B, &H8A, &H4A, &H4E, &H8E, &H8F, &H4F, &H8D, &H4D, &H4C, &H8C, &H44, &H84, &H85, &H45, &H87, &H47, &H46, &H86, &H82, &H42, &H43, &H83, &H41, &H81, &H80, &H40)</p>
<p>　　End Function</p>
<p></p>
<p>　　以上程序在Win98，VB6下調試通過。</p>
<p></p>