?? keyscan_6.asm
字號:
;///////////////////////////////////////////
;本程序源代碼由單片機培訓網提供.
;單片機培訓網,讓更多人學習單片機更容易.
;第一網址----www.mcuedu.com
;第二網址----http://51_train.nease.net
;創辦人------劉永忠
;熱線電話----(0755)27529998
;email-------aa815@163.com
;本程序實現按住"B"鍵不動則每秒鐘向上加一,按住"C"鍵不動則每秒向下減一功能.
;按鍵行列值表示如下：
;----P1.7---P1.6---P1.5---P1.4-------
;----03H----02H----01H----00H----P1.0
;----07H----06H----05H----04H----P1.1
;----0BH----0AH----09H----08H----P1.2
;----0FH----0EH----0DH----0CH----P1.3
;///////////////////////////////////////////
org 0000h
ajmp main
org 0030h
main:
mov dptr,#tab ;將表頭位置送入DPTR
mov 30h,#00h ;將30顯示單元清零
mov 31h,#00h ;將30顯示單元清零
mov 32h,#00h ;將30顯示單元清零
mov 33h,#00h ;將30顯示單元清零
mov 37h,#00h ;軟件計數器,決定延時時間.
loop:
lcall display ;調用顯示程序
lcall key ;調用鍵盤描程序
cpl a ;將A的值取反
jz loop ;無鍵鍵按下則返回
mov a,34h ;有鍵按下將鍵值送入ACC
cjne a,#0bh,jj1 ;若B鍵未按下則跳轉到JJ1處
lcall incdigit ;若B鍵按下則跳轉到向上加一的子程序
ljmp loop ;加一以后返回LOOP處循環
jj1: cjne a,#0ch,loop ;若C鍵未按下則跳轉到LOOP處
lcall decdigit ;若C鍵有按下則調用向下減一的子程序
ljmp loop ;減一完成返回LOOP處循環
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
incdigit:
inc 30h ;將30H單元中的數加一
mov a,30h ;將30H單元的值送入ACC
cjne a,#10,incdelay ;ACC中的值與10不相等跳轉
mov 30h,#00h ;ACC中的值與10相等,把30H單元的值清零
inc 31h ;31H單元向上加一
mov a,31h ;將31H單元的值送入ACC
cjne a,#6,incdelay ;ACC中的值與6不相等跳轉
mov 31h,#00h ;將31H單元清零
incdelay: ;此延時子程序實現向上加一并決定顯示增加的快慢
lcall display
inc 37h
mov a,37h
cjne a,#20,incdelay
mov 37h,#00h
ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
decdigit: ;此延時子程序實現向下減一并決定顯示向下遞減的快慢
dec 30h
mov a,30h
cjne a,#0ffh,decdelay
mov 30h,#09h
dec 31h
mov a,31h
cjne a,#0ffh,decdelay
mov 31h,#05h
decdelay:
lcall display
inc 37h
mov a,37h
cjne a,#20,incdelay
mov 37h,#00h
ret
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
display:
mov p2,#0ffh ;將P2口置為高電平
mov r7,#100 ;軟件計數器賦值
dd1:
mov a,30h ;將顯示緩沖區30H中的值送入ACC
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.0 ;開個位顯示單元
lcall delay100us ;延時100US
setb p2.0 ;關個位顯示單
mov a,31h ;將顯示緩沖區別31H中的值送入A
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.1 ;開十位顯示單元
lcall delay100us ;延時100US
setb p2.1 ;關十位顯示單元
mov a,32h ;將顯示緩沖區32H中的值送入ACC
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.2 ;開百位顯示單元
lcall delay100us ;延時100US
setb p2.2 ;關百位顯示單元
mov a,33h ;將顯示緩沖區33H中的值送入ACC
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.3 ;開千位顯示單元
lcall delay100us ;延時100US
setb p2.3 ;關千位顯示單元
djnz r7,dd1 ;R7不等于0返回至DD1處
ret ;R7等于0子程序返回
KEY: LCALL KS ;調用檢測按鍵子程序
JNZ K1 ;有鍵按下繼續
ljmp key_exit ;無鍵按下退出KEY子程序
K1: LCALL delay4ms ;返回繼續檢測有無按鍵按下
LCALL delay4ms
LCALL KS ;有鍵按下繼續延時去抖動
JNZ K2 ;再一次調用檢測按鍵程序
ljmp key_exit ;無鍵按下退出KEY子程序
K2: MOV R2,#0EFH ;將掃描值送入 R2暫存
MOV R4,#00H ;將第一列的列值00H送入R4暫存,R4用于存放列
K3: MOV P1,R2 ;將R2的值送入P1口
L6: JB P1.0,L1 ;P1.0等于1跳轉到L1
MOV A,#00H ;將第一行的行值00H送入ACC
AJMP LK ;跳轉到鍵值處理程序
L1: JB P1.1,L2 ;P1.1等于1跳轉到L2
MOV A,#04H ;將第二行的行值04H送入ACC
AJMP LK ;跳轉到鍵值理程序進行鍵值處理
L2: JB P1.2,L3 ;P1.2等于1跳轉到L3
MOV A,#08H ;將第三行的行值08H送入ACC
AJMP LK ;跳轉到鍵值處理程序
L3: JB P1.3,NEXT ;P1.3等于1跳轉到NEXT處
MOV A,#0cH ;將第四行的行值0CH送入ACC
LK: ADD A,R4 ;行值與列值相加后的鍵值送入A
mov 34h,a ;將A中的值送入34h暫存
K4:
RET ;有鍵按下立即返回
NEXT:
INC R4 ;將列值加一
MOV A,R2 ;將R2的值送入A
JNB ACC.7,key_exit ;掃描完成跳至KEY處進行下一回合的掃描
RL A ;掃描未完成將A中的值右移一位進行下一列的掃描
MOV R2,A ;將ACC的值送入R2暫存
AJMP K3 ;跳轉到K3繼續
key_exit:
mov a,#0ffh ;無鍵按下則將A賦成0FFH。
ret
KS: MOV P1,#0FH ;將P1口高四位置0低四位值1
MOV A,P1 ;讀P1口
XRL A,#0FH ;將A中的值與A中的值相異或
RET ;子程序返回
delay4ms: ;4ms
MOV R5,#08H
L7: MOV R6,#0FAH
L8: DJNZ R6,L8
DJNZ R5,L7
RET
delay100us:
mov r5,#50
djnz r5,$
ret
tab: db 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h,88h,83h,0c6h,0a1h,86h,8eh
end
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -