@ECHO ON

rem 調用格式 runstat 倉庫路徑 本地名稱 發布目錄
set repos=%1
set localname=%2
set target=%3

SET LOWER=0
SET UPPER=0

rem 檢查一下倉庫的最新版本，如果最新版本為0，說明沒有內容不需要統計，直接跳出
@FOR /f %%D IN ('%SVN_LOOK% youngest %repos%') DO set UPPER=%%D
if %UPPER%==0 GOTO :N_EXIT

rem 如果子目錄已經存在，認為工作拷貝已經存在，則直接更新，不進行檢出工作
if exist .\%localname%\nul GOTO :UPDATE

rem 檢出指定的倉庫路徑到本地名稱為目錄名的目錄下
:CHECKOUT
mkdir .\%localname%

%SVN_SVN% co file:///%repos% .\%localname%

rem 取出上次Update的版本號和當前版本號進行比較，如果版本號較舊則進行更新，否則說明不需要更新，直接跳出
:UPDATE
if not exist .\%localname%\%localname%_last_revision.txt GOTO :BEGIN_UPDATE

rem 取出上次備份后的版本號，并做＋1處理(注意此算法未在98系統驗證)
@FOR /f %%C IN (.\%localname%\%localname%_last_revision.txt) DO @set LOWER=%%C
@set /a LOWER=%LOWER%+1

rem 不需要更新，則跳轉結束
IF %LOWER% gtr %UPPER% GOTO :N_EXIT

rem 更新版本庫并記錄最新的版本號
:BEGIN_UPDATE
%SVN_SVN% update .\%localname%
@echo %UPPER% > .\%localname%\%localname%_last_revision.txt

rem 生成XMLLog文件logfile.log
cd %localname%
%SVN_SVN% log -v --xml > logfile.log

rem 調用Statsvn進行統計，本例中指定了需要統計的文件類型，并把結果輸出到指定的目錄，同時開50個線程進行查詢。
java -jar %STATSVN_JAR% -output-dir %target%\%localname% %target%\%localname%\logfile.log %target%\%localname% -include **/*.java;**/*.js;**/*jsp;**/*.xml -title SVNSpace -threads 50

cd ..

rem 到這里統計文件已經生成，可以到指定的發布目錄進行查看了。
:N_EXIT
@echo 項目庫%localname%處理結束...
@exit /B