;電子制作實(shí)驗(yàn)室http://www.xie-gang.com/
;可設(shè)定時(shí)間的倒計(jì)時(shí)定時(shí)器,可選擇5/15/20/30/35/45/50分鐘倒計(jì)時(shí)
;倒計(jì)時(shí)時(shí)間由四位撥碼開(kāi)關(guān)的2/3/4位來(lái)控制,
;第2位表示5分鐘,第3位表示15分鐘,第4位表示30分鐘,
;通過(guò)不同的組合可以產(chǎn)生5/15/20/30/35/45/50分鐘倒計(jì)時(shí)
;P1.0口的外接的發(fā)光二極管為狀態(tài)LED,定時(shí)未開(kāi)始時(shí)LED常亮,定時(shí)過(guò)程中LED閃爍
;K1為開(kāi)始按鈕,K2為停止按鈕

a_bit equ 20h ;數(shù)碼管個(gè)位數(shù)存放內(nèi)存位置
b_bit equ 21h ;數(shù)碼管十位數(shù)存放內(nèi)存位置
temp equ 22h ;計(jì)數(shù)器數(shù)值存放內(nèi)存位置

;開(kāi)機(jī)初始化
MOV P3,#0FFH;對(duì)P3口初始化,設(shè)置為高電平,用于按鍵輸入
MOV P0,#0FFH;使顯示時(shí)間數(shù)碼管熄滅
CLR P1.0;點(diǎn)亮LED指示燈

;等待鍵盤輸入
START:JB P3.6,$;循環(huán)判斷開(kāi)始按鈕K1是否按下?
ACALL DELAY10;延時(shí)10毫秒觸點(diǎn)消抖
JB P3.6,START;如果是干擾就返回
JNB P3.6,$;等待按鍵松開(kāi)

;讀撥碼開(kāi)關(guān)的狀態(tài),獲得倒計(jì)時(shí)時(shí)間
SET:MOV A,#0;首先對(duì)A清零
JB P2.0,A1;判斷撥碼開(kāi)關(guān)的第2位是否接通,接通就對(duì)A加5
ADD A,#5
A1:JB P2.1,A2;判斷撥碼開(kāi)關(guān)的第3位是否接通,接通就對(duì)A加15
ADD A,#15
A2:JB P2.2,A3;判斷撥碼開(kāi)關(guān)的第4位是否接通,接通就對(duì)A加30
ADD A,#30
A3:MOV TEMP,A
;這時(shí)TEMP中的值就是倒計(jì)時(shí)時(shí)間

;數(shù)碼管顯示定時(shí)時(shí)間的程序
display:CLR P2.4;使繼電器1釋放,開(kāi)始定時(shí)(開(kāi)機(jī)時(shí)繼電器處于吸合狀態(tài))
CLR P2.3;使繼電器2釋放,開(kāi)始定時(shí)(開(kāi)機(jī)時(shí)繼電器處于吸合狀態(tài))
MOV R2,#120
AB:MOV R3,#250
TIME1:mov a,temp ;將temp中的十六進(jìn)制數(shù)轉(zhuǎn)換成10進(jìn)制 
mov b,#10 ;10進(jìn)制/10=10進(jìn)制
div ab
mov b_bit,a ;十位在a
mov a_bit,b ;個(gè)位在b

mov dptr,#numtab ;指定查表啟始地址
mov r0,#4 
dpl1: mov r1,#250 ;
dplop: mov a,a_bit ;取個(gè)位數(shù)
MOVC A,@A+DPTR ;查個(gè)位數(shù)的7段代碼
mov p0,a ;送出個(gè)位的7段代碼
clr p2.7 ;開(kāi)個(gè)位顯示
ACALL DELY1;顯示1毫秒
setb p2.7;關(guān)閉個(gè)位顯示,防止鬼影
mov a,b_bit ;取十位數(shù)
MOVC A,@A+DPTR ;查十位數(shù)的7段代碼
mov p0,a ;送出十位的7段代碼
clr p2.6 ;開(kāi)十位顯示
ACALL DELY1;顯示1毫秒
setb p2.6;關(guān)閉十位顯示,防止鬼影

;插入一段判斷定時(shí)過(guò)程中是否有按鍵輸入的程序段
C1:JB P3.6,B1
ACALL DELAY10;延時(shí)10毫秒消抖
JB P3.6,C1
JNB P3.6,$;等待按鍵松開(kāi)
AJMP SET
B1:JB P3.7,M33
ACALL DELAY10;延時(shí)10毫秒消抖
JB P3.7,B1
JNB P3.7,$;等待按鍵松開(kāi)
AJMP OVER

M33:djnz r3,TIME1 ;2毫秒循環(huán)執(zhí)行250次,時(shí)間約0.5秒
CPL P1.0;使LED每1秒閃爍一次
djnz r2,AB ;循環(huán)執(zhí)行120次,時(shí)間為1分鐘

DEC TEMP;滿一分鐘對(duì)定時(shí)時(shí)間減1
MOV A,TEMP
JNZ DISPLAY;判斷TEMP的數(shù)值是否為0?不為0循環(huán) 

;結(jié)束定時(shí)
OVER:CLR P1.0;LED指示燈常亮
SETB P2.4;繼電器1吸合,定時(shí)結(jié)束,退回到開(kāi)機(jī)時(shí)的狀態(tài)
SETB P2.3;繼電器2吸合,定時(shí)結(jié)束,退回到開(kāi)機(jī)時(shí)的狀態(tài)
AJMP START;退到開(kāi)機(jī)初始化狀態(tài)

;1毫秒延時(shí)子程序
DELY1:MOV R4,#2
D1:MOV R5,#248
DJNZ R5,$
DJNZ R4,D1
RET

;10毫秒延時(shí)子程序
DELAY10:MOV R4,#20
D2:MOV R5,#248
DJNZ R5,$
DJNZ R4,D2
RET

;實(shí)驗(yàn)板上的兩位一體的數(shù)碼管0～9各數(shù)字的顯示代碼
numtab: DB 30H,0FCH,0A2H,0A4H,06CH,25H,21H,0BCH,20H,24H

end