?? ds1302.asm
字號:
;///////////////////////////////////////////
;本程序源代碼由單片機培訓網提供.
;單片機培訓網,讓更多人學習單片機更容易.
;第一網址----www.mcuedu.com
;第二網址----http://51_train.nease.net
;創辦人------劉永忠
;熱線電話----(0755)27529998
;email-------aa815@163.com
;本程序實現實時時鐘模塊 時鐘芯片型號：DS1302
;ds1302時鐘上升沿輸入命令或數據,下降沿輸出數據.
;time:2004.05.23
;///////////////////////////////////////////
;本程序使用的數碼管為共陽極數碼管.
; 顯示的時間:分為05,秒為00,然后在這個時間上累加.因數碼管有限,只顯示分
; 和秒.
; 在看本程序之前,最好看一下有關DS1302的資料.
T_CLK Bit P1.4 ;實時時鐘時鐘線引腳
T_IO Bit P1.5 ;實時時鐘數據線引腳
T_RST Bit P1.6 ;實時時鐘復位線引腳
;40h--46h 存放 "秒 分 時 日 月 星期 年 "
second equ 40h
org 0000h
ajmp main
org 0030h
main:
;
mov dptr,#tab ;送入表格地址
mov 40h,#00 ;秒賦初值
mov 41h,#05 ;分賦初值
mov 42h,#11 ;時賦初值
mov 43h,#23 ;日賦初值
mov 44h,#05 ;月賦初值
mov 45h,#00 ;星期賦初值
mov 46h,#04 ;年賦初值
lcall set1302 ;調用初值設定子程序
loop:
lcall get1302 ;調用時鐘子程序，時鐘自動加時
lcall exchange ;調用十六進制轉BCD碼子程序
mov r4, #3 ;刷新次數
tt1:
lcall display ;調用動態掃描子程序
djnz r4,tt1
ajmp loop
;***************************************
exchange:
mov a,41h
mov b,#10h
div ab ;把41H高低4位分開
mov 33h,a ;高4位存入33H單元
mov a,b
mov 32h,a ;低4位存入32H單元
mov a,40h
mov b,#10h
div ab ;把40H高低4位分開
mov 31h,a ;高4位存入31H單元
mov a,b
mov 30h,a ;低4位存入30H單元
ret
;***************************************
display:
mov r7,#100 ;動態掃描次數
dd1:
mov a,30h
movc a,@a+dptr
mov p0,a ;秒低位段選碼送P0口
clr p2.0 ;秒數碼管低位開顯示
lcall delay100us
setb p2.0 ;秒數碼管低位關顯示
mov a,31h
movc a,@a+dptr
mov p0,a ;秒高位段選碼送P0口
clr p2.1 ;秒數碼管高位開顯示
lcall delay100us
setb p2.1 ;秒數碼管高位關顯示
mov a,32h ;分低位段選碼送P0口
movc a,@a+dptr
mov p0,a ;分低位段選碼送P0口
clr p2.2 ;分數碼管低位開顯示
lcall delay100us
setb p2.2 ;分數碼管低位關顯示
mov a,33h
movc a,@a+dptr
mov p0,a ;分高位段選碼送P0口
clr p2.3 ;分數碼管高位開顯示
lcall delay100us
setb p2.3 ;分數碼管高位關顯示
djnz r7,dd1
ret
delay100us:
mov r5,#50
djnz r5,$
ret
tab: db 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h
;**********************************************************
;子程序名：Set1302
;功 能：設置DS1302 初始時間,并啟動計時。
;調 用：RTInputByte
;入口參數：初始時間:Second,Minute,Hour,Day,Month,Week.YearL(地址連續)
;出口參數：無
;影響資源：A B R0 R1 R4 R7
;設 計：劉永忠 日 期：04-5-23 10:52
;**********************************************************
Set1302:
CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, #8EH ;控制寄存器
LCALL RTInputByte
MOV B, #00H ;寫操作前WP=0
LCALL RTInputByte
SETB T_CLK
CLR T_RST
MOV R0, #Second;
MOV R7, #7 ;秒 分 時 日 月 星期 年
MOV R1, #80H ;秒寫地址
S13021: CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, R1 ;寫秒 分 時 日 月 星期 年 地址
LCALL RTInputByte
MOV A, @R0 ;寫秒數據
MOV B, A
LCALL RTInputByte
INC R0
INC R1
INC R1
SETB T_CLK
CLR T_RST
DJNZ R7, S13021
CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, #8EH ;控制寄存器
LCALL RTInputByte
MOV B, #80H ;控制,WP=1,寫保護
LCALL RTInputByte
SETB T_CLK
CLR T_RST
RET
;**********************************************************
;子程序名：Get1302
;功 能：從DS1302 讀時間
;調 用：RTInputByte,RTOutputByte
;入口參數：時間保存在:Second,Minute,Hour,Day,Month,Week.YearL
;出口參數：無
;影響資源：A B R0 R1 R4 R7
;設 計：劉永忠 日 期：04-5-23 10:52
;**********************************************************
Get1302:
MOV R0, #Second;
MOV R7, #7
MOV R1, #81H ;秒地址
G13021: CLR T_RST
CLR T_CLK
SETB T_RST
MOV B, R1 ;秒 分 時 日 月 星期 年 地址
LCALL RTInputByte
LCALL RTOutputByte
MOV @R0, A ;秒
INC R0
INC R1
INC R1
SETB T_CLK
CLR T_RST
DJNZ R7, G13021
RET
;**********************************************************
;功 能：寫1302一字節 （內部子程序）
;**********************************************************
RTInputByte:
MOV 50h, #8 ;一個字節有八個位,移八次.
Inbit1: MOV A, B
RRC A ;通過A移入CY.
MOV B, A
MOV T_IO, C ;移入芯片內.
SETB T_CLK
CLR T_CLK
DJNZ 50h, Inbit1
RET
;**********************************************************
;功 能：讀1302一字節 （內部子程序）
;**********************************************************
RTOutputByte:
MOV 50h, #8 ;一個字節有八個位,移八次.
Outbit1: MOV C, T_IO ;從芯片內移到CY
RRC A ;通過CY移入A.
SETB T_CLK
CLR T_CLK
DJNZ 50h, Outbit1
RET
;/////////////////////////////////////////////////////////////////
end
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -