?? 矩陣鍵盤鍵值顯示程序-lcd.asm
字號:
;--------------------------------------------------------------
;矩陣鍵盤定義：
;P1.0-P1.3為列線,P1.4-P1.7為行線
;--------------------------------------------------------------
RELAY EQU P1.3
BEEP EQU P3.7
;--------------------------------------------------------------
RS EQU P2.0
RW EQU P2.1
EN EQU P2.2
X EQU 26H ;LCD 地址變量
;--------------------------------------------------------------
ORG 0000H
JMP MAIN
;--------------------------------------------------------------
MAIN: MOV SP,#30H
CLR EN
CALL SET_LCD
CALL MENU1
CALL BEEP_BL
LOOP0:
MOV P1,#0F0H
MOV A,P1
CJNE A,#0F0H,LOOP1 ;有鍵按下轉(zhuǎn)LOOP1
JMP LOOP0
LOOP1:
CALL KEY_IN
CALL CONV
CALL BEEP_BL
JMP LOOP0
;-----------------------------------------------------
; LCD 初始化設(shè)置
;-----------------------------------------------------
SET_LCD:
CLR EN
CALL INIT_LCD ;初始化 LCD
CALL DELAY1
MOV DPTR,#INFO1 ;指針指到顯示信息1
MOV A,#1 ;顯示在第一行
CALL LCD_SHOW
MOV DPTR,#INFO2 ;指針指到顯示信息2
MOV A,#2 ;顯示在第二行
CALL LCD_SHOW
RET
;-----------------------------------------------------
INIT_LCD: ;8位I/O控制 LCD 接口初始化
MOV A,#38H ;雙列顯示，字形5*7點(diǎn)陣
CALL WCOM
CALL DELAY1
MOV A,#38H ;雙列顯示，字形5*7點(diǎn)陣
CALL WCOM
CALL DELAY1
MOV A,#38H ;雙列顯示，字形5*7點(diǎn)陣
CALL WCOM
CALL DELAY1
MOV A,#0CH ;開顯示，關(guān)光標(biāo)，
CALL WCOM
CALL DELAY1
MOV A,#01H ;清除 LCD 顯示屏
CALL WCOM
CALL DELAY1
RET
;----------------------------------------------------
LCD_SHOW: ;在LCD的第一行或第二行顯示信息字符
CJNE A,#1,LINE2 ;判斷是否為第一行
LINE1: MOV A,#80H ;設(shè)置 LCD 的第一行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數(shù)據(jù)
MOV A,#80H ;設(shè)置 LCD 的第一行地址
CALL WCOM ;寫入命令
JMP FILL
LINE2: MOV A,#0C0H ;設(shè)置 LCD 的第二行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數(shù)據(jù)
MOV A,#0C0H ;設(shè)置 LCD 的第二行地址
CALL WCOM
FILL: CLR A ;填入字符
MOVC A,@A+DPTR ;由信息區(qū)取出字符
CJNE A,#0,LC1 ;判斷是否為結(jié)束碼
RET
LC1: CALL WDATA ;寫入數(shù)據(jù)
INC DPTR ;指針加1
JMP FILL ;繼續(xù)填入字符
RET
;---------------------------------------------------
CLR_LINE: ;清除該行 LCD 的字符
MOV R0,#24
CL1: MOV A,#' '
CALL WDATA
DJNZ R0,CL1
RET
;----------------------------------------------------
MENU1: ;LCD 顯示工作菜單信息
MOV DPTR,#MENU2
MOV A,#1 ;在第一行顯示信息
CALL LCD_SHOW
RET
MENU2: DB " KEY NUMBER ",0
;-----------------------------------------------------
INFO1: DB " ",0 ;LCD 第一行顯示信息
INFO2: DB " KEY-CODE: -- H ",0 ;LCD 第二行顯示信息
;-----------------------------------------------------
;-----------------------------------------------------
; 寫指令、數(shù)據(jù)使能子程序
;-----------------------------------------------------
WCOM: ;寫指令使能
MOV P0,A
CLR RS ;RS=L,RW=L,D0-D7=指令碼，E=高脈沖
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
WDATA: ;寫數(shù)據(jù)使能
MOV P0,A
SETB RS ;RS=H,RW=L,D0-D7=數(shù)據(jù)，E=高脈沖
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
DELAY0: MOV R7,#250 ;延時(shí)500微秒
DJNZ R7,$
RET
;---------------------------------------------------
;在 LCD 第二行顯示字符
;A=ASC DATA, B=LINE X POS
;---------------------------------------------------
LCDP2: ;在LCD的第二行顯示字符
PUSH ACC ;
MOV A,B ;設(shè)置顯示地址
ADD A,#0C0H ;設(shè)置LCD的第二行地址
CALL WCOM ;寫入命令
POP ACC ;由堆棧取出A
CALL WDATA ;寫入數(shù)據(jù)
RET
;-----------------------------------------------------
KEY_IN: MOV P1,#0F0H ;置列線為0，行線為1
MOV A,P1
ANL A,#0F0H
MOV B,A
MOV P1,#0FH ;置列線為1，行線為0
MOV A,P1
ANL A,#0FH
ORL A,B ;高四位與低四位重新組合
CJNE A,#0FFH,KEY_IN1 ;0FFH為末按鍵
RET
KEY_IN1: MOV B,A
MOV DPTR,#KEYTABLE
MOV R3,#0FFH
KEY_IN2: INC R3
MOV A,R3
MOVC A,@A+DPTR
CJNE A,B,KEY_IN3
MOV A,R3 ;找到，取順序碼
MOV R5,#08H ;延時(shí)
CALL DELAY
RET
KEY_IN3: CJNE A,#0FFH,KEY_IN2 ;末完，繼續(xù)查
RET ;0FFH為結(jié)束碼
;-------------------------------------------------
CONV:
MOV X,#11 ;設(shè)置顯示起始位置
MOV A,R3
ANL A,#0F0H ;取出高四位二進(jìn)制數(shù)
SWAP A ;高四位與低四位互換
PUSH ACC ;壓入堆棧
CLR C ;C=0
SUBB A,#0AH ;減10
POP ACC ;彈出堆棧
JC ASCII0 ;該數(shù)小于10，轉(zhuǎn)ASCII0
ADD A,#07H ;大于10的數(shù)加上37H
ASCII0: ADD A,#30H ;小于10的數(shù)加上30H
MOV B,X
CALL LCDP2
MOV A,R3
ANL A,#0FH ;取出低四位二進(jìn)制數(shù)
CLR C
SUBB A,#0AH ;減10
POP ACC
JC ASCII1 ;該數(shù)小于10，轉(zhuǎn)ASCII0
ADD A,#07H ;大于10的數(shù)加上37H
ASCII1: ADD A,#30H ;小于10的數(shù)加上30H
INC X
MOV B,X
CALL LCDP2
RET
;--------------------------------------------------------
;蜂鳴器響一聲子程序
;--------------------------------------------------------
BEEP_BL:
MOV R6,#100
BL1: CALL DEX1
CPL BEEP
DJNZ R6,BL1
MOV R5,#50
CALL DELAY
RET
DEX1: MOV R7,#180
DEX2: NOP
DJNZ R7,DEX2
RET
DELAY: ;延時(shí)R5×10MS
MOV R6,#50
D1: MOV R7,#100
DJNZ R7,$
DJNZ R6,D1
DJNZ R5,DELAY
RET
;-----------------------------------------------------
DELAY1: ;延時(shí)5MS
MOV R6,#25
D2: MOV R7,#100
DJNZ R7,$
DJNZ R6,D2
RET
;-----------------------------------------------------
KEYTABLE:
DB 0EEH,0EDH,0EBH,0E7H,0DEH ;0,1,2,3,4, 順序碼
DB 0DDH,0DBH,0D7H,0BEH,0BDH ;5,6,7,8,9,
DB 0BBH,0B7H,07EH,07DH,07BH ;A,B,C,D,E,
DB 077H,0FFH ;F 0FF為結(jié)束碼
;-----------------------------------------------------
END
?? 快捷鍵說明
復(fù)制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -