;*****************************************************
;
;     This programme is for study Ver2.0.0 beta
;This programme must be run in 12MHz standard settings
;              The keys management
;               Designer: Mr.Koii
;         Copyright 2002-2003 koiistudio
;     2003.04.04 at Changsha. H.N. P.R.China.
;
;*****************************************************

;*****************************************************
;鍵盤中斷處理程序
;*****************************************************

keys_int:               clr     ea
                        clr     ie1
                        mov     p2,#0
                        mov     a,p1
                        cpl     a
                        anl     a,#0fh
                        cjne    a,#0,keys_reader
                        clr     ie1
                        setb    ea
                        reti
keys_reader:            call    time10ms
                        mov     a,p1
                        cpl     a
                        anl     a,#0fh
                        mov     keys_byte,a
keys_reader_0:          mov     a,p1
                        cpl     a
                        anl     a,#0fh
                        cjne    a,#0,keys_reader_0

;*****************************************************
;按鍵處理程序
;*****************************************************

keys_management:        call    beep1
                        mov     a,keys_byte
                        cjne    a,#01h,keys_check_2
                        sjmp    keys_1
keys_check_2:           cjne    a,#02h,keys_check_3
                        sjmp    keys_2
keys_check_3:           cjne    a,#04h,keys_check_4
                        sjmp    keys_3
keys_check_4:           cjne    a,#08h,keys_check_err
                        sjmp    keys_4
keys_check_err:         clr     ie1
                        setb    ea
                        reti

keys_1:                 jmp     keys_manage_1
keys_2:                 jmp     keys_manage_2
keys_3:                 jmp     keys_manage_3
keys_4:                 jmp     keys_manage_4

;*****************************************************
;1鍵處理
;*****************************************************

keys_manage_1:          mov     a,r4                        ;增加延時時間，即減慢流動速度
                        cjne    a,#50,keys_manage_1_0
                        call    beep2
                        clr     ie1
                        setb    ea
                        reti
keys_manage_1_0:        add     a,#5
                        mov     r4,a
                        clr     ie1
                        setb    ea
                        reti

;*****************************************************
;2鍵處理
;*****************************************************

keys_manage_2:          mov     a,r4                        ;增加延時時間，即減慢流動速度
                        cjne    a,#5,keys_manage_2_0
                        call    beep2
                        clr     ie1
                        setb    ea
                        reti
keys_manage_2_0:        clr     c
                        subb    a,#5
                        mov     r4,a
                        clr     ie1
                        setb    ea
                        reti

;*****************************************************
;3鍵處理
;*****************************************************

keys_manage_3:          mov     a,r3                        ;改變流動花樣
                        cjne    a,#3,keys_manage_3_0
                        mov     r3,#0
                        clr     ie1
                        setb    ea
                        reti
keys_manage_3_0:        inc     r3
                        clr     ie1
                        setb    ea
                        reti

;*****************************************************
;4鍵處理
;*****************************************************

keys_manage_4:          mov     a,r3                        ;改變流動花樣
                        cjne    a,#0,keys_manage_4_0
                        mov     r3,#3
                        clr     ie1
                        setb    ea
                        reti
keys_manage_4_0:        dec     r3
                        clr     ie1
                        setb    ea
                        reti