;//************************************************************
;文件名: 語音芯片控制程序1420 FOR 8088

;功能: 微機控制語音芯片的錄制和播放

;接線: 用導線對應連接語音接口模塊的A0～A6到8255模塊的PC0～PC6，
;      語音接口模塊的A7接地，
;      8255模塊的PC7接語音接口模塊的REC(或PLAYE或PLAYL)，
;      8255模塊的CS_8255連CPU模塊的200H。
;//*********************************************************** 
;PC0～6——A0～A6
;PC7——REC、PLAYE、PLAYL

PA8255    EQU 200H        ;8255PA口地址
PB8255    EQU 201H        ;8255PB口地址

PC8255    EQU 202H        ;8255PC口地址
PCTL8255  EQU 203H        ;8255控制口地址

CODE    SEGMENT
ASSUME  CS:CODE,DS:code,SS:code
START:
        PUSH    CS
        POP     DS    
        
        MOV     DX,PCTL8255
        MOV     AL,80H             ;設置8255,全部為輸出
        OUT     DX,AL
        
        MOV   AL,00H    ;錄放音地址,自行選擇
        
        ;CALL  RECORD0   ;錄音     調此子程序時PC7接REC
       ; CALL  PLAYL     ;電平放音 調此子程序時PC7接PLAYL
       CALL  PLAYE     ;脈沖放音 調此子程序時PC7接PLAYE
       
       ; 實驗時三個子程序取一個有效  逐個試驗。
       
 OK:     JMP  OK   


;**************************************
; 名稱:RECORD
; 功能:錄音
;**************************************
RECORD0:
      CALL  ADDR_OUT       ;設定開始錄音地址
      MOV   DX,PCTL8255 
      MOV   AL,0EH         ;PC7: REC置“0”
      OUT   DX,AL          ;控制開始錄音
      
      MOV   CX,10          ;控制延時10s 
RECORD1:
      CALL  DELAY1S
      LOOP  RECORD1
      MOV   DX,PCTL8255 
      MOV   AL,0FH         ;PC7: REC置“1”
      OUT   DX,AL          ;釋放錄音按鍵     

      RET

;**************************************
;名稱:PLAYL
;功能:電平控制放音
;**************************************
PLAYL:
      CALL  ADDR_OUT       ;設定開始播放地址
      MOV   DX,PCTL8255 
      MOV   AL,0EH         ;PC7: PLAYL置“0”
      OUT   DX,AL          ;控制開始錄音
      
      MOV   CX,10          ;控制延時10s 
PLAYL1:
      CALL  DELAY1S
      LOOP  PLAYL1
      MOV   DX,PCTL8255 
      MOV   AL,0FH         ;PC7: PLAYL置“1”
      OUT   DX,AL          ;釋放播放按鍵   
      
      RET

;**************************************
;名稱:PLAYE
;功能:脈沖觸發放音
;**************************************
PLAYE:
      CALL  ADDR_OUT       ;設定開始播放地址
      MOV   DX,PCTL8255 
      MOV   AL,0EH         ;PC7: PLAYE置“0”
      OUT   DX,AL   
      NOP
      NOP       
      MOV   AL,0FH         ;PC7: PLAYE置“1”
      OUT   DX,AL          ;產生控制脈沖
      
      RET      

;**************************************
;名稱:ADDR_OUT
;功能:發送地址
;入口:AL(地址)
;**************************************
ADDR_OUT:
      MOV   DX,PC8255
      OR    AL,80H        ;PC7=1
      OUT   DX,AL      
      RET

;**************************************
; 名稱:DELAY1S
; 功能:延時1S    
;**************************************
DELAY1S:                      ;1000 000=50 000 * (18+2)
      PUSH  CX
      MOV   CX,0C350H         ;C350H=50 000
DL1:  NOP
      NOP
      NOP
      NOP
      NOP
      NOP
      NOP
      NOP
      
      NOP
      NOP
      NOP
      NOP
      NOP
      NOP
      NOP
      NOP
           
      LOOP  DL1      
      POP   CX
      RET

        CODE    ENDS
END     START