VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CCooperates"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Option Explicit

Private mCol As Collection

'往集合中加入一個(gè)“合作信息”對(duì)象
Public Sub Add(objCoop As CCooperate)
  mCol.Add objCoop, "A" & objCoop.ID
  '在加入對(duì)象是，最好同時(shí)加入其“KEY”屬性
  '“KEY”屬性不可以是數(shù)字型，因此在前面隨便加
  '一個(gè)字母，此處加了一個(gè)“A”
End Sub

Public Property Get Item(vntIndexKey As Variant) As CCooperate
  Set Item = mCol(vntIndexKey)
End Property

Public Property Get Count() As Long
  Count = mCol.Count
End Property

Public Sub Remove(vntIndexKey As Variant)
  mCol.Remove vntIndexKey
End Sub

Public Property Get NewEnum() As IUnknown
  '本屬性允許用 For...Each 語(yǔ)法枚舉該集合。
  Set NewEnum = mCol.[_NewEnum]
End Property

'清除集合中的全部元素
Public Sub Clear()
  '注意！在清除時(shí)必須倒序清除，否則要出錯(cuò)！
  Dim i As Long
  For i = mCol.Count To 1 Step -1
    mCol.Remove i
  Next i
End Sub

Private Sub Class_Initialize()
  Set mCol = New Collection
End Sub

Private Sub Class_Terminate()
  Set mCol = Nothing
End Sub

'按條件查找合作信息，以集合類(lèi)的方式返回
Public Function Find(Optional ByVal lngID As Long = 0, _
                    Optional ByVal lngClientId As Long = 0) As CCooperates
                      
  '構(gòu)造查詢(xún)SQL
  Dim strSQL As String
  strSQL = "SELECT * FROM Cooperate WHERE "
  
  If lngID <> 0 Then strSQL = strSQL & " CooperateId=" & lngID & " and "
  '如果是按名稱(chēng)查詢(xún)，則采用“包含”的查詢(xún)方法
  If lngClientId <> 0 Then strSQL = strSQL & "ClientId=" & lngClientId & " and "
  strSQL = strSQL & "CooperateId>0"
  
  On Error Resume Next
  '將查詢(xún)結(jié)果加入集合類(lèi)
  Dim rs As Recordset
  Set rs = g_Conn.Execute(strSQL)
  Dim i As Long
  Dim objCoop As CCooperate
  For i = 1 To rs.RecordCount
    Set objCoop = New CCooperate
    With objCoop
      .ID = rs("CooperateId").Value
      .ClientID = rs("ClientId").Value
      .Remark = Trim(rs("Remark").Value)
      .CooperateDate = rs("Date").Value
      .Satisfaction = rs("Satisfaction").Value
    End With
    Me.Add objCoop
    Set objCoop = Nothing
    rs.MoveNext
  Next i
  
  Set rs = Nothing
  Set Find = Me
End Function