;/************************************************************************************
;* 文件名：DebugInChipSRAM.scf
;* 功  能：分散加載文件DebugInChipSRAM.scf適用于片內SRAM程序調試。
;*         對應生成目標DebugInChipSRAM。
;*                                                        
;* 注  意：有時候用戶希望將不同代碼放在不同存儲空間，也就是通過編譯器生成的映像文件需要
;*         包含多個域，每個域在加載和運行時可以有不同的地址。要生成這樣的映像文件，必須
;*         通過某種方式告訴連接器相關的地址映射關系。在ADS中，可以通過分散加載機制實現。        
;*
;* 作  者：POWER  
;* 日  期：2006年5月18號
;* 斯凱科技主頁：www.armsky.net
;* 斯凱科技論壇：www.armsky.net/bbs       
;*************************************************************************************/

ROM_LOAD 0x40000000                                ;/* 加載區，從0x40000000(LPC213X片內SRAM最低端)開始 */
{
    ROM_EXEC 0x40000000                            ;/* 執行區，起始地址、空間大小要和加載區一致 */
    {
        Startup.o (vectors, +First)                ;/* 存儲Startup.s中的向量表（Startup.o為文件Startup.s的目標代碼 */
        
        * (+RO)                                    ;/* 存儲其他代碼*/
    }

     IRAM 0x40001800                                ;/* LPC2141片內SRAM調試時，代碼空間的結束地址，此處的值可以根據需要進行調整 */ 
 ;// IRAM 0x40003800                                ;/* LPC2142/44片內SRAM調試時，代碼空間的結束地址，此處的值可以根據需要進行調整 */    
 ;// IRAM 0x40007800                                ;/* LPC2146/48片內SRAM調試時，代碼空間的結束地址，此處的值可以根據需要進行調整 */    
 
    {                                              ;/* 變量區，起始地址可以根據需要進行調整 */
    
        Startup.o (MyStacks)                       ;/* Startup.s中的MyStacks */
        
        * (+RW,+ZI)                                ;/* 文件的其他變量 */
    }

    HEAP +0 UNINIT                                 ;/* 系統堆空間 */
    {
        Startup.o (Heap)                           ;/* Sartup.s中的Heap */
    }

     STACKS 0x40002000 UNINIT                       ;/* LPC2141片內SRAM(8KB)最高端 */
 ;// STACKS 0x40004000 UNINIT                       ;/* LPC2142/44片內SRAM(16KB)最高端 */
 ;// STACKS 0x40008000 UNINIT                       ;/* LPC2146/48片內SRAM(32KB+8KB)的前32KB的最高端 */
    {
        Startup.o (Stacks)                         ;/* Startup.s中的Stacks */
    }
}