RS EQU P2.5  ;P3.4腳接RS端
 R_W EQU P2.6  ;P3.5腳接R_W端
 E EQU P2.7  ;P3.3腳接E端
 D_BUS EQU P0  ;P0口控制D_BUS輸出

 ORG 0000H   ;從0000H處開始
 LJMP MAIN   ;跳轉(zhuǎn)到MAIN處

 ORG 0030H   ;主程序從0030H處開始

MAIN: 
 MOV SP,#70H   ;堆棧指針指向70H
 LCALL INITIAL   ;調(diào)用啟動(dòng)LCM子程序進(jìn)行初始化
 LCALL CLS   ;調(diào)用清除LCM子程序
 
 MOV A,#80H   ;向A送立即數(shù)80H設(shè)定顯示地址為第一行第一列
 LCALL WRITE_COM  ;調(diào)用寫指令到LCM子程序
 
 MOV DPTR,#LINE1  ;將第一行字符串的啟始地址送如DPTR中
 LCALL DISP   ;調(diào)用顯示字符串到LCM子程序
 
 
 MOV A,#0C0H   ;向A送立即數(shù)0C0H設(shè)定顯示地址為第二行第一列
 LCALL WRITE_COM  ;調(diào)用寫指令到LCM子程序
 
 MOV DPTR,#LINE2  ;將第二行字符串的啟始地址送如DPTR中
 LCALL DISP   ;調(diào)用顯示字符串到LCM子程序
 SJMP $   ;程序動(dòng)態(tài)停機(jī)

LINE1: DB "WELCOME TO QLMCU",00H ;第一行字符串
LINE2: DB " WWW.QLMCU.COM! ",00H ;第二行字符串

INITIAL:    ;啟動(dòng)LCM子程序
 MOV A,#38H
 LCALL WRITE_COM
 MOV A,#0EH
 LCALL WRITE_COM
 MOV A,#06H
 LCALL WRITE_COM
 RET

;-------------------------------------------------------
CHECK_BUSY:    ;查詢忙碌信號(hào)子程序
 PUSH ACC
BUSY_LOOP:
 CLR E
 SETB R_W
 CLR RS
 SETB E
 MOV A,D_BUS
 CLR E
 JB ACC.7,BUSY_LOOP
 POP ACC
 LCALL DEL
 RET
;---------------------------------------------------------
 
WRITE_COM:    ;寫指令到LCM子程序 
 LCALL CHECK_BUSY
  MOV D_BUS,A
 CLR E
 CLR RS
 CLR R_W
 SETB E
 CLR E
 RET
;----------------------------------------------------------

WRITE_DATA:    ;寫數(shù)據(jù)到LCM子程序
 LCALL CHECK_BUSY
  MOV D_BUS,A
 CLR E
 SETB RS
 CLR R_W
 SETB E
 CLR E
 RET
;-----------------------------------------------------------

CLS:     ;清除LCM子程序
 MOV A,#01H
 LCALL WRITE_COM
 RET
;-----------------------------------------------------------

DEL: 
 MOV R6,#5   ;2.7ms延時(shí)子程序
D1: MOV R7,#248
 DJNZ R7,$
 DJNZ R6,D1
 RET

;----------------------------------------------------
DISP: 
 PUSH ACC   ;將A的內(nèi)容壓棧

DISP_LOOP: 
 CLR A   ;A清零
 MOVC A,@A+DPTR  ;查表將字符串內(nèi)容送入A
 JZ END_DISP  ;若查到的內(nèi)容為0則終止查表
 LCALL WRITE_DATA  ;調(diào)用寫數(shù)據(jù)到LCM子程序
 INC DPTR   ;DPTR加1指向下一個(gè)對(duì)象
 SJMP DISP_LOOP  ;跳轉(zhuǎn)到DISP_LOOP循環(huán)執(zhí)行

END_DISP:
 POP ACC   ;彈出壓棧內(nèi)容至A
 RET
;---------------------------------------------------------
 



 END    ;程序結(jié)束